src/cmake/library.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 macro(add_vpp_library lib)
  15   cmake_parse_arguments(ARG
  16     ""
  17     ""
  18     "SOURCES;MULTIARCH_SOURCES;API_FILES;LINK_LIBRARIES;INSTALL_HEADERS;DEPENDS"
  19     ${ARGN}
  20   )
  21
  22   add_library(${lib} SHARED ${ARG_SOURCES})
  23
  24   # library deps
  25   if(ARG_LINK_LIBRARIES)
  26     target_link_libraries(${lib} ${ARG_LINK_LIBRARIES})
  27   endif()
  28   # install .so
  29   install(TARGETS ${lib} DESTINATION ${VPP_LIB_DIR_NAME})
  30
  31   if(ARG_MULTIARCH_SOURCES)
  32     vpp_library_set_multiarch_sources(${lib} ${ARG_MULTIARCH_SOURCES})
  33   endif()
  34
  35   if(ARG_API_FILES)
  36     vpp_add_api_files(${lib} ${ARG_API_FILES})
  37     foreach(file ${ARG_API_FILES})
  38       get_filename_component(dir ${file} DIRECTORY)
  39       install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${file}.h DESTINATION include/${lib}/${dir})
  40     endforeach()
  41   endif()
  42
  43   if(ARG_DEPENDS)
  44     add_dependencies(${lib} ${ARG_DEPENDS})
  45   endif()
  46
  47   # install headers
  48   if(ARG_INSTALL_HEADERS)
  49     foreach(file ${ARG_INSTALL_HEADERS})
  50       get_filename_component(dir ${file} DIRECTORY)
  51       install(FILES ${file} DESTINATION include/${lib}/${dir})
  52     endforeach()
  53   endif()
  54 endmacro()
  55
  56 ##############################################################################
  57 # header files
  58 ##############################################################################
  59 function (add_vpp_headers path)
  60   foreach(file ${ARGN})
  61     get_filename_component(dir ${file} DIRECTORY)
  62     install(FILES ${file} DESTINATION include/${path}/${dir})
  63   endforeach()
  64 endfunction()