src/configure.ac

   1 AC_INIT([vpp], [18.07], [vpp-dev@fd.io])
   2 LT_INIT
   3 AC_CONFIG_AUX_DIR([.])
   4 AM_INIT_AUTOMAKE([subdir-objects])
   5 AM_SILENT_RULES([yes])
   6 AC_CONFIG_FILES([Makefile plugins/Makefile vpp-api/python/Makefile vpp-api/java/Makefile vpp-api/vapi/Makefile])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_PROG_CC
  10 AC_PROG_CPP
  11 AM_PROG_AS
  12 AM_PROG_LIBTOOL
  13 AM_PATH_PYTHON
  14
  15 AM_CONDITIONAL([CROSSCOMPILE], [test "$cross_compiling" == "yes"])
  16
  17 ###############################################################################
  18 # Macros
  19 ###############################################################################
  20
  21 AC_DEFUN([ENABLE_ARG],
  22 [
  23   AC_ARG_ENABLE($1,
  24     AC_HELP_STRING(patsubst([--enable-$1],[_],[-]), $2),
  25     [enable_$1=yes n_enable_$1=1],
  26     [enable_$1=no n_enable_$1=0])
  27   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  28   m4_append([list_of_enabled], [$1], [, ])
  29 ])
  30
  31 AC_DEFUN([DISABLE_ARG],
  32 [
  33   AC_ARG_ENABLE($1,
  34     AC_HELP_STRING(patsubst([--disable-$1],[_],[-]), $2),
  35     [enable_$1=no n_enable_$1=0],
  36     [enable_$1=yes n_enable_$1=1])
  37   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  38   m4_append([list_of_enabled], [$1], [, ])
  39 ])
  40
  41 AC_DEFUN([WITH_ARG],
  42 [
  43   AC_ARG_WITH($1,
  44     AC_HELP_STRING(patsubst([--with-$1],[_],[-]), $2),
  45     [with_$1=yes n_with_$1=1],
  46     [with_$1=no n_with_$1=0])
  47   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  48   m4_append([list_of_with], [$1], [, ])
  49 ])
  50
  51 AC_DEFUN([WITHOUT_ARG],
  52 [
  53   AC_ARG_WITH($1,
  54     AC_HELP_STRING(patsubst([--without-$1],[_],[-]), $2),
  55     [with_$1=no n_with_$1=0],
  56     [with_$1=yes n_with_$1=1])
  57   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  58   m4_append([list_of_with], [$1], [, ])
  59 ])
  60
  61 AC_DEFUN([PLUGIN_ENABLED],
  62 [
  63    AC_ARG_ENABLE($1_plugin,
  64      AC_HELP_STRING([--disable-$1-plugin], [Do not build $1 plugin]),
  65        [enable_$1_plugin=no],
  66        [enable_$1_plugin=yes ])
  67   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  68   m4_append([list_of_plugins], [$1], [, ])
  69 ])
  70
  71 AC_DEFUN([PLUGIN_DISABLED],
  72 [
  73    AC_ARG_ENABLE($1_plugin,
  74      AC_HELP_STRING([--enable-$1-plugin], [Build $1 plugin]),
  75        [enable_$1_plugin=yes ],
  76        [enable_$1_plugin=no])
  77   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  78   m4_append([list_of_plugins], [$1], [, ])
  79 ])
  80
  81 AC_DEFUN([PRINT_VAL], [ AC_MSG_RESULT(AC_HELP_STRING($1,$2)) ])
  82
  83 AC_DEFUN([DPDK_IS_PMD_ENABLED],
  84 [
  85   AC_MSG_CHECKING([for $1 in rte_config.h])
  86   AC_COMPILE_IFELSE(
  87     [AC_LANG_PROGRAM(
  88       [[#include <rte_config.h>]],
  89       [[return RTE_$1;]],
  90     )],
  91     [with_$2=yes]
  92     [AC_MSG_RESULT([yes])],
  93     [with_$2=no]
  94     [AC_MSG_RESULT([no])]
  95   )
  96   AM_CONDITIONAL(m4_toupper(WITH_$2), test "$with_$2" = "yes")
  97   m4_append_uniq([list_of_with], [$2], [, ])
  98 ])
  99
 100 # Check if compiler supports specific flag
 101 AC_DEFUN([CC_CHECK_FLAG],
 102 [
 103   AC_MSG_CHECKING([if $CC supports $1])
 104   AC_LANG_PUSH([C])
 105   ac_saved_cflags="$CFLAGS"
 106   CFLAGS="-Werror $1"
 107   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 108   [cc_flag_check=yes],
 109   [cc_flag_check=no]
 110 )
 111   AC_MSG_RESULT([$cc_flag_check])
 112   CFLAGS="$ac_saved_cflags"
 113   AC_LANG_POP([C])
 114 ])
 115
 116 ###############################################################################
 117 # configure arguments
 118 ###############################################################################
 119
 120 # --enable-X
 121 ENABLE_ARG(tests,       [Enable unit tests])
 122 ENABLE_ARG(dpdk_shared, [Enable unit tests])
 123 ENABLE_ARG(perftool,    [Enable perftool])
 124 ENABLE_ARG(g2,          [Enable g2])
 125
 126 # --disable-X
 127 DISABLE_ARG(vlib,       [Disable vlib and dependant libs and binaries])
 128 DISABLE_ARG(svm,        [Disable svm and dependant libs and binaries])
 129 DISABLE_ARG(papi,       [Disable Python API bindings])
 130 DISABLE_ARG(japi,       [Disable Java API bindings])
 131
 132 # --with-X
 133
 134 # --without-X
 135 WITHOUT_ARG(libssl,     [Disable libssl])
 136 WITHOUT_ARG(apicli,     [Disable binary api CLI])
 137 WITHOUT_ARG(mbedtls,    [Disable mbedtls])
 138
 139 AC_ARG_WITH(unix,
 140             AC_HELP_STRING([--with-unix],[Compile unix version of clib]),
 141             [],
 142             [case $host_os in
 143               darwin* | linux*) with_unix=yes;;
 144               *) with_unix=no;;
 145               esac])
 146
 147 AM_CONDITIONAL(WITH_UNIX, test "$with_unix" = "yes")
 148
 149 AC_ARG_WITH(pre-data,
 150             AC_HELP_STRING([--with-pre-data],[Set buffer rewrite space]),
 151             [case $with_pre_data in
 152                128) ;;
 153                256) ;;
 154                *) with_pre_data="pre-data-not-set" ;;
 155              esac], [with_pre_data=128])
 156
 157 ###############################################################################
 158 # Target CPU flags
 159 ###############################################################################
 160
 161 # Check if compiler supports march=core-avx2
 162 CC_CHECK_FLAG("-march=core-avx2")
 163 AS_IF([test "$cc_flag_check" = yes],
 164       [march_core_avx2=yes],
 165       [march_core_avx2=no])
 166 AM_CONDITIONAL([CC_SUPPORTS_AVX2], [test "$march_core_avx2" = "yes"])
 167
 168 # Check if compiler supports march=skylake-avx512
 169 CC_CHECK_FLAG("-march=skylake-avx512")
 170 AS_IF([test "$cc_flag_check" = yes],
 171   [march_skylake_avx512=yes],
 172   [march_skylake_avx512=no])
 173 AM_CONDITIONAL([CC_SUPPORTS_AVX512], [test "$march_skylake_avx512" = "yes"])
 174
 175 AS_CASE([$build_cpu],
 176         [x86_64], [CPU_FLAGS="-march=corei7 -mtune=corei7-avx"],
 177         [aarch64], [CPU_FLAGS="-march=armv8-a+crc"],
 178         [CPU_FLAGS=""],
 179 )
 180 AC_SUBST([CPU_FLAGS])
 181
 182 AC_SUBST([CPU_AVX2_FLAGS],"-march=core-avx2 -mtune=core-avx2")
 183 AC_SUBST([CPU_AVX512_FLAGS],"-march=skylake-avx512 -mtune=skylake-avx512")
 184
 185 AM_CONDITIONAL([CPU_X86_64], [test "$build_cpu" = "x86_64"])
 186 AM_CONDITIONAL([CPU_AARCH64], [test "$build_cpu" = "aarch64"])
 187
 188 ###############################################################################
 189 # misc compiler flags
 190 ###############################################################################
 191
 192 CC_CHECK_FLAG("-Wno-address-of-packed-member")
 193 AS_IF([test "$cc_flag_check" = yes],
 194         [CFLAGS="${CFLAGS} -Wno-address-of-packed-member"], [])
 195
 196 ###############################################################################
 197 # Substitutions and defines
 198 ###############################################################################
 199
 200 AC_SUBST(PRE_DATA_SIZE,         [$with_pre_data])
 201 AC_SUBST(APICLI,                [-DVPP_API_TEST_BUILTIN=${n_with_apicli}])
 202
 203 AC_DEFINE_UNQUOTED(DPDK_SHARED_LIB,     [${n_enable_dpdk_shared}])
 204 AC_DEFINE_UNQUOTED(WITH_LIBSSL,         [${n_with_libssl}])
 205 AC_DEFINE_UNQUOTED(WITH_MBEDTLS,        [${n_with_mbedtls}])
 206
 207
 208 # Silence following noise:
 209 # ar: `u' modifier ignored since `D' is the default (see `U')
 210 AR_FLAGS=cr
 211 AC_SUBST(AR_FLAGS)
 212
 213 ###############################################################################
 214 # Plugins
 215 ###############################################################################
 216
 217 # Please keep alphabetical order
 218 PLUGIN_ENABLED(abf)
 219 PLUGIN_ENABLED(acl)
 220 PLUGIN_ENABLED(avf)
 221 PLUGIN_ENABLED(cdp)
 222 PLUGIN_ENABLED(dpdk)
 223 PLUGIN_ENABLED(flowprobe)
 224 PLUGIN_ENABLED(gbp)
 225 PLUGIN_ENABLED(gtpu)
 226 PLUGIN_ENABLED(igmp)
 227 PLUGIN_ENABLED(ila)
 228 PLUGIN_ENABLED(ioam)
 229 PLUGIN_ENABLED(ixge)
 230 PLUGIN_ENABLED(kubeproxy)
 231 PLUGIN_ENABLED(l2e)
 232 PLUGIN_ENABLED(lacp)
 233 PLUGIN_ENABLED(lb)
 234 PLUGIN_ENABLED(marvell)
 235 PLUGIN_ENABLED(memif)
 236 PLUGIN_ENABLED(pppoe)
 237 PLUGIN_ENABLED(nat)
 238 PLUGIN_ENABLED(srv6ad)
 239 PLUGIN_ENABLED(srv6am)
 240 PLUGIN_ENABLED(srv6as)
 241 PLUGIN_ENABLED(stn)
 242 PLUGIN_ENABLED(tlsmbedtls)
 243 PLUGIN_ENABLED(tlsopenssl)
 244
 245 ###############################################################################
 246 # Dependency checks
 247 ###############################################################################
 248 AC_CHECK_FUNC([memfd_create], [AC_DEFINE([HAVE_MEMFD_CREATE], [1], [Define if memfd exists])])
 249
 250 AM_COND_IF([ENABLE_DPDK_SHARED],
 251 [
 252   AC_CHECK_HEADERS([rte_config.h],
 253     [],
 254     [AC_MSG_ERROR([DPDK header files not found])],)
 255   AC_CHECK_LIB( [dpdk], [rte_eal_init],
 256     [],
 257     [AC_MSG_ERROR([DPDK shared library not found])],)
 258 ])
 259
 260 with_aesni_mb_lib=no
 261 with_isa_l_crypto_lib=no
 262
 263 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_MB, dpdk_aesni_mb_pmd)
 264 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_GCM, dpdk_aesni_gcm_pmd)
 265
 266 AM_COND_IF([WITH_DPDK_AESNI_MB_PMD],
 267 [
 268   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 269                [with_aesni_mb_lib=yes],
 270                [AC_MSG_ERROR([IPSec_MB library not found])])
 271 ])
 272
 273 AM_COND_IF([WITH_DPDK_AESNI_GCM_PMD],
 274 [
 275   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 276     [with_aesni_mb_lib=yes],
 277     [AC_MSG_ERROR([IPSec_MB library not found])])
 278 ])
 279
 280 m4_append([list_of_with], [aesni_mb_lib], [, ])
 281 AM_CONDITIONAL(WITH_AESNI_MB_LIB, test "$with_aesni_mb_lib" = "yes")
 282
 283 m4_append([list_of_with], [isa_l_crypto_lib], [, ])
 284 AM_CONDITIONAL(WITH_ISA_L_CRYPTO_LIB, test "$with_isa_l_crypto_lib" = "yes")
 285
 286 AM_COND_IF([ENABLE_G2],
 287 [
 288   PKG_CHECK_MODULES(g2, gtk+-2.0)
 289 ])
 290
 291 AM_COND_IF([ENABLE_MARVELL_PLUGIN],
 292 [
 293   AC_CHECK_LIB( [musdk], [pp2_init],
 294     [],
 295     [
 296       AC_MSG_WARN([Marvell MUSDK library with PP2 support not found. Plugin disabled.])
 297       enable_marvell_plugin=no
 298       AM_CONDITIONAL(ENABLE_MARVELL_PLUGIN, false)
 299     ])
 300 ])
 301
 302 AM_COND_IF([WITH_MBEDTLS], [],
 303 [
 304   AC_MSG_WARN([mbedtls not enabled. Disabling tlsmbedtls plugin])
 305   enable_tlsmbedtls_plugin=no
 306   AM_CONDITIONAL(ENABLE_TLSMBEDTLS_PLUGIN, false)
 307 ])
 308
 309 AM_COND_IF([ENABLE_TLSMBEDTLS_PLUGIN],
 310 [
 311   AC_CHECK_HEADERS([mbedtls/ssl.h], [],
 312     [
 313       AC_MSG_WARN([mbedtls headers not found. TLS engine implementation disabled])
 314       enable_tlsmbedtls_plugin=no
 315       AM_CONDITIONAL(ENABLE_TLSMBEDTLS_PLUGIN, false)
 316     ], [])
 317 ])
 318
 319 AM_COND_IF([WITH_LIBSSL], [],
 320 [
 321   AC_MSG_WARN([openssl not enabled. Disabling tlsopenssl plugin])
 322   enable_tlsopenssl_plugin=no
 323   AM_CONDITIONAL(ENABLE_TLSOPENSSL_PLUGIN, false)
 324 ])
 325
 326 ###############################################################################
 327 # JAVA
 328 ###############################################################################
 329
 330 AM_COND_IF([ENABLE_JAPI],
 331 [
 332   AX_VPP_FIND_JDK8
 333   AC_SUBST(JAVA_HOME)
 334   AC_SUBST(JAVAC)
 335   AC_SUBST(JAVAH)
 336   AC_SUBST(JAR)
 337 ])
 338
 339 ###############################################################################
 340 # PYTHON
 341 ###############################################################################
 342
 343 AM_COND_IF([ENABLE_PAPI],
 344 [
 345   AM_PATH_PYTHON
 346 ])
 347
 348 ###############################################################################
 349 # Output
 350 ###############################################################################
 351
 352 AC_OUTPUT
 353
 354 AC_MSG_RESULT([==============================================================================])
 355 PRINT_VAL([version], $PACKAGE $VERSION)
 356 PRINT_VAL([prefix], ${prefix})
 357 PRINT_VAL([libdir], ${libdir})
 358 PRINT_VAL([includedir], ${includedir})
 359 PRINT_VAL([CFLAGS], ${CFLAGS})
 360 PRINT_VAL([CPPFLAGS], ${CPPFLAGS})
 361 PRINT_VAL([LDFLAGS], ${LDFLAGS})
 362 AM_COND_IF([ENABLE_JAPI],
 363 [
 364   PRINT_VAL([JAVA_VERSION], ${JAVA_VERSION})
 365   PRINT_VAL([JAVA_HOME], ${JAVA_HOME})
 366 ])
 367
 368 AC_MSG_RESULT([])
 369 AC_MSG_RESULT([with:])
 370 m4_foreach([x], m4_dquote(list_of_with), [
 371   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${with_], x, [}])))
 372 ])
 373
 374 AC_MSG_RESULT([])
 375 AC_MSG_RESULT([enabled:])
 376 m4_foreach([x], m4_dquote(list_of_enabled), [
 377   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [}])))
 378 ])
 379
 380 AC_MSG_RESULT([])
 381 AC_MSG_RESULT([plugins:])
 382 m4_foreach([x], m4_dquote(list_of_plugins), [
 383   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [_plugin}])))
 384 ])
 385 AC_MSG_RESULT([==============================================================================])
 386
 387