src/configure.ac

   1 AC_INIT([vpp], [18.07], [vpp-dev@fd.io])
   2 LT_INIT
   3 AC_CONFIG_AUX_DIR([.])
   4 AM_INIT_AUTOMAKE([subdir-objects])
   5 AM_SILENT_RULES([yes])
   6 AC_CONFIG_FILES([Makefile plugins/Makefile vpp-api/python/Makefile vpp-api/java/Makefile vpp-api/vapi/Makefile])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_PROG_CC
  10 AC_PROG_CPP
  11 AM_PROG_AS
  12 AM_PROG_LIBTOOL
  13 AM_PATH_PYTHON
  14
  15 AM_CONDITIONAL([CROSSCOMPILE], [test "$cross_compiling" == "yes"])
  16
  17 ###############################################################################
  18 # Macros
  19 ###############################################################################
  20
  21 AC_DEFUN([ENABLE_ARG],
  22 [
  23   AC_ARG_ENABLE($1,
  24     AC_HELP_STRING(patsubst([--enable-$1],[_],[-]), $2),
  25     [enable_$1=yes n_enable_$1=1],
  26     [enable_$1=no n_enable_$1=0])
  27   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  28   m4_append([list_of_enabled], [$1], [, ])
  29 ])
  30
  31 AC_DEFUN([DISABLE_ARG],
  32 [
  33   AC_ARG_ENABLE($1,
  34     AC_HELP_STRING(patsubst([--disable-$1],[_],[-]), $2),
  35     [enable_$1=no n_enable_$1=0],
  36     [enable_$1=yes n_enable_$1=1])
  37   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  38   m4_append([list_of_enabled], [$1], [, ])
  39 ])
  40
  41 AC_DEFUN([WITH_ARG],
  42 [
  43   AC_ARG_WITH($1,
  44     AC_HELP_STRING(patsubst([--with-$1],[_],[-]), $2),
  45     [with_$1=yes n_with_$1=1],
  46     [with_$1=no n_with_$1=0])
  47   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  48   m4_append([list_of_with], [$1], [, ])
  49 ])
  50
  51 AC_DEFUN([WITHOUT_ARG],
  52 [
  53   AC_ARG_WITH($1,
  54     AC_HELP_STRING(patsubst([--without-$1],[_],[-]), $2),
  55     [with_$1=no n_with_$1=0],
  56     [with_$1=yes n_with_$1=1])
  57   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  58   m4_append([list_of_with], [$1], [, ])
  59 ])
  60
  61 AC_DEFUN([PLUGIN_ENABLED],
  62 [
  63    AC_ARG_ENABLE($1_plugin,
  64      AC_HELP_STRING([--disable-$1-plugin], [Do not build $1 plugin]),
  65        [enable_$1_plugin=no],
  66        [enable_$1_plugin=yes ])
  67   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  68   m4_append([list_of_plugins], [$1], [, ])
  69 ])
  70
  71 AC_DEFUN([PLUGIN_DISABLED],
  72 [
  73    AC_ARG_ENABLE($1_plugin,
  74      AC_HELP_STRING([--enable-$1-plugin], [Build $1 plugin]),
  75        [enable_$1_plugin=yes ],
  76        [enable_$1_plugin=no])
  77   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  78   m4_append([list_of_plugins], [$1], [, ])
  79 ])
  80
  81 AC_DEFUN([PRINT_VAL], [ AC_MSG_RESULT(AC_HELP_STRING($1,$2)) ])
  82
  83 AC_DEFUN([DPDK_IS_PMD_ENABLED],
  84 [
  85   AC_MSG_CHECKING([for $1 in rte_config.h])
  86   AC_COMPILE_IFELSE(
  87     [AC_LANG_PROGRAM(
  88       [[#include <rte_config.h>]],
  89       [[return RTE_$1;]],
  90     )],
  91     [with_$2=yes]
  92     [AC_MSG_RESULT([yes])],
  93     [with_$2=no]
  94     [AC_MSG_RESULT([no])]
  95   )
  96   AM_CONDITIONAL(m4_toupper(WITH_$2), test "$with_$2" = "yes")
  97   m4_append_uniq([list_of_with], [$2], [, ])
  98 ])
  99
 100 # Check if compiler supports specific flag
 101 AC_DEFUN([CC_CHECK_FLAG],
 102 [
 103   AC_MSG_CHECKING([if $CC supports $1])
 104   AC_LANG_PUSH([C])
 105   ac_saved_cflags="$CFLAGS"
 106   CFLAGS="-Werror $1"
 107   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 108   [cc_flag_check=yes],
 109   [cc_flag_check=no]
 110 )
 111   AC_MSG_RESULT([$cc_flag_check])
 112   CFLAGS="$ac_saved_cflags"
 113   AC_LANG_POP([C])
 114 ])
 115
 116 ###############################################################################
 117 # configure arguments
 118 ###############################################################################
 119
 120 # --enable-X
 121 ENABLE_ARG(tests,       [Enable unit tests])
 122 ENABLE_ARG(dpdk_shared, [Enable unit tests])
 123 ENABLE_ARG(perftool,    [Enable perftool])
 124 ENABLE_ARG(g2,          [Enable g2])
 125
 126 # --disable-X
 127 DISABLE_ARG(vlib,       [Disable vlib and dependant libs and binaries])
 128 DISABLE_ARG(svm,        [Disable svm and dependant libs and binaries])
 129 DISABLE_ARG(papi,       [Disable Python API bindings])
 130 DISABLE_ARG(japi,       [Disable Java API bindings])
 131
 132 # --with-X
 133
 134 # --without-X
 135 WITHOUT_ARG(libssl,     [Disable libssl])
 136 WITHOUT_ARG(apicli,     [Disable binary api CLI])
 137 WITHOUT_ARG(mbedtls,    [Disable mbedtls])
 138 WITHOUT_ARG(libnuma,    [for non numa architectures])
 139
 140 AC_ARG_WITH(unix,
 141             AC_HELP_STRING([--with-unix],[Compile unix version of clib]),
 142             [],
 143             [case $host_os in
 144               darwin* | linux*) with_unix=yes;;
 145               *) with_unix=no;;
 146               esac])
 147
 148 AM_CONDITIONAL(WITH_UNIX, test "$with_unix" = "yes")
 149
 150 AC_ARG_WITH(pre-data,
 151             AC_HELP_STRING([--with-pre-data],[Set buffer rewrite space]),
 152             [case $with_pre_data in
 153                128) ;;
 154                256) ;;
 155                *) with_pre_data="pre-data-not-set" ;;
 156              esac], [with_pre_data=128])
 157
 158 ###############################################################################
 159 # Target CPU flags
 160 ###############################################################################
 161
 162 # Check if compiler supports march=core-avx2
 163 CC_CHECK_FLAG("-march=core-avx2")
 164 AS_IF([test "$cc_flag_check" = yes],
 165       [march_core_avx2=yes],
 166       [march_core_avx2=no])
 167 AM_CONDITIONAL([CC_SUPPORTS_AVX2], [test "$march_core_avx2" = "yes"])
 168
 169 # Check if compiler supports march=skylake-avx512
 170 CC_CHECK_FLAG("-march=skylake-avx512")
 171 AS_IF([test "$cc_flag_check" = yes],
 172   [march_skylake_avx512=yes],
 173   [march_skylake_avx512=no])
 174 AM_CONDITIONAL([CC_SUPPORTS_AVX512], [test "$march_skylake_avx512" = "yes"])
 175
 176 AS_CASE([$host_cpu],
 177         [x86_64], [CPU_FLAGS="-march=corei7 -mtune=corei7-avx"],
 178         [aarch64], [CPU_FLAGS="-march=armv8-a+crc"],
 179         [CPU_FLAGS=""],
 180 )
 181 AC_SUBST([CPU_FLAGS])
 182
 183 AC_SUBST([CPU_AVX2_FLAGS],"-march=core-avx2 -mtune=core-avx2")
 184 AC_SUBST([CPU_AVX512_FLAGS],"-march=skylake-avx512 -mtune=skylake-avx512")
 185
 186 AM_CONDITIONAL([CPU_X86_64], [test "$host_cpu" = "x86_64"])
 187 AM_CONDITIONAL([CPU_AARCH64], [test "$host_cpu" = "aarch64"])
 188
 189 ###############################################################################
 190 # misc compiler flags
 191 ###############################################################################
 192
 193 CC_CHECK_FLAG("-Wno-address-of-packed-member")
 194 AS_IF([test "$cc_flag_check" = yes],
 195         [CFLAGS="${CFLAGS} -Wno-address-of-packed-member"], [])
 196
 197 ###############################################################################
 198 # Substitutions and defines
 199 ###############################################################################
 200
 201 AC_SUBST(PRE_DATA_SIZE,         [$with_pre_data])
 202 AC_SUBST(APICLI,                [-DVPP_API_TEST_BUILTIN=${n_with_apicli}])
 203
 204 AC_DEFINE_UNQUOTED(DPDK_SHARED_LIB,     [${n_enable_dpdk_shared}])
 205 AC_DEFINE_UNQUOTED(WITH_LIBSSL,         [${n_with_libssl}])
 206 AC_DEFINE_UNQUOTED(WITH_MBEDTLS,        [${n_with_mbedtls}])
 207 AC_DEFINE_UNQUOTED(WITH_LIBNUMA,        [${n_with_libnuma}])
 208
 209
 210 # Silence following noise:
 211 # ar: `u' modifier ignored since `D' is the default (see `U')
 212 AR_FLAGS=cr
 213 AC_SUBST(AR_FLAGS)
 214
 215 ###############################################################################
 216 # Plugins
 217 ###############################################################################
 218
 219 # Please keep alphabetical order
 220 PLUGIN_ENABLED(abf)
 221 PLUGIN_ENABLED(acl)
 222 PLUGIN_ENABLED(avf)
 223 PLUGIN_ENABLED(cdp)
 224 PLUGIN_ENABLED(dpdk)
 225 PLUGIN_ENABLED(flowprobe)
 226 PLUGIN_ENABLED(gbp)
 227 PLUGIN_ENABLED(gtpu)
 228 PLUGIN_ENABLED(igmp)
 229 PLUGIN_ENABLED(ila)
 230 PLUGIN_ENABLED(ioam)
 231 PLUGIN_ENABLED(ixge)
 232 PLUGIN_ENABLED(l2e)
 233 PLUGIN_ENABLED(lacp)
 234 PLUGIN_ENABLED(lb)
 235 PLUGIN_ENABLED(marvell)
 236 PLUGIN_ENABLED(memif)
 237 PLUGIN_ENABLED(pppoe)
 238 PLUGIN_ENABLED(nat)
 239 PLUGIN_ENABLED(srv6ad)
 240 PLUGIN_ENABLED(srv6am)
 241 PLUGIN_ENABLED(srv6as)
 242 PLUGIN_ENABLED(stn)
 243 PLUGIN_ENABLED(tlsmbedtls)
 244 PLUGIN_ENABLED(tlsopenssl)
 245
 246 ###############################################################################
 247 # Dependency checks
 248 ###############################################################################
 249 AC_CHECK_FUNC([memfd_create], [AC_DEFINE([HAVE_MEMFD_CREATE], [1], [Define if memfd exists])])
 250
 251 AM_COND_IF([ENABLE_DPDK_SHARED],
 252 [
 253   AC_CHECK_HEADERS([rte_config.h],
 254     [],
 255     [AC_MSG_ERROR([DPDK header files not found])],)
 256   AC_CHECK_LIB( [dpdk], [rte_eal_init],
 257     [],
 258     [AC_MSG_ERROR([DPDK shared library not found])],)
 259 ])
 260
 261 with_aesni_mb_lib=no
 262 with_isa_l_crypto_lib=no
 263
 264 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_MB, dpdk_aesni_mb_pmd)
 265 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_GCM, dpdk_aesni_gcm_pmd)
 266
 267 AM_COND_IF([WITH_DPDK_AESNI_MB_PMD],
 268 [
 269   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 270                [with_aesni_mb_lib=yes],
 271                [AC_MSG_ERROR([IPSec_MB library not found])])
 272 ])
 273
 274 AM_COND_IF([WITH_DPDK_AESNI_GCM_PMD],
 275 [
 276   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 277     [with_aesni_mb_lib=yes],
 278     [AC_MSG_ERROR([IPSec_MB library not found])])
 279 ])
 280
 281 m4_append([list_of_with], [aesni_mb_lib], [, ])
 282 AM_CONDITIONAL(WITH_AESNI_MB_LIB, test "$with_aesni_mb_lib" = "yes")
 283
 284 m4_append([list_of_with], [isa_l_crypto_lib], [, ])
 285 AM_CONDITIONAL(WITH_ISA_L_CRYPTO_LIB, test "$with_isa_l_crypto_lib" = "yes")
 286
 287 AM_COND_IF([ENABLE_G2],
 288 [
 289   PKG_CHECK_MODULES(g2, gtk+-2.0)
 290 ])
 291
 292 AM_COND_IF([ENABLE_MARVELL_PLUGIN],
 293 [
 294   AC_CHECK_LIB( [musdk], [pp2_init],
 295     [],
 296     [
 297       AC_MSG_WARN([Marvell MUSDK library with PP2 support not found. Plugin disabled.])
 298       enable_marvell_plugin=no
 299       AM_CONDITIONAL(ENABLE_MARVELL_PLUGIN, false)
 300     ])
 301 ])
 302
 303 AM_COND_IF([WITH_MBEDTLS], [],
 304 [
 305   AC_MSG_WARN([mbedtls not enabled. Disabling tlsmbedtls plugin])
 306   enable_tlsmbedtls_plugin=no
 307   AM_CONDITIONAL(ENABLE_TLSMBEDTLS_PLUGIN, false)
 308 ])
 309
 310 AM_COND_IF([ENABLE_TLSMBEDTLS_PLUGIN],
 311 [
 312   AC_CHECK_HEADERS([mbedtls/ssl.h], [],
 313     [
 314       AC_MSG_WARN([mbedtls headers not found. TLS engine implementation disabled])
 315       enable_tlsmbedtls_plugin=no
 316       AM_CONDITIONAL(ENABLE_TLSMBEDTLS_PLUGIN, false)
 317     ], [])
 318 ])
 319
 320 AM_COND_IF([WITH_LIBSSL], [],
 321 [
 322   AC_MSG_WARN([openssl not enabled. Disabling tlsopenssl plugin])
 323   enable_tlsopenssl_plugin=no
 324   AM_CONDITIONAL(ENABLE_TLSOPENSSL_PLUGIN, false)
 325 ])
 326
 327 ###############################################################################
 328 # JAVA
 329 ###############################################################################
 330
 331 AM_COND_IF([ENABLE_JAPI],
 332 [
 333   AX_VPP_FIND_JDK8
 334   AC_SUBST(JAVA_HOME)
 335   AC_SUBST(JAVAC)
 336   AC_SUBST(JAVAH)
 337   AC_SUBST(JAR)
 338 ])
 339
 340 ###############################################################################
 341 # PYTHON
 342 ###############################################################################
 343
 344 AM_COND_IF([ENABLE_PAPI],
 345 [
 346   AM_PATH_PYTHON
 347 ])
 348
 349 ###############################################################################
 350 # Output
 351 ###############################################################################
 352
 353 AC_OUTPUT
 354
 355 AC_MSG_RESULT([==============================================================================])
 356 PRINT_VAL([version], $PACKAGE $VERSION)
 357 PRINT_VAL([prefix], ${prefix})
 358 PRINT_VAL([libdir], ${libdir})
 359 PRINT_VAL([includedir], ${includedir})
 360 PRINT_VAL([CFLAGS], ${CFLAGS})
 361 PRINT_VAL([CPPFLAGS], ${CPPFLAGS})
 362 PRINT_VAL([LDFLAGS], ${LDFLAGS})
 363 AM_COND_IF([ENABLE_JAPI],
 364 [
 365   PRINT_VAL([JAVA_VERSION], ${JAVA_VERSION})
 366   PRINT_VAL([JAVA_HOME], ${JAVA_HOME})
 367 ])
 368
 369 AC_MSG_RESULT([])
 370 AC_MSG_RESULT([with:])
 371 m4_foreach([x], m4_dquote(list_of_with), [
 372   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${with_], x, [}])))
 373 ])
 374
 375 AC_MSG_RESULT([])
 376 AC_MSG_RESULT([enabled:])
 377 m4_foreach([x], m4_dquote(list_of_enabled), [
 378   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [}])))
 379 ])
 380
 381 AC_MSG_RESULT([])
 382 AC_MSG_RESULT([plugins:])
 383 m4_foreach([x], m4_dquote(list_of_plugins), [
 384   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [_plugin}])))
 385 ])
 386 AC_MSG_RESULT([==============================================================================])
 387
 388