src/configure.ac

   1 AC_INIT([vpp], [18.07], [vpp-dev@fd.io])
   2 LT_INIT
   3 AC_CONFIG_AUX_DIR([.])
   4 AM_INIT_AUTOMAKE([subdir-objects])
   5 AM_SILENT_RULES([yes])
   6 AC_CONFIG_FILES([ \
   7   Makefile \
   8   plugins/Makefile \
   9   vpp-api/python/Makefile \
  10   vpp-api/java/Makefile \
  11   vpp-api/vapi/Makefile \
  12   vlib/config.h \
  13 ])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AC_PROG_CC
  17 AC_PROG_CPP
  18 AM_PROG_AS
  19 AM_PROG_LIBTOOL
  20 AM_PATH_PYTHON
  21
  22 AM_CONDITIONAL([CROSSCOMPILE], [test "$cross_compiling" == "yes"])
  23
  24 ###############################################################################
  25 # Macros
  26 ###############################################################################
  27
  28 AC_DEFUN([ENABLE_ARG],
  29 [
  30   AC_ARG_ENABLE($1,
  31     AC_HELP_STRING(patsubst([--enable-$1],[_],[-]), $2),
  32     [enable_$1=yes n_enable_$1=1],
  33     [enable_$1=no n_enable_$1=0])
  34   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  35   m4_append([list_of_enabled], [$1], [, ])
  36 ])
  37
  38 AC_DEFUN([DISABLE_ARG],
  39 [
  40   AC_ARG_ENABLE($1,
  41     AC_HELP_STRING(patsubst([--disable-$1],[_],[-]), $2),
  42     [enable_$1=no n_enable_$1=0],
  43     [enable_$1=yes n_enable_$1=1])
  44   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  45   m4_append([list_of_enabled], [$1], [, ])
  46 ])
  47
  48 AC_DEFUN([WITH_ARG],
  49 [
  50   AC_ARG_WITH($1,
  51     AC_HELP_STRING(patsubst([--with-$1],[_],[-]), $2),
  52     [with_$1=yes n_with_$1=1],
  53     [with_$1=no n_with_$1=0])
  54   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  55   m4_append([list_of_with], [$1], [, ])
  56 ])
  57
  58 AC_DEFUN([WITHOUT_ARG],
  59 [
  60   AC_ARG_WITH($1,
  61     AC_HELP_STRING(patsubst([--without-$1],[_],[-]), $2),
  62     [with_$1=no n_with_$1=0],
  63     [with_$1=yes n_with_$1=1])
  64   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  65   m4_append([list_of_with], [$1], [, ])
  66 ])
  67
  68 AC_DEFUN([PLUGIN_ENABLED],
  69 [
  70    AC_ARG_ENABLE($1_plugin,
  71      AC_HELP_STRING([--disable-$1-plugin], [Do not build $1 plugin]),
  72        [enable_$1_plugin=no],
  73        [enable_$1_plugin=yes ])
  74   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  75   m4_append([list_of_plugins], [$1], [, ])
  76 ])
  77
  78 AC_DEFUN([PLUGIN_DISABLED],
  79 [
  80    AC_ARG_ENABLE($1_plugin,
  81      AC_HELP_STRING([--enable-$1-plugin], [Build $1 plugin]),
  82        [enable_$1_plugin=yes ],
  83        [enable_$1_plugin=no])
  84   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  85   m4_append([list_of_plugins], [$1], [, ])
  86 ])
  87
  88 AC_DEFUN([PRINT_VAL], [ AC_MSG_RESULT(AC_HELP_STRING($1,$2)) ])
  89
  90 AC_DEFUN([DPDK_IS_PMD_ENABLED],
  91 [
  92   AC_MSG_CHECKING([for $1 in rte_config.h])
  93   AC_COMPILE_IFELSE(
  94     [AC_LANG_PROGRAM(
  95       [[#include <rte_config.h>]],
  96       [[return RTE_$1;]],
  97     )],
  98     [with_$2=yes]
  99     [AC_MSG_RESULT([yes])],
 100     [with_$2=no]
 101     [AC_MSG_RESULT([no])]
 102   )
 103   AM_CONDITIONAL(m4_toupper(WITH_$2), test "$with_$2" = "yes")
 104   m4_append_uniq([list_of_with], [$2], [, ])
 105 ])
 106
 107 # Check if compiler supports specific flag
 108 AC_DEFUN([CC_CHECK_FLAG],
 109 [
 110   AC_MSG_CHECKING([if $CC supports $1])
 111   AC_LANG_PUSH([C])
 112   ac_saved_cflags="$CFLAGS"
 113   CFLAGS="-Werror $1"
 114   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 115   [cc_flag_check=yes],
 116   [cc_flag_check=no]
 117 )
 118   AC_MSG_RESULT([$cc_flag_check])
 119   CFLAGS="$ac_saved_cflags"
 120   AC_LANG_POP([C])
 121 ])
 122
 123 # This function deduces the BUILD HOST cache-line size by
 124 # inspecting /sys and/or /proc depending on the kernel / arch in use
 125 as_fn_log2_cache_line_size_p()
 126 {
 127   sysfs_cache_path="/sys/devices/system/cpu/cpu0/cache/index0/coherency_line_size"
 128   m4_define([read_cache_line_size_from_sysfs], [`head -n 1 $1`])
 129   m4_define([read_midr_implementer],
 130             [`awk '/implementer/ {print $[]4;exit}' /proc/cpuinfo`])
 131   m4_define([read_midr_cpuid],
 132             [`awk '/part/ {print $[]4;exit}' /proc/cpuinfo`])
 133
 134   #Check if sysfs path exists,to ignore warning, else do manual mapping
 135   AC_CHECK_FILE($sysfs_cache_path,
 136     [
 137       cache_line_size=read_cache_line_size_from_sysfs($sysfs_cache_path);
 138       if test $cache_line_size = "32"  ; then
 139           log2_cache_line_size="5";
 140       elif test $cache_line_size = "64"  ; then
 141           log2_cache_line_size="6";
 142       elif test $cache_line_size = "128"  ; then
 143           log2_cache_line_size="7";
 144       fi
 145       AC_MSG_NOTICE([cache_line_size/log2_cache_line_size deduced as $cache_line_size/$log2_cache_line_size])
 146     ],
 147     [
 148         #Define Implementer Ids here
 149         implementer_id_cavium=0x43
 150
 151         #Define CPU Ids here
 152         cpu_id_cavium_thunderx_cn88xx=0x0a1
 153         cpu_id_cavium_thunderx2_cn99xx=0x0af
 154
 155         implementer=read_midr_implementer()
 156         cpuid=read_midr_cpuid()
 157
 158         AC_MSG_CHECKING([for implementerid/cpuid to set log2_cache_line_size])
 159
 160         # Switch case to map log2_cache_line_size for implementer/cpuid combination.
 161         # Default case of Switch sets log2_cache_line_size to 6
 162         AS_CASE($implementer,
 163               #Switch Case for Cavium SoC's
 164               [$implementer_id_cavium],
 165                   [AS_CASE($cpuid,
 166                       #Only ThunderX2 is 64B. Remaining chips are 128B
 167                       [$cpu_id_cavium_thunderx2_cn99xx],
 168                             [AC_MSG_RESULT([Cavium/ThunderX2]);log2_cache_line_size=6],
 169                       [$cpu_id_cavium_thunderx_cn88xx],
 170                             [AC_MSG_RESULT([Cavium/ThunderX]);log2_cache_line_size=7],
 171                       [log2_cache_line_size=7;AC_MSG_RESULT([Cavium/OCTEONTx($cpuid)])]
 172                    )],
 173               #Add implementer specific case here:
 174
 175               #Default case: 64B for all SoC's
 176               [log2_cache_line_size=6;AC_MSG_RESULT([$implementer/$cpuid])]
 177         )
 178       AC_MSG_NOTICE([log2_cache_line_size deduced as $log2_cache_line_size])
 179     ]
 180   )
 181   echo $log2_cache_line_size
 182 }
 183
 184 ###############################################################################
 185 # configure arguments
 186 ###############################################################################
 187
 188 # --enable-X
 189 ENABLE_ARG(tests,       [Enable unit tests])
 190 ENABLE_ARG(dpdk_shared, [Enable unit tests])
 191 ENABLE_ARG(perftool,    [Enable perftool])
 192 ENABLE_ARG(g2,          [Enable g2])
 193
 194 # --disable-X
 195 DISABLE_ARG(vlib,       [Disable vlib and dependant libs and binaries])
 196 DISABLE_ARG(svm,        [Disable svm and dependant libs and binaries])
 197 DISABLE_ARG(papi,       [Disable Python API bindings])
 198 DISABLE_ARG(japi,       [Disable Java API bindings])
 199
 200 # --with-X
 201
 202 # --without-X
 203 WITHOUT_ARG(libssl,     [Disable libssl])
 204 WITHOUT_ARG(apicli,     [Disable binary api CLI])
 205 WITHOUT_ARG(mbedtls,    [Disable mbedtls])
 206 WITHOUT_ARG(libnuma,    [for non numa architectures])
 207
 208 AC_ARG_WITH(log2-cache-line-bytes,
 209             AC_HELP_STRING([--with-log2-cache-line-bytes],[Set the cache line size, --with-log2-cache-line-bytes=5|6|7|auto]),
 210             [case $with_log2_cache_line_bytes in
 211               5 | 6 | 7);;
 212               auto) with_log2_cache_line_bytes=`as_fn_log2_cache_line_size_p`;;
 213               *) with_log2_cache_line_bytes="CONFIG_ERROR";;
 214               esac],
 215               [with_log2_cache_line_bytes=`as_fn_log2_cache_line_size_p`])
 216
 217 AC_ARG_WITH(unix,
 218             AC_HELP_STRING([--with-unix],[Compile unix version of clib]),
 219             [],
 220             [case $host_os in
 221               darwin* | linux*) with_unix=yes;;
 222               *) with_unix=no;;
 223               esac])
 224
 225 AM_CONDITIONAL(WITH_UNIX, test "$with_unix" = "yes")
 226
 227 AC_ARG_WITH(pre-data,
 228             AC_HELP_STRING([--with-pre-data],[Set buffer rewrite space]),
 229             [case $with_pre_data in
 230                128) ;;
 231                256) ;;
 232                *) with_pre_data="pre-data-not-set" ;;
 233              esac], [with_pre_data=128])
 234
 235 ###############################################################################
 236 # Target CPU flags
 237 ###############################################################################
 238
 239 # Check if compiler supports march=core-avx2
 240 CC_CHECK_FLAG("-march=core-avx2")
 241 AS_IF([test "$cc_flag_check" = yes],
 242       [march_core_avx2=yes],
 243       [march_core_avx2=no])
 244 AM_CONDITIONAL([CC_SUPPORTS_AVX2], [test "$march_core_avx2" = "yes"])
 245
 246 # Check if compiler supports march=skylake-avx512
 247 CC_CHECK_FLAG("-march=skylake-avx512")
 248 AS_IF([test "$cc_flag_check" = yes],
 249   [march_skylake_avx512=yes],
 250   [march_skylake_avx512=no])
 251 AM_CONDITIONAL([CC_SUPPORTS_AVX512], [test "$march_skylake_avx512" = "yes"])
 252
 253 AS_CASE([$host_cpu],
 254         [x86_64], [CPU_FLAGS="-march=corei7 -mtune=corei7-avx"],
 255         [aarch64], [CPU_FLAGS="-march=armv8-a+crc"],
 256         [CPU_FLAGS=""],
 257 )
 258 AC_SUBST([CPU_FLAGS])
 259
 260 AC_SUBST([CPU_AVX2_FLAGS],"-march=core-avx2 -mtune=core-avx2")
 261 AC_SUBST([CPU_AVX512_FLAGS],"-march=skylake-avx512 -mtune=skylake-avx512")
 262
 263 AM_CONDITIONAL([CPU_X86_64], [test "$host_cpu" = "x86_64"])
 264 AM_CONDITIONAL([CPU_AARCH64], [test "$host_cpu" = "aarch64"])
 265
 266 ###############################################################################
 267 # misc compiler flags
 268 ###############################################################################
 269
 270 CC_CHECK_FLAG("-Wno-address-of-packed-member")
 271 AS_IF([test "$cc_flag_check" = yes],
 272         [CFLAGS="${CFLAGS} -Wno-address-of-packed-member"], [])
 273
 274 ###############################################################################
 275 # Substitutions and defines
 276 ###############################################################################
 277
 278 AC_SUBST(PRE_DATA_SIZE,         [$with_pre_data])
 279 AC_SUBST(LOG2_CACHE_LINE_BYTES, [$with_log2_cache_line_bytes])
 280 AC_SUBST(APICLI,                [-DVPP_API_TEST_BUILTIN=${n_with_apicli}])
 281
 282 AC_DEFINE_UNQUOTED(DPDK_SHARED_LIB,     [${n_enable_dpdk_shared}])
 283 AC_DEFINE_UNQUOTED(WITH_LIBSSL,         [${n_with_libssl}])
 284 AC_DEFINE_UNQUOTED(WITH_MBEDTLS,        [${n_with_mbedtls}])
 285 AC_DEFINE_UNQUOTED(WITH_LIBNUMA,        [${n_with_libnuma}])
 286
 287
 288 # Silence following noise:
 289 # ar: `u' modifier ignored since `D' is the default (see `U')
 290 AR_FLAGS=cr
 291 AC_SUBST(AR_FLAGS)
 292
 293 ###############################################################################
 294 # Plugins
 295 ###############################################################################
 296
 297 # Please keep alphabetical order
 298 PLUGIN_ENABLED(abf)
 299 PLUGIN_ENABLED(acl)
 300 PLUGIN_ENABLED(avf)
 301 PLUGIN_ENABLED(cdp)
 302 PLUGIN_ENABLED(dpdk)
 303 PLUGIN_ENABLED(flowprobe)
 304 PLUGIN_ENABLED(gbp)
 305 PLUGIN_ENABLED(gtpu)
 306 PLUGIN_ENABLED(igmp)
 307 PLUGIN_ENABLED(ila)
 308 PLUGIN_ENABLED(ioam)
 309 PLUGIN_ENABLED(ixge)
 310 PLUGIN_ENABLED(l2e)
 311 PLUGIN_ENABLED(lacp)
 312 PLUGIN_ENABLED(lb)
 313 PLUGIN_ENABLED(mactime)
 314 PLUGIN_ENABLED(marvell)
 315 PLUGIN_ENABLED(memif)
 316 PLUGIN_ENABLED(pppoe)
 317 PLUGIN_ENABLED(nat)
 318 PLUGIN_ENABLED(srv6ad)
 319 PLUGIN_ENABLED(srv6am)
 320 PLUGIN_ENABLED(srv6as)
 321 PLUGIN_ENABLED(stn)
 322 PLUGIN_ENABLED(tlsmbedtls)
 323 PLUGIN_ENABLED(tlsopenssl)
 324
 325 ###############################################################################
 326 # Dependency checks
 327 ###############################################################################
 328 AC_CHECK_FUNC([memfd_create], [AC_DEFINE([HAVE_MEMFD_CREATE], [1], [Define if memfd exists])])
 329
 330 AM_COND_IF([ENABLE_DPDK_SHARED],
 331 [
 332   AC_CHECK_HEADERS([rte_config.h],
 333     [],
 334     [AC_MSG_ERROR([DPDK header files not found])],)
 335   AC_CHECK_LIB( [dpdk], [rte_eal_init],
 336     [],
 337     [AC_MSG_ERROR([DPDK shared library not found])],)
 338 ])
 339
 340 with_aesni_mb_lib=no
 341 with_isa_l_crypto_lib=no
 342
 343 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_MB, dpdk_aesni_mb_pmd)
 344 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_GCM, dpdk_aesni_gcm_pmd)
 345
 346 AM_COND_IF([WITH_DPDK_AESNI_MB_PMD],
 347 [
 348   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 349                [with_aesni_mb_lib=yes],
 350                [AC_MSG_ERROR([IPSec_MB library not found])])
 351 ])
 352
 353 AM_COND_IF([WITH_DPDK_AESNI_GCM_PMD],
 354 [
 355   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 356     [with_aesni_mb_lib=yes],
 357     [AC_MSG_ERROR([IPSec_MB library not found])])
 358 ])
 359
 360 m4_append([list_of_with], [aesni_mb_lib], [, ])
 361 AM_CONDITIONAL(WITH_AESNI_MB_LIB, test "$with_aesni_mb_lib" = "yes")
 362
 363 m4_append([list_of_with], [isa_l_crypto_lib], [, ])
 364 AM_CONDITIONAL(WITH_ISA_L_CRYPTO_LIB, test "$with_isa_l_crypto_lib" = "yes")
 365
 366 AM_COND_IF([ENABLE_G2],
 367 [
 368   PKG_CHECK_MODULES(g2, gtk+-2.0)
 369 ])
 370
 371 AM_COND_IF([ENABLE_MARVELL_PLUGIN],
 372 [
 373   AC_CHECK_LIB( [musdk], [pp2_init],
 374     [],
 375     [
 376       AC_MSG_WARN([Marvell MUSDK library with PP2 support not found. Plugin disabled.])
 377       enable_marvell_plugin=no
 378       AM_CONDITIONAL(ENABLE_MARVELL_PLUGIN, false)
 379     ])
 380 ])
 381
 382 AM_COND_IF([WITH_MBEDTLS], [],
 383 [
 384   AC_MSG_WARN([mbedtls not enabled. Disabling tlsmbedtls plugin])
 385   enable_tlsmbedtls_plugin=no
 386   AM_CONDITIONAL(ENABLE_TLSMBEDTLS_PLUGIN, false)
 387 ])
 388
 389 AM_COND_IF([ENABLE_TLSMBEDTLS_PLUGIN],
 390 [
 391   AC_CHECK_HEADERS([mbedtls/ssl.h], [],
 392     [
 393       AC_MSG_WARN([mbedtls headers not found. TLS engine implementation disabled])
 394       enable_tlsmbedtls_plugin=no
 395       AM_CONDITIONAL(ENABLE_TLSMBEDTLS_PLUGIN, false)
 396     ], [])
 397 ])
 398
 399 AM_COND_IF([WITH_LIBSSL],
 400 [
 401   AC_CHECK_LIB([ssl -lcrypto], [SSL_set_async_callback],
 402     [
 403       AC_DEFINE([HAVE_OPENSSL_ASYNC], [1], [Define if new openssl interface exists])
 404     ])
 405 ],
 406 [
 407   AC_MSG_WARN([openssl not enabled. Disabling tlsopenssl plugin])
 408   enable_tlsopenssl_plugin=no
 409   AM_CONDITIONAL(ENABLE_TLSOPENSSL_PLUGIN, false)
 410 ])
 411
 412 ###############################################################################
 413 # JAVA
 414 ###############################################################################
 415
 416 AM_COND_IF([ENABLE_JAPI],
 417 [
 418   AX_VPP_FIND_JDK8
 419   AC_SUBST(JAVA_HOME)
 420   AC_SUBST(JAVAC)
 421   AC_SUBST(JAVAH)
 422   AC_SUBST(JAR)
 423 ])
 424
 425 ###############################################################################
 426 # PYTHON
 427 ###############################################################################
 428
 429 AM_COND_IF([ENABLE_PAPI],
 430 [
 431   AM_PATH_PYTHON
 432 ])
 433
 434 ###############################################################################
 435 # Output
 436 ###############################################################################
 437
 438 AC_OUTPUT
 439
 440 AC_MSG_RESULT([==============================================================================])
 441 PRINT_VAL([version], $PACKAGE $VERSION)
 442 PRINT_VAL([prefix], ${prefix})
 443 PRINT_VAL([libdir], ${libdir})
 444 PRINT_VAL([includedir], ${includedir})
 445 PRINT_VAL([CFLAGS], ${CFLAGS})
 446 PRINT_VAL([CPPFLAGS], ${CPPFLAGS})
 447 PRINT_VAL([LDFLAGS], ${LDFLAGS})
 448 PRINT_VAL([LOG2_CACHE_LINE_BYTES], ${with_log2_cache_line_bytes})
 449 AM_COND_IF([ENABLE_JAPI],
 450 [
 451   PRINT_VAL([JAVA_VERSION], ${JAVA_VERSION})
 452   PRINT_VAL([JAVA_HOME], ${JAVA_HOME})
 453 ])
 454
 455 AC_MSG_RESULT([])
 456 AC_MSG_RESULT([with:])
 457 m4_foreach([x], m4_dquote(list_of_with), [
 458   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${with_], x, [}])))
 459 ])
 460
 461 AC_MSG_RESULT([])
 462 AC_MSG_RESULT([enabled:])
 463 m4_foreach([x], m4_dquote(list_of_enabled), [
 464   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [}])))
 465 ])
 466
 467 AC_MSG_RESULT([])
 468 AC_MSG_RESULT([plugins:])
 469 m4_foreach([x], m4_dquote(list_of_plugins), [
 470   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [_plugin}])))
 471 ])
 472 AC_MSG_RESULT([==============================================================================])
 473
 474