src/cmake/library.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 macro(add_vpp_library lib)
  15   cmake_parse_arguments(ARG
  16     "LTO"
  17     "COMPONENT"
  18     "SOURCES;MULTIARCH_SOURCES;API_FILES;LINK_LIBRARIES;INSTALL_HEADERS;DEPENDS"
  19     ${ARGN}
  20   )
  21
  22   add_library(${lib} SHARED ${ARG_SOURCES})
  23   if(VPP_LIB_VERSION)
  24     set_target_properties(${lib} PROPERTIES SOVERSION ${VPP_LIB_VERSION})
  25   endif()
  26
  27   # library deps
  28   if(ARG_LINK_LIBRARIES)
  29     target_link_libraries(${lib} ${ARG_LINK_LIBRARIES})
  30   endif()
  31   # install .so
  32   if(NOT ARG_COMPONENT)
  33     set(ARG_COMPONENT vpp)
  34   endif()
  35   install(
  36     TARGETS ${lib}
  37     DESTINATION ${VPP_LIBRARY_DIR}
  38     COMPONENT ${ARG_COMPONENT}
  39   )
  40
  41   if (ARG_LTO AND VPP_USE_LTO)
  42      set_property(TARGET ${lib} PROPERTY INTERPROCEDURAL_OPTIMIZATION TRUE)
  43      target_compile_options (${lib} PRIVATE "-ffunction-sections")
  44      target_compile_options (${lib} PRIVATE "-fdata-sections")
  45      target_link_libraries (${lib} "-Wl,--gc-sections")
  46   endif()
  47
  48   if(ARG_MULTIARCH_SOURCES)
  49     vpp_library_set_multiarch_sources(${lib} "${ARG_DEPENDS}" ${ARG_MULTIARCH_SOURCES})
  50   endif()
  51
  52   if(ARG_API_FILES)
  53     vpp_add_api_files(${lib} core vpp ${ARG_API_FILES})
  54     foreach(file ${ARG_API_FILES})
  55       get_filename_component(dir ${file} DIRECTORY)
  56       install(
  57         FILES ${file} ${CMAKE_CURRENT_BINARY_DIR}/${file}.h
  58         ${CMAKE_CURRENT_BINARY_DIR}/${file}_enum.h
  59         ${CMAKE_CURRENT_BINARY_DIR}/${file}_types.h
  60         ${CMAKE_CURRENT_BINARY_DIR}/${file}_tojson.h
  61         ${CMAKE_CURRENT_BINARY_DIR}/${file}_fromjson.h
  62         DESTINATION include/${lib}/${dir}
  63         COMPONENT vpp-dev
  64       )
  65     endforeach()
  66   endif()
  67
  68   if(ARG_DEPENDS)
  69     add_dependencies(${lib} ${ARG_DEPENDS})
  70   endif()
  71
  72   # install headers
  73   if(ARG_INSTALL_HEADERS)
  74     foreach(file ${ARG_INSTALL_HEADERS})
  75       get_filename_component(dir ${file} DIRECTORY)
  76       install(
  77         FILES ${file}
  78         DESTINATION include/${lib}/${dir}
  79         COMPONENT ${ARG_COMPONENT}-dev
  80       )
  81     endforeach()
  82   endif()
  83 endmacro()
  84
  85 ##############################################################################
  86 # header files
  87 ##############################################################################
  88 function (add_vpp_headers path)
  89   foreach(file ${ARGN})
  90     get_filename_component(dir ${file} DIRECTORY)
  91     install(
  92       FILES ${file}
  93       DESTINATION include/${path}/${dir}
  94       COMPONENT vpp-dev
  95     )
  96   endforeach()
  97 endfunction()
  98
  99 macro(add_vpp_test_library lib)
 100   cmake_parse_arguments(TEST
 101     ""
 102     ""
 103     ${ARGN}
 104   )
 105
 106   foreach(file ${ARGN})
 107     get_filename_component(name ${file} NAME_WE)
 108     set(test_lib ${lib}_${name}_plugin)
 109     add_library(${test_lib} SHARED ${file}_test2.c)
 110     if(NOT VPP_EXTERNAL_PROJECT)
 111       add_dependencies(${test_lib} api_headers)
 112     endif()
 113     include_directories(${CMAKE_CURRENT_BINARY_DIR})
 114     set_target_properties(${test_lib} PROPERTIES NO_SONAME 1)
 115     set_target_properties(${test_lib} PROPERTIES
 116       PREFIX ""
 117       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vat2_plugins)
 118
 119     # Later: Install and package
 120     # install .so
 121     #install(
 122     #  TARGETS ${test_lib}
 123     #  DESTINATION ${VPP_LIBRARY_DIR}/vat2_plugins
 124     #  #COMPONENT ${ARG_COMPONENT}
 125     #  )
 126   endforeach()
 127 endmacro()