src/cmake/plugin.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 macro(add_vpp_plugin name)
  15   cmake_parse_arguments(PLUGIN
  16     ""
  17     "LINK_FLAGS;COMPONENT;DEV_COMPONENT"
  18     "SOURCES;API_FILES;MULTIARCH_SOURCES;LINK_LIBRARIES;INSTALL_HEADERS;API_TEST_SOURCES"
  19     ${ARGN}
  20   )
  21   set(plugin_name ${name}_plugin)
  22   set(api_includes)
  23   if(NOT PLUGIN_COMPONENT)
  24     set(PLUGIN_COMPONENT vpp-plugin-core)
  25   endif()
  26   if(NOT PLUGIN_DEV_COMPONENT)
  27     if(NOT VPP_EXTERNAL_PROJECT)
  28       set(PLUGIN_DEV_COMPONENT vpp-dev)
  29     else()
  30       set(PLUGIN_DEV_COMPONENT ${PLUGIN_COMPONENT}-dev)
  31     endif()
  32   endif()
  33
  34   vpp_add_api_files(${plugin_name} plugins ${PLUGIN_COMPONENT} ${PLUGIN_API_FILES})
  35   foreach(f ${PLUGIN_API_FILES})
  36     get_filename_component(dir ${f} DIRECTORY)
  37     list(APPEND api_includes ${f}.h ${f}.json)
  38     install(
  39       FILES ${CMAKE_CURRENT_BINARY_DIR}/${f}.h
  40       ${CMAKE_CURRENT_BINARY_DIR}/${f}_enum.h
  41       ${CMAKE_CURRENT_BINARY_DIR}/${f}_types.h
  42       DESTINATION include/vpp_plugins/${name}/${dir}
  43       COMPONENT ${PLUGIN_DEV_COMPONENT}
  44     )
  45   endforeach()
  46   add_library(${plugin_name} SHARED ${PLUGIN_SOURCES} ${api_includes})
  47   set_target_properties(${plugin_name} PROPERTIES NO_SONAME 1)
  48   if(PLUGIN_API_FILES)
  49     add_dependencies(${plugin_name} ${plugin_name}_api_headers)
  50   endif()
  51   if(NOT VPP_EXTERNAL_PROJECT)
  52     add_dependencies(${plugin_name} vpp_version_h api_headers)
  53   endif()
  54   set_target_properties(${plugin_name} PROPERTIES
  55     PREFIX ""
  56     LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_plugins)
  57   if(PLUGIN_MULTIARCH_SOURCES)
  58     vpp_library_set_multiarch_sources(${plugin_name} ${PLUGIN_MULTIARCH_SOURCES})
  59   endif()
  60   if(PLUGIN_LINK_LIBRARIES)
  61     target_link_libraries(${plugin_name} ${PLUGIN_LINK_LIBRARIES})
  62   endif()
  63   if(PLUGIN_LINK_FLAGS)
  64     set_target_properties(${plugin_name} PROPERTIES LINK_FLAGS "${PLUGIN_LINK_FLAGS}")
  65   endif()
  66   if(PLUGIN_INSTALL_HEADERS)
  67     foreach(file ${PLUGIN_INSTALL_HEADERS})
  68       get_filename_component(dir ${file} DIRECTORY)
  69       install(
  70         FILES ${file}
  71         DESTINATION include/vpp_plugins/${name}/${dir}
  72         COMPONENT vpp-dev
  73       )
  74     endforeach()
  75   endif()
  76   if(PLUGIN_API_TEST_SOURCES)
  77     set(test_plugin_name ${name}_test_plugin)
  78     add_library(${test_plugin_name} SHARED ${PLUGIN_API_TEST_SOURCES}
  79                 ${api_includes})
  80     set_target_properties(${test_plugin_name} PROPERTIES NO_SONAME 1)
  81     if(NOT VPP_EXTERNAL_PROJECT)
  82       add_dependencies(${test_plugin_name} api_headers)
  83     endif()
  84     set_target_properties(${test_plugin_name} PROPERTIES
  85       PREFIX ""
  86       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_api_test_plugins)
  87     install(
  88       TARGETS ${test_plugin_name}
  89       DESTINATION lib/vpp_api_test_plugins
  90       COMPONENT ${PLUGIN_COMPONENT}
  91     )
  92   endif()
  93   install(
  94     TARGETS ${plugin_name}
  95     DESTINATION lib/vpp_plugins
  96     COMPONENT ${PLUGIN_COMPONENT}
  97   )
  98 endmacro()
  99
 100 macro(vpp_plugin_find_library plugin var name)
 101   find_library(${var} NAMES ${name} ${ARGN})
 102 if (NOT ${var})
 103   message(WARNING "-- ${name} library not found - ${plugin} plugin disabled")
 104   return()
 105 endif()
 106     message(STATUS "${plugin} plugin needs ${name} library - found at ${${var}}")
 107 endmacro()