src/cmake/plugin.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 macro(add_vpp_plugin name)
  15   cmake_parse_arguments(PLUGIN
  16     ""
  17     "LINK_FLAGS"
  18     "SOURCES;API_FILES;MULTIARCH_SOURCES;LINK_LIBRARIES;API_TEST_SOURCES"
  19     ${ARGN}
  20   )
  21   set(plugin_name ${name}_plugin)
  22   set(api_headers)
  23   foreach(f ${PLUGIN_API_FILES})
  24      vpp_generate_api_header(${f} plugins)
  25      list(APPEND api_headers ${f}.h ${f}.json)
  26   endforeach()
  27   add_library(${plugin_name} SHARED ${PLUGIN_SOURCES} ${api_headers})
  28   add_dependencies(${plugin_name} vpp_version_h api_headers)
  29   set_target_properties(${plugin_name} PROPERTIES
  30     PREFIX ""
  31     LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_plugins)
  32   if(PLUGIN_MULTIARCH_SOURCES)
  33     vpp_library_set_multiarch_sources(${plugin_name} ${PLUGIN_MULTIARCH_SOURCES})
  34   endif()
  35   if(PLUGIN_LINK_LIBRARIES)
  36     target_link_libraries(${plugin_name} ${PLUGIN_LINK_LIBRARIES})
  37   endif()
  38   if(PLUGIN_LINK_FLAGS)
  39     set_target_properties(${plugin_name} PROPERTIES LINK_FLAGS "${PLUGIN_LINK_FLAGS}")
  40   endif()
  41   if(PLUGIN_API_TEST_SOURCES)
  42     set(test_plugin_name ${name}_test_plugin)
  43     add_library(${test_plugin_name} SHARED ${PLUGIN_API_TEST_SOURCES} ${api_headers})
  44     add_dependencies(${test_plugin_name} api_headers)
  45     set_target_properties(${test_plugin_name} PROPERTIES
  46       PREFIX ""
  47       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_api_test_plugins)
  48     install(TARGETS ${test_plugin_name} DESTINATION ${VPP_LIB_DIR_NAME}/vpp_api_test_plugins COMPONENT
  49             plugins)
  50   endif()
  51   install(TARGETS ${plugin_name} DESTINATION ${VPP_LIB_DIR_NAME}/vpp_plugins COMPONENT plugins)
  52 endmacro()
  53