src/configure.ac

   1 AC_INIT([vpp], [17.04], [vpp-dev@fd.io])
   2 LT_INIT
   3 AC_CONFIG_AUX_DIR([.])
   4 AM_INIT_AUTOMAKE([subdir-objects])
   5 AM_SILENT_RULES([yes])
   6 AC_CONFIG_FILES([Makefile plugins/Makefile vpp-api/python/Makefile vpp-api/java/Makefile])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_PROG_CC
  10 AM_PROG_AS
  11 AM_PROG_LIBTOOL
  12 AC_PROG_YACC
  13 AM_PATH_PYTHON
  14
  15 AM_CONDITIONAL([CROSSCOMPILE], [test "$cross_compiling" == "yes"])
  16
  17 ###############################################################################
  18 # Macros
  19 ###############################################################################
  20
  21 AC_DEFUN([ENABLE_ARG],
  22 [
  23   AC_ARG_ENABLE($1,
  24     AC_HELP_STRING(patsubst([--enable-$1],[_],[-]), $2),
  25     [enable_$1=yes n_enable_$1=1],
  26     [enable_$1=no n_enable_$1=0])
  27   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  28   m4_append([list_of_enabled], [$1], [, ])
  29 ])
  30
  31 AC_DEFUN([DISABLE_ARG],
  32 [
  33   AC_ARG_ENABLE($1,
  34     AC_HELP_STRING(patsubst([--disable-$1],[_],[-]), $2),
  35     [enable_$1=no n_enable_$1=0],
  36     [enable_$1=yes n_enable_$1=1])
  37   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  38   m4_append([list_of_enabled], [$1], [, ])
  39 ])
  40
  41 AC_DEFUN([WITH_ARG],
  42 [
  43   AC_ARG_WITH($1,
  44     AC_HELP_STRING(patsubst([--with-$1],[_],[-]), $2),
  45     [with_$1=yes n_with_$1=1],
  46     [with_$1=no n_with_$1=0])
  47   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  48   m4_append([list_of_with], [$1], [, ])
  49 ])
  50
  51 AC_DEFUN([WITHOUT_ARG],
  52 [
  53   AC_ARG_WITH($1,
  54     AC_HELP_STRING(patsubst([--without-$1],[_],[-]), $2),
  55     [with_$1=no n_with_$1=0],
  56     [with_$1=yes n_with_$1=1])
  57   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  58   m4_append([list_of_with], [$1], [, ])
  59 ])
  60
  61 AC_DEFUN([PLUGIN_ENABLED],
  62 [
  63    AC_ARG_ENABLE($1_plugin,
  64      AC_HELP_STRING([--disable-$1-plugin], [Do not build $1 plugin]),
  65        [enable_$1_plugin=no],
  66        [enable_$1_plugin=yes ])
  67   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  68   m4_append([list_of_plugins], [$1], [, ])
  69 ])
  70
  71 AC_DEFUN([PLUGIN_DISABLED],
  72 [
  73    AC_ARG_ENABLE($1_plugin,
  74      AC_HELP_STRING([--enable-$1-plugin], [Build $1 plugin]),
  75        [enable_$1_plugin=yes ],
  76        [enable_$1_plugin=no])
  77   AM_CONDITIONAL(m4_toupper((ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  78   m4_append([list_of_plugins], [$1], [, ])
  79 ])
  80
  81 AC_DEFUN([PRINT_VAL], [ AC_MSG_RESULT(AC_HELP_STRING($1,$2)) ])
  82
  83 ###############################################################################
  84 # configure arguments
  85 ###############################################################################
  86
  87 # --enable-X
  88 ENABLE_ARG(tests,       [Enable unit tests])
  89 ENABLE_ARG(dpdk_shared, [Enable unit tests])
  90 ENABLE_ARG(perftool,    [Enable perftool])
  91 ENABLE_ARG(g2,          [Enable g2])
  92
  93 # --disable-X
  94 DISABLE_ARG(vlib,       [Disable vlib and dependant libs and binaries])
  95 DISABLE_ARG(svm,        [Disable svm and dependant libs and binaries])
  96 DISABLE_ARG(papi,       [Disable Python API bindings])
  97 DISABLE_ARG(japi,       [Disable Java API bindings])
  98
  99 # --with-X
 100 WITH_ARG(dpdk,          [Use use DPDK])
 101 WITH_ARG(dpdk_crypto_sw,[Use DPDK cryptodev SW PMDs])
 102 WITH_ARG(dpdk_mlx5_pmd, [Use DPDK with mlx5 PMD])
 103
 104 # --without-X
 105 WITHOUT_ARG(libssl,     [Disable libssl])
 106 WITHOUT_ARG(apicli,     [Disable binary api CLI])
 107
 108 AC_ARG_WITH(unix,
 109             AC_HELP_STRING([--with-unix],[Compile unix version of clib]),
 110             [],
 111             [case $host_os in
 112               darwin* | linux*) with_unix=yes;;
 113               *) with_unix=no;;
 114               esac])
 115
 116 AM_CONDITIONAL(WITH_UNIX, test "$with_unix" = "yes")
 117
 118 AC_ARG_WITH(pre-data,
 119             AC_HELP_STRING([--with-pre-data],[Set buffer rewrite space]),
 120             [case $with_pre_data in
 121                128) ;;
 122                256) ;;
 123                *) with_pre_data="pre-data-not-set" ;;
 124              esac], [with_pre_data=128])
 125
 126 ###############################################################################
 127 # Substitutions and defines
 128 ###############################################################################
 129
 130 AC_SUBST(PRE_DATA_SIZE,         [$with_pre_data])
 131 AC_SUBST(APICLI,                [-DVPP_API_TEST_BUILTIN=${n_with_apicli}])
 132
 133 AC_DEFINE_UNQUOTED(DPDK,                [${n_with_dpdk}])
 134 AC_DEFINE_UNQUOTED(DPDK_SHARED_LIB,     [${n_enable_dpdk_shared}])
 135 AC_DEFINE_UNQUOTED(DPDK_CRYPTO_SW,      [${n_with_dpdk_crypto_sw}])
 136 AC_DEFINE_UNQUOTED(WITH_LIBSSL,         [${n_with_libssl}])
 137
 138
 139 # Silence following noise:
 140 # ar: `u' modifier ignored since `D' is the default (see `U')
 141 AR_FLAGS=cr
 142 AC_SUBST(AR_FLAGS)
 143
 144 ###############################################################################
 145 # Plugins
 146 ###############################################################################
 147
 148 # Please keep alphabetical order
 149 PLUGIN_ENABLED(acl)
 150 PLUGIN_ENABLED(flowperpkt)
 151 PLUGIN_ENABLED(ila)
 152 PLUGIN_ENABLED(ioam)
 153 PLUGIN_ENABLED(lb)
 154 PLUGIN_ENABLED(sixrd)
 155 PLUGIN_ENABLED(snat)
 156
 157 ###############################################################################
 158 # Dependency checks
 159 ###############################################################################
 160
 161 AM_COND_IF([ENABLE_DPDK_SHARED],
 162 [
 163   AC_CHECK_HEADERS([rte_config.h],
 164     [],
 165     [AC_MSG_ERROR([DPDK header files not found])],)
 166   AC_CHECK_LIB( [dpdk], [rte_eal_init],
 167     [],
 168     [AC_MSG_ERROR([DPDK shared library not found])],)
 169 ])
 170
 171 AM_COND_IF([ENABLE_G2],
 172 [
 173   PKG_CHECK_MODULES(g2, gtk+-2.0)
 174 ])
 175
 176 # If cross-compiling, we need external vppapigen and we cannot continue without it
 177 # For native builds, we just set dependency on vpppaigen binary in top_builddir
 178 AM_COND_IF([CROSSCOMPILE],
 179 [
 180   AC_PATH_PROG([VPPAPIGEN], [vppapigen], [no])
 181   if test "$VPPAPIGEN" = "no"; then
 182     AC_MSG_ERROR([Externaly built vppapigen is needed when cross-compiling...])
 183   fi
 184 ],[
 185   VPPAPIGEN=\$\(top_builddir\)/vppapigen
 186 ])
 187 AC_SUBST([VPPAPIGEN])
 188
 189
 190 ###############################################################################
 191 # JAVA
 192 ###############################################################################
 193
 194 AM_COND_IF([ENABLE_JAPI],
 195 [
 196   AX_VPP_FIND_JDK8
 197   AC_SUBST(JAVA_HOME)
 198   AC_SUBST(JAVAC)
 199   AC_SUBST(JAVAH)
 200   AC_SUBST(JAR)
 201 ])
 202
 203 ###############################################################################
 204 # Output
 205 ###############################################################################
 206
 207 AC_OUTPUT
 208
 209 AC_MSG_RESULT([==============================================================================])
 210 PRINT_VAL([version], $PACKAGE $VERSION)
 211 PRINT_VAL([prefix], ${prefix})
 212 PRINT_VAL([libdir], ${libdir})
 213 PRINT_VAL([includedir], ${includedir})
 214 PRINT_VAL([CFLAGS], ${CFLAGS})
 215 PRINT_VAL([CPPFLAGS], ${CPPFLAGS})
 216 PRINT_VAL([LDFLAGS], ${LDFLAGS})
 217 AM_COND_IF([ENABLE_JAPI],
 218 [
 219   PRINT_VAL([JAVA_VERSION], ${JAVA_VERSION})
 220   PRINT_VAL([JAVA_HOME], ${JAVA_HOME})
 221 ])
 222
 223 AC_MSG_RESULT([])
 224 AC_MSG_RESULT([with:])
 225 m4_foreach([x], m4_dquote(list_of_with), [
 226   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${with_], x, [}])))
 227 ])
 228
 229 AC_MSG_RESULT([])
 230 AC_MSG_RESULT([enabled:])
 231 m4_foreach([x], m4_dquote(list_of_enabled), [
 232   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [}])))
 233 ])
 234
 235 AC_MSG_RESULT([])
 236 AC_MSG_RESULT([plugins:])
 237 m4_foreach([x], m4_dquote(list_of_plugins), [
 238   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [_plugin}])))
 239 ])
 240 AC_MSG_RESULT([==============================================================================])
 241
 242