src/cmake/message.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 ##############################################################################
  15 # Highlight WARNING and ERROR messages
  16 ##############################################################################
  17 function(message)
  18   list(GET ARGV 0 type)
  19   if("$ENV{TERM}" STREQUAL "xterm-256color")
  20     string(ASCII 27 esc)
  21     set(red "${esc}[1;31m")
  22     set(yellow "${esc}[1;33m")
  23     set(reset "${esc}[m")
  24   endif()
  25   if(type STREQUAL FATAL_ERROR OR type STREQUAL SEND_ERROR)
  26     list(REMOVE_AT ARGV 0)
  27     _message(${type} "${red}${ARGV}${reset}")
  28   elseif(type STREQUAL WARNING)
  29     list(REMOVE_AT ARGV 0)
  30     _message(STATUS "${yellow}${ARGV}${reset}")
  31   elseif(type STREQUAL STATUS)
  32     list(REMOVE_AT ARGV 0)
  33     _message(STATUS "${ARGV}")
  34   else()
  35     _message(${ARGV})
  36   endif()
  37 endfunction()
  38
  39 ##############################################################################
  40 # aligned config output
  41 ##############################################################################
  42 function(pr desc val)
  43   if("$ENV{TERM}" STREQUAL "xterm-256color")
  44     string(ASCII 27 esc)
  45     set(reset "${esc}[m")
  46     set(cyan "${esc}[36m")
  47   endif()
  48   string(LENGTH ${desc} len)
  49   while (len LESS 20)
  50     set (desc "${desc} ")
  51     string(LENGTH ${desc} len)
  52   endwhile()
  53   _message("${cyan}${desc}${reset}: ${val}")
  54 endfunction()