src/cmake/plugin.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 macro(add_vpp_plugin name)
  15   cmake_parse_arguments(PLUGIN
  16     ""
  17     "LINK_FLAGS;COMPONENT;DEV_COMPONENT"
  18     "SOURCES;API_FILES;MULTIARCH_SOURCES;LINK_LIBRARIES;INSTALL_HEADERS;API_TEST_SOURCES"
  19     ${ARGN}
  20   )
  21   set(plugin_name ${name}_plugin)
  22   set(api_includes)
  23   if(NOT PLUGIN_COMPONENT)
  24     set(PLUGIN_COMPONENT vpp-plugin-core)
  25   endif()
  26   if(NOT PLUGIN_DEV_COMPONENT)
  27     if(NOT VPP_EXTERNAL_PROJECT)
  28       set(PLUGIN_DEV_COMPONENT vpp-dev)
  29     else()
  30       set(PLUGIN_DEV_COMPONENT ${PLUGIN_COMPONENT}-dev)
  31     endif()
  32   endif()
  33
  34   file(RELATIVE_PATH rpath ${CMAKE_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR})
  35   foreach(f ${PLUGIN_API_FILES})
  36     get_filename_component(dir ${f} DIRECTORY)
  37     vpp_generate_api_header(${f} plugins ${PLUGIN_COMPONENT})
  38     list(APPEND api_includes ${f}.h ${f}.json)
  39     set_property(GLOBAL APPEND PROPERTY VPP_API_FILES ${rpath}/${f})
  40     install(
  41       FILES ${CMAKE_CURRENT_BINARY_DIR}/${f}.h
  42       ${CMAKE_CURRENT_BINARY_DIR}/${f}_enum.h
  43       ${CMAKE_CURRENT_BINARY_DIR}/${f}_types.h
  44       DESTINATION include/vpp_plugins/${name}/${dir}
  45       COMPONENT ${PLUGIN_DEV_COMPONENT}
  46     )
  47   endforeach()
  48   add_library(${plugin_name} SHARED ${PLUGIN_SOURCES} ${api_includes})
  49   set_target_properties(${plugin_name} PROPERTIES NO_SONAME 1)
  50   if(NOT VPP_EXTERNAL_PROJECT)
  51     add_dependencies(${plugin_name} vpp_version_h api_headers)
  52   endif()
  53   set_target_properties(${plugin_name} PROPERTIES
  54     PREFIX ""
  55     LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_plugins)
  56   if(PLUGIN_MULTIARCH_SOURCES)
  57     vpp_library_set_multiarch_sources(${plugin_name} ${PLUGIN_MULTIARCH_SOURCES})
  58   endif()
  59   if(PLUGIN_LINK_LIBRARIES)
  60     target_link_libraries(${plugin_name} ${PLUGIN_LINK_LIBRARIES})
  61   endif()
  62   if(PLUGIN_LINK_FLAGS)
  63     set_target_properties(${plugin_name} PROPERTIES LINK_FLAGS "${PLUGIN_LINK_FLAGS}")
  64   endif()
  65   if(PLUGIN_INSTALL_HEADERS)
  66     foreach(file ${PLUGIN_INSTALL_HEADERS})
  67       get_filename_component(dir ${file} DIRECTORY)
  68       install(
  69         FILES ${file}
  70         DESTINATION include/vpp_plugins/${name}/${dir}
  71         COMPONENT vpp-dev
  72       )
  73     endforeach()
  74   endif()
  75   if(PLUGIN_API_TEST_SOURCES)
  76     set(test_plugin_name ${name}_test_plugin)
  77     add_library(${test_plugin_name} SHARED ${PLUGIN_API_TEST_SOURCES}
  78                 ${api_includes})
  79     set_target_properties(${test_plugin_name} PROPERTIES NO_SONAME 1)
  80     if(NOT VPP_EXTERNAL_PROJECT)
  81       add_dependencies(${test_plugin_name} api_headers)
  82     endif()
  83     set_target_properties(${test_plugin_name} PROPERTIES
  84       PREFIX ""
  85       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_api_test_plugins)
  86     install(
  87       TARGETS ${test_plugin_name}
  88       DESTINATION lib/vpp_api_test_plugins
  89       COMPONENT ${PLUGIN_COMPONENT}
  90     )
  91   endif()
  92   install(
  93     TARGETS ${plugin_name}
  94     DESTINATION lib/vpp_plugins
  95     COMPONENT ${PLUGIN_COMPONENT}
  96   )
  97 endmacro()
  98
  99 macro(vpp_plugin_find_library plugin var name)
 100   find_library(${var} NAMES ${name} ${ARGN})
 101 if (NOT ${var})
 102   message(WARNING "-- ${name} library not found - ${plugin} plugin disabled")
 103   return()
 104 endif()
 105     message(STATUS "${plugin} plugin needs ${name} library - found at ${${var}}")
 106 endmacro()