src/configure.ac

   1 AC_INIT([vpp], [18.10], [vpp-dev@fd.io])
   2 LT_INIT
   3 AC_CONFIG_AUX_DIR([.])
   4 AM_INIT_AUTOMAKE([subdir-objects])
   5 AM_SILENT_RULES([yes])
   6 AC_CONFIG_FILES([ \
   7   Makefile \
   8   plugins/Makefile \
   9   vpp-api/python/Makefile \
  10   vpp-api/java/Makefile \
  11   vpp-api/vapi/Makefile \
  12   vlib/config.h \
  13 ])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AC_PROG_CC
  17 AC_PROG_CPP
  18 AM_PROG_AS
  19 AM_PROG_LIBTOOL
  20 AM_PATH_PYTHON
  21
  22 AM_CONDITIONAL([CROSSCOMPILE], [test "$cross_compiling" == "yes"])
  23
  24 ###############################################################################
  25 # Macros
  26 ###############################################################################
  27
  28 AC_DEFUN([ENABLE_ARG],
  29 [
  30   AC_ARG_ENABLE($1,
  31     AC_HELP_STRING(patsubst([--enable-$1],[_],[-]), $2),
  32     [enable_$1=yes n_enable_$1=1],
  33     [enable_$1=no n_enable_$1=0])
  34   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  35   m4_append([list_of_enabled], [$1], [, ])
  36 ])
  37
  38 AC_DEFUN([DISABLE_ARG],
  39 [
  40   AC_ARG_ENABLE($1,
  41     AC_HELP_STRING(patsubst([--disable-$1],[_],[-]), $2),
  42     [enable_$1=no n_enable_$1=0],
  43     [enable_$1=yes n_enable_$1=1])
  44   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  45   m4_append([list_of_enabled], [$1], [, ])
  46 ])
  47
  48 AC_DEFUN([WITH_ARG],
  49 [
  50   AC_ARG_WITH($1,
  51     AC_HELP_STRING(patsubst([--with-$1],[_],[-]), $2),
  52     [with_$1=yes n_with_$1=1],
  53     [with_$1=no n_with_$1=0])
  54   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  55   m4_append([list_of_with], [$1], [, ])
  56 ])
  57
  58 AC_DEFUN([WITHOUT_ARG],
  59 [
  60   AC_ARG_WITH($1,
  61     AC_HELP_STRING(patsubst([--without-$1],[_],[-]), $2),
  62     [with_$1=no n_with_$1=0],
  63     [with_$1=yes n_with_$1=1])
  64   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  65   m4_append([list_of_with], [$1], [, ])
  66 ])
  67
  68 AC_DEFUN([PLUGIN_ENABLED],
  69 [
  70    AC_ARG_ENABLE($1_plugin,
  71      AC_HELP_STRING([--disable-$1-plugin], [Do not build $1 plugin]),
  72        [enable_$1_plugin=no],
  73        [enable_$1_plugin=yes ])
  74   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  75   m4_append([list_of_plugins], [$1], [, ])
  76 ])
  77
  78 AC_DEFUN([PLUGIN_DISABLED],
  79 [
  80    AC_ARG_ENABLE($1_plugin,
  81      AC_HELP_STRING([--enable-$1-plugin], [Build $1 plugin]),
  82        [enable_$1_plugin=yes ],
  83        [enable_$1_plugin=no])
  84   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  85   m4_append([list_of_plugins], [$1], [, ])
  86 ])
  87
  88 AC_DEFUN([PRINT_VAL], [ AC_MSG_RESULT(AC_HELP_STRING($1,$2)) ])
  89
  90 AC_DEFUN([DPDK_IS_PMD_ENABLED],
  91 [
  92   AC_MSG_CHECKING([for $1 in rte_config.h])
  93   AC_COMPILE_IFELSE(
  94     [AC_LANG_PROGRAM(
  95       [[#include <rte_config.h>]],
  96       [[return RTE_$1;]],
  97     )],
  98     [with_$2=yes]
  99     [AC_MSG_RESULT([yes])],
 100     [with_$2=no]
 101     [AC_MSG_RESULT([no])]
 102   )
 103   AM_CONDITIONAL(m4_toupper(WITH_$2), test "$with_$2" = "yes")
 104   m4_append_uniq([list_of_with], [$2], [, ])
 105 ])
 106
 107 # Check if compiler supports specific flag
 108 AC_DEFUN([CC_CHECK_FLAG],
 109 [
 110   AC_MSG_CHECKING([if $CC supports $1])
 111   AC_LANG_PUSH([C])
 112   ac_saved_cflags="$CFLAGS"
 113   CFLAGS="-Werror $1"
 114   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 115   [cc_flag_check=yes],
 116   [cc_flag_check=no]
 117 )
 118   AC_MSG_RESULT([$cc_flag_check])
 119   CFLAGS="$ac_saved_cflags"
 120   AC_LANG_POP([C])
 121 ])
 122
 123 # This function deduces the BUILD HOST cache-line size by
 124 # inspecting /sys and/or /proc depending on the kernel / arch in use
 125 as_fn_log2_cache_line_size_p()
 126 {
 127   sysfs_cache_path="/sys/devices/system/cpu/cpu0/cache/index0/coherency_line_size"
 128   m4_define([read_cache_line_size_from_sysfs], [`head -n 1 $1`])
 129   m4_define([read_midr_implementer],
 130             [`awk '/implementer/ {print $[]4;exit}' /proc/cpuinfo`])
 131   m4_define([read_midr_cpuid],
 132             [`awk '/part/ {print $[]4;exit}' /proc/cpuinfo`])
 133
 134   #Check if sysfs path exists,to ignore warning, else do manual mapping
 135   AC_CHECK_FILE($sysfs_cache_path,
 136     [
 137       cache_line_size=read_cache_line_size_from_sysfs($sysfs_cache_path);
 138       if test $cache_line_size = "32"  ; then
 139           log2_cache_line_size="5";
 140       elif test $cache_line_size = "64"  ; then
 141           log2_cache_line_size="6";
 142       elif test $cache_line_size = "128"  ; then
 143           log2_cache_line_size="7";
 144       fi
 145       AC_MSG_NOTICE([cache_line_size/log2_cache_line_size deduced as $cache_line_size/$log2_cache_line_size])
 146     ],
 147     [
 148         #Define Implementer Ids here
 149         implementer_id_cavium=0x43
 150
 151         #Define CPU Ids here
 152         cpu_id_cavium_thunderx_cn88xx=0x0a1
 153         cpu_id_cavium_thunderx2_cn99xx=0x0af
 154
 155         implementer=read_midr_implementer()
 156         cpuid=read_midr_cpuid()
 157
 158         AC_MSG_CHECKING([for implementerid/cpuid to set log2_cache_line_size])
 159
 160         # Switch case to map log2_cache_line_size for implementer/cpuid combination.
 161         # Default case of Switch sets log2_cache_line_size to 6
 162         AS_CASE($implementer,
 163               #Switch Case for Cavium SoC's
 164               [$implementer_id_cavium],
 165                   [AS_CASE($cpuid,
 166                       #Only ThunderX2 is 64B. Remaining chips are 128B
 167                       [$cpu_id_cavium_thunderx2_cn99xx],
 168                             [AC_MSG_RESULT([Cavium/ThunderX2]);log2_cache_line_size=6],
 169                       [$cpu_id_cavium_thunderx_cn88xx],
 170                             [AC_MSG_RESULT([Cavium/ThunderX]);log2_cache_line_size=7],
 171                       [log2_cache_line_size=7;AC_MSG_RESULT([Cavium/OCTEONTx($cpuid)])]
 172                    )],
 173               #Add implementer specific case here:
 174
 175               #Default case: 64B for all SoC's
 176               [log2_cache_line_size=6;AC_MSG_RESULT([$implementer/$cpuid])]
 177         )
 178       AC_MSG_NOTICE([log2_cache_line_size deduced as $log2_cache_line_size])
 179     ]
 180   )
 181   echo $log2_cache_line_size
 182 }
 183
 184 ###############################################################################
 185 # configure arguments
 186 ###############################################################################
 187
 188 # --enable-X
 189 ENABLE_ARG(tests,       [Enable unit tests])
 190 ENABLE_ARG(dpdk_shared, [Enable unit tests])
 191 ENABLE_ARG(perftool,    [Enable perftool])
 192 ENABLE_ARG(g2,          [Enable g2])
 193 ENABLE_ARG(dlmalloc,    [Enable dlmalloc])
 194
 195 # --disable-X
 196 DISABLE_ARG(vlib,       [Disable vlib and dependant libs and binaries])
 197 DISABLE_ARG(svm,        [Disable svm and dependant libs and binaries])
 198 DISABLE_ARG(papi,       [Disable Python API bindings])
 199 DISABLE_ARG(japi,       [Disable Java API bindings])
 200
 201 # --with-X
 202
 203 # --without-X
 204 WITHOUT_ARG(libssl,     [Disable libssl])
 205 WITHOUT_ARG(apicli,     [Disable binary api CLI])
 206 WITHOUT_ARG(mbedtls,    [Disable mbedtls])
 207 WITHOUT_ARG(libnuma,    [for non numa architectures])
 208
 209 AC_ARG_WITH(log2-cache-line-bytes,
 210             AC_HELP_STRING([--with-log2-cache-line-bytes],[Set the cache line size, --with-log2-cache-line-bytes=5|6|7|auto]),
 211             [case $with_log2_cache_line_bytes in
 212               5 | 6 | 7);;
 213               auto) with_log2_cache_line_bytes=`as_fn_log2_cache_line_size_p`;;
 214               *) with_log2_cache_line_bytes="CONFIG_ERROR";;
 215               esac],
 216               [with_log2_cache_line_bytes=`as_fn_log2_cache_line_size_p`])
 217
 218 AC_ARG_WITH(unix,
 219             AC_HELP_STRING([--with-unix],[Compile unix version of clib]),
 220             [],
 221             [case $host_os in
 222               darwin* | linux*) with_unix=yes;;
 223               *) with_unix=no;;
 224               esac])
 225
 226 AM_CONDITIONAL(WITH_UNIX, test "$with_unix" = "yes")
 227
 228 AC_ARG_WITH(pre-data,
 229             AC_HELP_STRING([--with-pre-data],[Set buffer rewrite space]),
 230             [case $with_pre_data in
 231                128) ;;
 232                256) ;;
 233                *) with_pre_data="pre-data-not-set" ;;
 234              esac], [with_pre_data=128])
 235
 236 AM_CONDITIONAL(ENABLE_DLMALLOC, test "$enable_dlmalloc" = "yes")
 237
 238 ###############################################################################
 239 # Target CPU flags
 240 ###############################################################################
 241
 242 # Check if compiler supports march=core-avx2
 243 CC_CHECK_FLAG("-march=core-avx2")
 244 AS_IF([test "$cc_flag_check" = yes],
 245       [march_core_avx2=yes],
 246       [march_core_avx2=no])
 247 AM_CONDITIONAL([CC_SUPPORTS_AVX2], [test "$march_core_avx2" = "yes"])
 248
 249 # Check if compiler supports march=skylake-avx512
 250 CC_CHECK_FLAG("-march=skylake-avx512")
 251 AS_IF([test "$cc_flag_check" = yes],
 252   [march_skylake_avx512=yes],
 253   [march_skylake_avx512=no])
 254 AM_CONDITIONAL([CC_SUPPORTS_AVX512], [test "$march_skylake_avx512" = "yes"])
 255
 256 AS_CASE([$host_cpu],
 257         [x86_64], [CPU_FLAGS="-march=corei7 -mtune=corei7-avx"],
 258         [aarch64], [CPU_FLAGS="-march=armv8-a+crc"],
 259         [CPU_FLAGS=""],
 260 )
 261 AC_SUBST([CPU_FLAGS])
 262
 263 AC_SUBST([CPU_AVX2_FLAGS],"-march=core-avx2 -mtune=core-avx2")
 264 AC_SUBST([CPU_AVX512_FLAGS],"-march=skylake-avx512 -mtune=skylake-avx512")
 265
 266 AM_CONDITIONAL([CPU_X86_64], [test "$host_cpu" = "x86_64"])
 267 AM_CONDITIONAL([CPU_AARCH64], [test "$host_cpu" = "aarch64"])
 268
 269 ###############################################################################
 270 # misc compiler flags
 271 ###############################################################################
 272
 273 CC_CHECK_FLAG("-Wno-address-of-packed-member")
 274 AS_IF([test "$cc_flag_check" = yes],
 275         [CFLAGS="${CFLAGS} -Wno-address-of-packed-member"], [])
 276
 277 ###############################################################################
 278 # Substitutions and defines
 279 ###############################################################################
 280
 281 AC_SUBST(PRE_DATA_SIZE,         [$with_pre_data])
 282 AC_SUBST(LOG2_CACHE_LINE_BYTES, [$with_log2_cache_line_bytes])
 283 AC_SUBST(APICLI,                [-DVPP_API_TEST_BUILTIN=${n_with_apicli}])
 284 AC_SUBST(DLMALLOC,              [-DUSE_DLMALLOC=${n_enable_dlmalloc}])
 285
 286 AC_DEFINE_UNQUOTED(DPDK_SHARED_LIB,     [${n_enable_dpdk_shared}])
 287 AC_DEFINE_UNQUOTED(WITH_LIBSSL,         [${n_with_libssl}])
 288 AC_DEFINE_UNQUOTED(WITH_MBEDTLS,        [${n_with_mbedtls}])
 289 AC_DEFINE_UNQUOTED(WITH_LIBNUMA,        [${n_with_libnuma}])
 290
 291
 292 # Silence following noise:
 293 # ar: `u' modifier ignored since `D' is the default (see `U')
 294 AR_FLAGS=cr
 295 AC_SUBST(AR_FLAGS)
 296
 297 ###############################################################################
 298 # Plugins
 299 ###############################################################################
 300
 301 # Please keep alphabetical order
 302 PLUGIN_ENABLED(abf)
 303 PLUGIN_ENABLED(acl)
 304 PLUGIN_ENABLED(avf)
 305 PLUGIN_ENABLED(cdp)
 306 PLUGIN_ENABLED(dpdk)
 307 PLUGIN_ENABLED(flowprobe)
 308 PLUGIN_ENABLED(gbp)
 309 PLUGIN_ENABLED(gtpu)
 310 PLUGIN_ENABLED(igmp)
 311 PLUGIN_ENABLED(ila)
 312 PLUGIN_ENABLED(ioam)
 313 PLUGIN_ENABLED(ixge)
 314 PLUGIN_ENABLED(l2e)
 315 PLUGIN_ENABLED(lacp)
 316 PLUGIN_ENABLED(lb)
 317 PLUGIN_ENABLED(mactime)
 318 PLUGIN_ENABLED(marvell)
 319 PLUGIN_ENABLED(memif)
 320 PLUGIN_ENABLED(pppoe)
 321 PLUGIN_ENABLED(nat)
 322 PLUGIN_ENABLED(map)
 323 PLUGIN_ENABLED(srv6ad)
 324 PLUGIN_ENABLED(srv6am)
 325 PLUGIN_ENABLED(srv6as)
 326 PLUGIN_ENABLED(stn)
 327 PLUGIN_ENABLED(tlsmbedtls)
 328 PLUGIN_ENABLED(tlsopenssl)
 329
 330 ###############################################################################
 331 # Dependency checks
 332 ###############################################################################
 333 AC_CHECK_FUNC([memfd_create], [AC_DEFINE([HAVE_MEMFD_CREATE], [1], [Define if memfd exists])])
 334
 335 AM_COND_IF([ENABLE_DPDK_SHARED],
 336 [
 337   AC_CHECK_HEADERS([rte_config.h],
 338     [],
 339     [AC_MSG_ERROR([DPDK header files not found])],)
 340   AC_CHECK_LIB( [dpdk], [rte_eal_init],
 341     [],
 342     [AC_MSG_ERROR([DPDK shared library not found])],)
 343 ])
 344
 345 with_aesni_mb_lib=no
 346 with_isa_l_crypto_lib=no
 347
 348 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_MB, dpdk_aesni_mb_pmd)
 349 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_GCM, dpdk_aesni_gcm_pmd)
 350
 351 AM_COND_IF([WITH_DPDK_AESNI_MB_PMD],
 352 [
 353   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 354                [with_aesni_mb_lib=yes],
 355                [AC_MSG_ERROR([IPSec_MB library not found])])
 356 ])
 357
 358 AM_COND_IF([WITH_DPDK_AESNI_GCM_PMD],
 359 [
 360   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 361     [with_aesni_mb_lib=yes],
 362     [AC_MSG_ERROR([IPSec_MB library not found])])
 363 ])
 364
 365 m4_append([list_of_with], [aesni_mb_lib], [, ])
 366 AM_CONDITIONAL(WITH_AESNI_MB_LIB, test "$with_aesni_mb_lib" = "yes")
 367
 368 m4_append([list_of_with], [isa_l_crypto_lib], [, ])
 369 AM_CONDITIONAL(WITH_ISA_L_CRYPTO_LIB, test "$with_isa_l_crypto_lib" = "yes")
 370
 371 AM_COND_IF([ENABLE_G2],
 372 [
 373   PKG_CHECK_MODULES(g2, gtk+-2.0)
 374 ])
 375
 376 AM_COND_IF([ENABLE_MARVELL_PLUGIN],
 377 [
 378   AC_CHECK_LIB( [musdk], [pp2_init],
 379     [],
 380     [
 381       AC_MSG_WARN([Marvell MUSDK library with PP2 support not found. Plugin disabled.])
 382       enable_marvell_plugin=no
 383       AM_CONDITIONAL(ENABLE_MARVELL_PLUGIN, false)
 384     ])
 385 ])
 386
 387 AM_COND_IF([WITH_MBEDTLS], [],
 388 [
 389   AC_MSG_WARN([mbedtls not enabled. Disabling tlsmbedtls plugin])
 390   enable_tlsmbedtls_plugin=no
 391   AM_CONDITIONAL(ENABLE_TLSMBEDTLS_PLUGIN, false)
 392 ])
 393
 394 AM_COND_IF([ENABLE_TLSMBEDTLS_PLUGIN],
 395 [
 396   AC_CHECK_HEADERS([mbedtls/ssl.h], [],
 397     [
 398       AC_MSG_WARN([mbedtls headers not found. TLS engine implementation disabled])
 399       enable_tlsmbedtls_plugin=no
 400       AM_CONDITIONAL(ENABLE_TLSMBEDTLS_PLUGIN, false)
 401     ], [])
 402 ])
 403
 404 AM_COND_IF([WITH_LIBSSL],
 405 [
 406   AC_CHECK_LIB([ssl -lcrypto], [SSL_set_async_callback],
 407     [
 408       AC_DEFINE([HAVE_OPENSSL_ASYNC], [1], [Define if new openssl interface exists])
 409     ])
 410 ],
 411 [
 412   AC_MSG_WARN([openssl not enabled. Disabling tlsopenssl plugin])
 413   enable_tlsopenssl_plugin=no
 414   AM_CONDITIONAL(ENABLE_TLSOPENSSL_PLUGIN, false)
 415 ])
 416
 417 ###############################################################################
 418 # JAVA
 419 ###############################################################################
 420
 421 AM_COND_IF([ENABLE_JAPI],
 422 [
 423   AX_VPP_FIND_JDK8
 424   AC_SUBST(JAVA_HOME)
 425   AC_SUBST(JAVAC)
 426   AC_SUBST(JAVAH)
 427   AC_SUBST(JAR)
 428 ])
 429
 430 ###############################################################################
 431 # PYTHON
 432 ###############################################################################
 433
 434 AM_COND_IF([ENABLE_PAPI],
 435 [
 436   AM_PATH_PYTHON
 437 ])
 438
 439 ###############################################################################
 440 # Output
 441 ###############################################################################
 442
 443 AC_OUTPUT
 444
 445 AC_MSG_RESULT([==============================================================================])
 446 PRINT_VAL([version], $PACKAGE $VERSION)
 447 PRINT_VAL([prefix], ${prefix})
 448 PRINT_VAL([libdir], ${libdir})
 449 PRINT_VAL([includedir], ${includedir})
 450 PRINT_VAL([CFLAGS], ${CFLAGS})
 451 PRINT_VAL([CPPFLAGS], ${CPPFLAGS})
 452 PRINT_VAL([LDFLAGS], ${LDFLAGS})
 453 PRINT_VAL([LOG2_CACHE_LINE_BYTES], ${with_log2_cache_line_bytes})
 454 PRINT_VAL([DLMALLOC], ${enable_dlmalloc})
 455 AM_COND_IF([ENABLE_JAPI],
 456 [
 457   PRINT_VAL([JAVA_VERSION], ${JAVA_VERSION})
 458   PRINT_VAL([JAVA_HOME], ${JAVA_HOME})
 459 ])
 460
 461 AC_MSG_RESULT([])
 462 AC_MSG_RESULT([with:])
 463 m4_foreach([x], m4_dquote(list_of_with), [
 464   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${with_], x, [}])))
 465 ])
 466
 467 AC_MSG_RESULT([])
 468 AC_MSG_RESULT([enabled:])
 469 m4_foreach([x], m4_dquote(list_of_enabled), [
 470   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [}])))
 471 ])
 472
 473 AC_MSG_RESULT([])
 474 AC_MSG_RESULT([plugins:])
 475 m4_foreach([x], m4_dquote(list_of_plugins), [
 476   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [_plugin}])))
 477 ])
 478 AC_MSG_RESULT([==============================================================================])
 479
 480