src/cmake/plugin.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 macro(add_vpp_plugin name)
  15   cmake_parse_arguments(PLUGIN
  16     ""
  17     "LINK_FLAGS"
  18     "SOURCES;API_FILES;MULTIARCH_SOURCES;LINK_LIBRARIES;API_TEST_SOURCES"
  19     ${ARGN}
  20   )
  21   set(plugin_name ${name}_plugin)
  22   set(api_headers)
  23   file(RELATIVE_PATH rpath ${CMAKE_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR})
  24   foreach(f ${PLUGIN_API_FILES})
  25     vpp_generate_api_header(${f} plugins)
  26     list(APPEND api_headers ${f}.h ${f}.json)
  27     set_property(GLOBAL APPEND PROPERTY VPP_API_FILES ${rpath}/${f})
  28   endforeach()
  29   add_library(${plugin_name} SHARED ${PLUGIN_SOURCES} ${api_headers})
  30   add_dependencies(${plugin_name} vpp_version_h api_headers)
  31   set_target_properties(${plugin_name} PROPERTIES
  32     PREFIX ""
  33     LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_plugins)
  34   if(PLUGIN_MULTIARCH_SOURCES)
  35     vpp_library_set_multiarch_sources(${plugin_name} ${PLUGIN_MULTIARCH_SOURCES})
  36   endif()
  37   if(PLUGIN_LINK_LIBRARIES)
  38     target_link_libraries(${plugin_name} ${PLUGIN_LINK_LIBRARIES})
  39   endif()
  40   if(PLUGIN_LINK_FLAGS)
  41     set_target_properties(${plugin_name} PROPERTIES LINK_FLAGS "${PLUGIN_LINK_FLAGS}")
  42   endif()
  43   if(PLUGIN_API_TEST_SOURCES)
  44     set(test_plugin_name ${name}_test_plugin)
  45     add_library(${test_plugin_name} SHARED ${PLUGIN_API_TEST_SOURCES} ${api_headers})
  46     add_dependencies(${test_plugin_name} api_headers)
  47     set_target_properties(${test_plugin_name} PROPERTIES
  48       PREFIX ""
  49       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_api_test_plugins)
  50     install(TARGETS ${test_plugin_name} DESTINATION ${VPP_LIB_DIR_NAME}/vpp_api_test_plugins COMPONENT
  51             plugins)
  52   endif()
  53   install(TARGETS ${plugin_name} DESTINATION ${VPP_LIB_DIR_NAME}/vpp_plugins COMPONENT plugins)
  54 endmacro()
  55