src/configure.ac

   1 AC_INIT([vpp], [18.01], [vpp-dev@fd.io])
   2 LT_INIT
   3 AC_CONFIG_AUX_DIR([.])
   4 AM_INIT_AUTOMAKE([subdir-objects])
   5 AM_SILENT_RULES([yes])
   6 AC_CONFIG_FILES([Makefile plugins/Makefile vpp-api/python/Makefile vpp-api/java/Makefile vpp-api/vapi/Makefile vpp-api/vom/Makefile])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_PROG_CC
  10 AC_PROG_CXX
  11 AC_PROG_CPP
  12 AM_PROG_AS
  13 AM_PROG_LIBTOOL
  14 AC_PROG_YACC
  15 AM_PATH_PYTHON
  16
  17 AM_CONDITIONAL([CROSSCOMPILE], [test "$cross_compiling" == "yes"])
  18
  19 ###############################################################################
  20 # Macros
  21 ###############################################################################
  22
  23 AC_DEFUN([ENABLE_ARG],
  24 [
  25   AC_ARG_ENABLE($1,
  26     AC_HELP_STRING(patsubst([--enable-$1],[_],[-]), $2),
  27     [enable_$1=yes n_enable_$1=1],
  28     [enable_$1=no n_enable_$1=0])
  29   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  30   m4_append([list_of_enabled], [$1], [, ])
  31 ])
  32
  33 AC_DEFUN([DISABLE_ARG],
  34 [
  35   AC_ARG_ENABLE($1,
  36     AC_HELP_STRING(patsubst([--disable-$1],[_],[-]), $2),
  37     [enable_$1=no n_enable_$1=0],
  38     [enable_$1=yes n_enable_$1=1])
  39   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  40   m4_append([list_of_enabled], [$1], [, ])
  41 ])
  42
  43 AC_DEFUN([WITH_ARG],
  44 [
  45   AC_ARG_WITH($1,
  46     AC_HELP_STRING(patsubst([--with-$1],[_],[-]), $2),
  47     [with_$1=yes n_with_$1=1],
  48     [with_$1=no n_with_$1=0])
  49   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  50   m4_append([list_of_with], [$1], [, ])
  51 ])
  52
  53 AC_DEFUN([WITHOUT_ARG],
  54 [
  55   AC_ARG_WITH($1,
  56     AC_HELP_STRING(patsubst([--without-$1],[_],[-]), $2),
  57     [with_$1=no n_with_$1=0],
  58     [with_$1=yes n_with_$1=1])
  59   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  60   m4_append([list_of_with], [$1], [, ])
  61 ])
  62
  63 AC_DEFUN([PLUGIN_ENABLED],
  64 [
  65    AC_ARG_ENABLE($1_plugin,
  66      AC_HELP_STRING([--disable-$1-plugin], [Do not build $1 plugin]),
  67        [enable_$1_plugin=no],
  68        [enable_$1_plugin=yes ])
  69   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  70   m4_append([list_of_plugins], [$1], [, ])
  71 ])
  72
  73 AC_DEFUN([PLUGIN_DISABLED],
  74 [
  75    AC_ARG_ENABLE($1_plugin,
  76      AC_HELP_STRING([--enable-$1-plugin], [Build $1 plugin]),
  77        [enable_$1_plugin=yes ],
  78        [enable_$1_plugin=no])
  79   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  80   m4_append([list_of_plugins], [$1], [, ])
  81 ])
  82
  83 AC_DEFUN([PRINT_VAL], [ AC_MSG_RESULT(AC_HELP_STRING($1,$2)) ])
  84
  85 AC_DEFUN([DPDK_IS_PMD_ENABLED],
  86 [
  87   AC_MSG_CHECKING([for $1 in rte_config.h])
  88   AC_COMPILE_IFELSE(
  89     [AC_LANG_PROGRAM(
  90       [[#include <rte_config.h>]],
  91       [[return RTE_$1;]],
  92     )],
  93     [with_$2=yes]
  94     [AC_MSG_RESULT([yes])],
  95     [with_$2=no]
  96     [AC_MSG_RESULT([no])]
  97   )
  98   AM_CONDITIONAL(m4_toupper(WITH_$2), test "$with_$2" = "yes")
  99   m4_append_uniq([list_of_with], [$2], [, ])
 100 ])
 101
 102 # Check if compiler supports specific flag
 103 AC_DEFUN([CC_CHECK_FLAG],
 104 [
 105   AC_MSG_CHECKING([if $CC supports $1])
 106   AC_LANG_PUSH([C])
 107   ac_saved_cflags="$CFLAGS"
 108   CFLAGS="-Werror $1"
 109   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 110   [cc_flag_check=yes],
 111   [cc_flag_check=no]
 112 )
 113   AC_MSG_RESULT([$cc_flag_check])
 114   CFLAGS="$ac_saved_cflags"
 115   AC_LANG_POP([C])
 116 ])
 117
 118 ###############################################################################
 119 # configure arguments
 120 ###############################################################################
 121
 122 # --enable-X
 123 ENABLE_ARG(tests,       [Enable unit tests])
 124 ENABLE_ARG(dpdk_shared, [Enable unit tests])
 125 ENABLE_ARG(perftool,    [Enable perftool])
 126 ENABLE_ARG(g2,          [Enable g2])
 127
 128 # --disable-X
 129 DISABLE_ARG(vlib,       [Disable vlib and dependant libs and binaries])
 130 DISABLE_ARG(svm,        [Disable svm and dependant libs and binaries])
 131 DISABLE_ARG(papi,       [Disable Python API bindings])
 132 DISABLE_ARG(japi,       [Disable Java API bindings])
 133 DISABLE_ARG(vom,        [Disable VPP object model bindings])
 134
 135 # --with-X
 136
 137 # --without-X
 138 WITHOUT_ARG(libssl,     [Disable libssl])
 139 WITHOUT_ARG(apicli,     [Disable binary api CLI])
 140
 141 AC_ARG_WITH(unix,
 142             AC_HELP_STRING([--with-unix],[Compile unix version of clib]),
 143             [],
 144             [case $host_os in
 145               darwin* | linux*) with_unix=yes;;
 146               *) with_unix=no;;
 147               esac])
 148
 149 AM_CONDITIONAL(WITH_UNIX, test "$with_unix" = "yes")
 150
 151 AC_ARG_WITH(pre-data,
 152             AC_HELP_STRING([--with-pre-data],[Set buffer rewrite space]),
 153             [case $with_pre_data in
 154                128) ;;
 155                256) ;;
 156                *) with_pre_data="pre-data-not-set" ;;
 157              esac], [with_pre_data=128])
 158
 159 ###############################################################################
 160 # Target CPU flags
 161 ###############################################################################
 162
 163 # Check if compiler supports march=core-avx2
 164 CC_CHECK_FLAG("-march=core-avx2")
 165 AS_IF([test "$cc_flag_check" = yes],
 166       [march_core_avx2=yes],
 167       [march_core_avx2=no])
 168 AM_CONDITIONAL([CC_SUPPORTS_AVX2], [test "$march_core_avx2" = "yes"])
 169
 170 # Check if compiler supports march=skylake-avx512
 171 CC_CHECK_FLAG("-march=skylake-avx512")
 172 AS_IF([test "$cc_flag_check" = yes],
 173   [march_skylake_avx512=yes],
 174   [march_skylake_avx512=no])
 175 AM_CONDITIONAL([CC_SUPPORTS_AVX512], [test "$march_skylake_avx512" = "yes"])
 176
 177 AS_CASE([$build_cpu],
 178         [x86_64], [CPU_FLAGS="-march=corei7 -mtune=corei7-avx"],
 179         [aarch64], [CPU_FLAGS="-march=armv8-a+crc"],
 180         [CPU_FLAGS=""],
 181 )
 182 AC_SUBST([CPU_FLAGS])
 183
 184 AC_SUBST([CPU_AVX2_FLAGS],"-march=core-avx2 -mtune=core-avx2")
 185 AC_SUBST([CPU_AVX512_FLAGS],"-march=skylake-avx512 -mtune=skylake-avx512")
 186
 187 AM_CONDITIONAL([CPU_X86_64], [test "$build_cpu" = "x86_64"])
 188 AM_CONDITIONAL([CPU_AARCH64], [test "$build_cpu" = "aarch64"])
 189
 190 ###############################################################################
 191 # Substitutions and defines
 192 ###############################################################################
 193
 194 AC_SUBST(PRE_DATA_SIZE,         [$with_pre_data])
 195 AC_SUBST(APICLI,                [-DVPP_API_TEST_BUILTIN=${n_with_apicli}])
 196
 197 AC_DEFINE_UNQUOTED(DPDK_SHARED_LIB,     [${n_enable_dpdk_shared}])
 198 AC_DEFINE_UNQUOTED(WITH_LIBSSL,         [${n_with_libssl}])
 199
 200
 201 # Silence following noise:
 202 # ar: `u' modifier ignored since `D' is the default (see `U')
 203 AR_FLAGS=cr
 204 AC_SUBST(AR_FLAGS)
 205
 206 ###############################################################################
 207 # Plugins
 208 ###############################################################################
 209
 210 # Please keep alphabetical order
 211 PLUGIN_ENABLED(acl)
 212 PLUGIN_ENABLED(dpdk)
 213 PLUGIN_ENABLED(flowprobe)
 214 PLUGIN_ENABLED(gtpu)
 215 PLUGIN_ENABLED(ila)
 216 PLUGIN_ENABLED(ioam)
 217 PLUGIN_ENABLED(ixge)
 218 PLUGIN_ENABLED(kubeproxy)
 219 PLUGIN_ENABLED(lb)
 220 PLUGIN_ENABLED(memif)
 221 PLUGIN_ENABLED(pppoe)
 222 PLUGIN_ENABLED(sixrd)
 223 PLUGIN_ENABLED(nat)
 224 PLUGIN_ENABLED(stn)
 225 PLUGIN_ENABLED(l2e)
 226
 227 ###############################################################################
 228 # Dependency checks
 229 ###############################################################################
 230
 231 AM_COND_IF([ENABLE_DPDK_SHARED],
 232 [
 233   AC_CHECK_HEADERS([rte_config.h],
 234     [],
 235     [AC_MSG_ERROR([DPDK header files not found])],)
 236   AC_CHECK_LIB( [dpdk], [rte_eal_init],
 237     [],
 238     [AC_MSG_ERROR([DPDK shared library not found])],)
 239 ])
 240
 241 with_aesni_mb_lib=no
 242 with_isa_l_crypto_lib=no
 243
 244 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_MB, dpdk_aesni_mb_pmd)
 245 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_GCM, dpdk_aesni_gcm_pmd)
 246
 247 AM_COND_IF([WITH_DPDK_AESNI_MB_PMD],
 248 [
 249   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 250                [with_aesni_mb_lib=yes],
 251                [AC_MSG_ERROR([IPSec_MB library not found])])
 252 ])
 253
 254 AM_COND_IF([WITH_DPDK_AESNI_GCM_PMD],
 255 [
 256   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 257     [with_aesni_mb_lib=yes],
 258     [AC_MSG_ERROR([IPSec_MB library not found])])
 259 ])
 260
 261 m4_append([list_of_with], [aesni_mb_lib], [, ])
 262 AM_CONDITIONAL(WITH_AESNI_MB_LIB, test "$with_aesni_mb_lib" = "yes")
 263
 264 m4_append([list_of_with], [isa_l_crypto_lib], [, ])
 265 AM_CONDITIONAL(WITH_ISA_L_CRYPTO_LIB, test "$with_isa_l_crypto_lib" = "yes")
 266
 267
 268 with_ibverbs_lib=no
 269 DPDK_IS_PMD_ENABLED(LIBRTE_MLX4_PMD, dpdk_mlx4_pmd)
 270 AM_COND_IF([WITH_DPDK_MLX4_PMD],
 271 [
 272   AC_CHECK_LIB([ibverbs], [ibv_fork_init],
 273                [with_ibverbs_lib=yes],
 274                [AC_MSG_ERROR([ibverbs library not found])])
 275 ])
 276
 277 DPDK_IS_PMD_ENABLED(LIBRTE_MLX5_PMD, dpdk_mlx5_pmd)
 278 AM_COND_IF([WITH_DPDK_MLX5_PMD],
 279 [
 280   AC_CHECK_LIB([ibverbs], [ibv_fork_init],
 281                [with_ibverbs_lib=yes],
 282                [AC_MSG_ERROR([ibverbs library not found])])
 283 ])
 284
 285 m4_append([list_of_with], [ibverbs_lib], [, ])
 286 AM_CONDITIONAL(WITH_IBVERBS_LIB, test "$with_ibverbs_lib" = "yes")
 287
 288
 289 AM_COND_IF([ENABLE_G2],
 290 [
 291   PKG_CHECK_MODULES(g2, gtk+-2.0)
 292 ])
 293
 294 # If cross-compiling, we need external vppapigen and we cannot continue without it
 295 # For native builds, we just set dependency on vpppaigen binary in top_builddir
 296 AM_COND_IF([CROSSCOMPILE],
 297 [
 298   AC_PATH_PROG([VPPAPIGEN], [vppapigen], [no])
 299   if test "$VPPAPIGEN" = "no"; then
 300     AC_MSG_ERROR([Externaly built vppapigen is needed when cross-compiling...])
 301   fi
 302 ],[
 303   VPPAPIGEN=\$\(top_builddir\)/vppapigen
 304 ])
 305 AC_SUBST([VPPAPIGEN])
 306
 307
 308 ###############################################################################
 309 # JAVA
 310 ###############################################################################
 311
 312 AM_COND_IF([ENABLE_JAPI],
 313 [
 314   AX_VPP_FIND_JDK8
 315   AC_SUBST(JAVA_HOME)
 316   AC_SUBST(JAVAC)
 317   AC_SUBST(JAVAH)
 318   AC_SUBST(JAR)
 319 ])
 320
 321 ###############################################################################
 322 # PYTHON
 323 ###############################################################################
 324
 325 AM_COND_IF([ENABLE_PAPI],
 326 [
 327   AM_PATH_PYTHON
 328 ])
 329
 330 ###############################################################################
 331 # Output
 332 ###############################################################################
 333
 334 AC_OUTPUT
 335
 336 AC_MSG_RESULT([==============================================================================])
 337 PRINT_VAL([version], $PACKAGE $VERSION)
 338 PRINT_VAL([prefix], ${prefix})
 339 PRINT_VAL([libdir], ${libdir})
 340 PRINT_VAL([includedir], ${includedir})
 341 PRINT_VAL([CFLAGS], ${CFLAGS})
 342 PRINT_VAL([CPPFLAGS], ${CPPFLAGS})
 343 PRINT_VAL([LDFLAGS], ${LDFLAGS})
 344 AM_COND_IF([ENABLE_JAPI],
 345 [
 346   PRINT_VAL([JAVA_VERSION], ${JAVA_VERSION})
 347   PRINT_VAL([JAVA_HOME], ${JAVA_HOME})
 348 ])
 349
 350 AC_MSG_RESULT([])
 351 AC_MSG_RESULT([with:])
 352 m4_foreach([x], m4_dquote(list_of_with), [
 353   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${with_], x, [}])))
 354 ])
 355
 356 AC_MSG_RESULT([])
 357 AC_MSG_RESULT([enabled:])
 358 m4_foreach([x], m4_dquote(list_of_enabled), [
 359   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [}])))
 360 ])
 361
 362 AC_MSG_RESULT([])
 363 AC_MSG_RESULT([plugins:])
 364 m4_foreach([x], m4_dquote(list_of_plugins), [
 365   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [_plugin}])))
 366 ])
 367 AC_MSG_RESULT([==============================================================================])
 368
 369