src/configure.ac

   1 AC_INIT([vpp], [17.10], [vpp-dev@fd.io])
   2 LT_INIT
   3 AC_CONFIG_AUX_DIR([.])
   4 AM_INIT_AUTOMAKE([subdir-objects])
   5 AM_SILENT_RULES([yes])
   6 AC_CONFIG_FILES([Makefile plugins/Makefile vpp-api/python/Makefile vpp-api/java/Makefile])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_PROG_CC
  10 AM_PROG_AS
  11 AM_PROG_LIBTOOL
  12 AC_PROG_YACC
  13 AM_PATH_PYTHON
  14
  15 AM_CONDITIONAL([CROSSCOMPILE], [test "$cross_compiling" == "yes"])
  16
  17 ###############################################################################
  18 # Macros
  19 ###############################################################################
  20
  21 AC_DEFUN([ENABLE_ARG],
  22 [
  23   AC_ARG_ENABLE($1,
  24     AC_HELP_STRING(patsubst([--enable-$1],[_],[-]), $2),
  25     [enable_$1=yes n_enable_$1=1],
  26     [enable_$1=no n_enable_$1=0])
  27   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  28   m4_append([list_of_enabled], [$1], [, ])
  29 ])
  30
  31 AC_DEFUN([DISABLE_ARG],
  32 [
  33   AC_ARG_ENABLE($1,
  34     AC_HELP_STRING(patsubst([--disable-$1],[_],[-]), $2),
  35     [enable_$1=no n_enable_$1=0],
  36     [enable_$1=yes n_enable_$1=1])
  37   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  38   m4_append([list_of_enabled], [$1], [, ])
  39 ])
  40
  41 AC_DEFUN([WITH_ARG],
  42 [
  43   AC_ARG_WITH($1,
  44     AC_HELP_STRING(patsubst([--with-$1],[_],[-]), $2),
  45     [with_$1=yes n_with_$1=1],
  46     [with_$1=no n_with_$1=0])
  47   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  48   m4_append([list_of_with], [$1], [, ])
  49 ])
  50
  51 AC_DEFUN([WITHOUT_ARG],
  52 [
  53   AC_ARG_WITH($1,
  54     AC_HELP_STRING(patsubst([--without-$1],[_],[-]), $2),
  55     [with_$1=no n_with_$1=0],
  56     [with_$1=yes n_with_$1=1])
  57   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  58   m4_append([list_of_with], [$1], [, ])
  59 ])
  60
  61 AC_DEFUN([PLUGIN_ENABLED],
  62 [
  63    AC_ARG_ENABLE($1_plugin,
  64      AC_HELP_STRING([--disable-$1-plugin], [Do not build $1 plugin]),
  65        [enable_$1_plugin=no],
  66        [enable_$1_plugin=yes ])
  67   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  68   m4_append([list_of_plugins], [$1], [, ])
  69 ])
  70
  71 AC_DEFUN([PLUGIN_DISABLED],
  72 [
  73    AC_ARG_ENABLE($1_plugin,
  74      AC_HELP_STRING([--enable-$1-plugin], [Build $1 plugin]),
  75        [enable_$1_plugin=yes ],
  76        [enable_$1_plugin=no])
  77   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  78   m4_append([list_of_plugins], [$1], [, ])
  79 ])
  80
  81 AC_DEFUN([PRINT_VAL], [ AC_MSG_RESULT(AC_HELP_STRING($1,$2)) ])
  82
  83 AC_DEFUN([DPDK_IS_PMD_ENABLED],
  84 [
  85   AC_MSG_CHECKING([for $1 in rte_config.h])
  86   AC_COMPILE_IFELSE(
  87     [AC_LANG_PROGRAM(
  88       [[#include <rte_config.h>]],
  89       [[return RTE_$1;]],
  90     )],
  91     [with_$2=yes]
  92     [AC_MSG_RESULT([yes])],
  93     [with_$2=no]
  94     [AC_MSG_RESULT([no])]
  95   )
  96   AM_CONDITIONAL(m4_toupper(WITH_$2), test "$with_$2" = "yes")
  97   m4_append_uniq([list_of_with], [$2], [, ])
  98 ])
  99
 100 ###############################################################################
 101 # configure arguments
 102 ###############################################################################
 103
 104 # --enable-X
 105 ENABLE_ARG(tests,       [Enable unit tests])
 106 ENABLE_ARG(dpdk_shared, [Enable unit tests])
 107 ENABLE_ARG(perftool,    [Enable perftool])
 108 ENABLE_ARG(g2,          [Enable g2])
 109
 110 # --disable-X
 111 DISABLE_ARG(vlib,       [Disable vlib and dependant libs and binaries])
 112 DISABLE_ARG(svm,        [Disable svm and dependant libs and binaries])
 113 DISABLE_ARG(papi,       [Disable Python API bindings])
 114 DISABLE_ARG(japi,       [Disable Java API bindings])
 115
 116 # --with-X
 117
 118 # --without-X
 119 WITHOUT_ARG(libssl,     [Disable libssl])
 120 WITHOUT_ARG(apicli,     [Disable binary api CLI])
 121
 122 AC_ARG_WITH(unix,
 123             AC_HELP_STRING([--with-unix],[Compile unix version of clib]),
 124             [],
 125             [case $host_os in
 126               darwin* | linux*) with_unix=yes;;
 127               *) with_unix=no;;
 128               esac])
 129
 130 AM_CONDITIONAL(WITH_UNIX, test "$with_unix" = "yes")
 131
 132 AC_ARG_WITH(pre-data,
 133             AC_HELP_STRING([--with-pre-data],[Set buffer rewrite space]),
 134             [case $with_pre_data in
 135                128) ;;
 136                256) ;;
 137                *) with_pre_data="pre-data-not-set" ;;
 138              esac], [with_pre_data=128])
 139
 140 ###############################################################################
 141 # Substitutions and defines
 142 ###############################################################################
 143
 144 AC_SUBST(PRE_DATA_SIZE,         [$with_pre_data])
 145 AC_SUBST(APICLI,                [-DVPP_API_TEST_BUILTIN=${n_with_apicli}])
 146
 147 AC_DEFINE_UNQUOTED(DPDK_SHARED_LIB,     [${n_enable_dpdk_shared}])
 148 AC_DEFINE_UNQUOTED(WITH_LIBSSL,         [${n_with_libssl}])
 149
 150
 151 # Silence following noise:
 152 # ar: `u' modifier ignored since `D' is the default (see `U')
 153 AR_FLAGS=cr
 154 AC_SUBST(AR_FLAGS)
 155
 156 ###############################################################################
 157 # Plugins
 158 ###############################################################################
 159
 160 # Please keep alphabetical order
 161 PLUGIN_ENABLED(acl)
 162 PLUGIN_ENABLED(dpdk)
 163 PLUGIN_ENABLED(flowprobe)
 164 PLUGIN_ENABLED(gtpu)
 165 PLUGIN_ENABLED(ila)
 166 PLUGIN_ENABLED(ioam)
 167 PLUGIN_ENABLED(ixge)
 168 PLUGIN_ENABLED(lb)
 169 PLUGIN_ENABLED(memif)
 170 PLUGIN_ENABLED(pppoe)
 171 PLUGIN_ENABLED(sixrd)
 172 PLUGIN_ENABLED(snat)
 173
 174 ###############################################################################
 175 # Dependency checks
 176 ###############################################################################
 177
 178 AM_COND_IF([ENABLE_DPDK_SHARED],
 179 [
 180   AC_CHECK_HEADERS([rte_config.h],
 181     [],
 182     [AC_MSG_ERROR([DPDK header files not found])],)
 183   AC_CHECK_LIB( [dpdk], [rte_eal_init],
 184     [],
 185     [AC_MSG_ERROR([DPDK shared library not found])],)
 186 ])
 187
 188 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_MB, dpdk_aesni_mb_pmd)
 189 AM_COND_IF([WITH_DPDK_AESNI_MB_PMD],
 190 [
 191   AC_CHECK_LIB([IPSec_MB], [submit_job_sse], [],
 192                [AC_MSG_ERROR([IPSec_MB library not found])])
 193 ])
 194
 195 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_GCM, dpdk_aesni_gcm_pmd)
 196 AM_COND_IF([WITH_DPDK_AESNI_GCM_PMD],
 197 [
 198   AC_CHECK_LIB([isal_crypto], [aesni_gcm128_init], [],
 199                [AC_MSG_ERROR([isal_crypto library not found])])
 200 ])
 201
 202 DPDK_IS_PMD_ENABLED(LIBRTE_MLX5_PMD, dpdk_mlx5_pmd)
 203 AM_COND_IF([WITH_DPDK_MLX5_PMD],
 204 [
 205   AC_CHECK_LIB([ibverbs], [ibv_fork_init], [],
 206                [AC_MSG_ERROR([ibverbs library not found])])
 207 ])
 208
 209 DPDK_IS_PMD_ENABLED(LIBRTE_MLX4_PMD, dpdk_mlx4_pmd)
 210 AM_COND_IF([WITH_DPDK_MLX4_PMD],
 211 [
 212   AC_CHECK_LIB([ibverbs], [ibv_fork_init], [],
 213                [AC_MSG_ERROR([ibverbs library not found])])
 214 ])
 215
 216 AM_COND_IF([ENABLE_G2],
 217 [
 218   PKG_CHECK_MODULES(g2, gtk+-2.0)
 219 ])
 220
 221 # If cross-compiling, we need external vppapigen and we cannot continue without it
 222 # For native builds, we just set dependency on vpppaigen binary in top_builddir
 223 AM_COND_IF([CROSSCOMPILE],
 224 [
 225   AC_PATH_PROG([VPPAPIGEN], [vppapigen], [no])
 226   if test "$VPPAPIGEN" = "no"; then
 227     AC_MSG_ERROR([Externaly built vppapigen is needed when cross-compiling...])
 228   fi
 229 ],[
 230   VPPAPIGEN=\$\(top_builddir\)/vppapigen
 231 ])
 232 AC_SUBST([VPPAPIGEN])
 233
 234
 235 ###############################################################################
 236 # JAVA
 237 ###############################################################################
 238
 239 AM_COND_IF([ENABLE_JAPI],
 240 [
 241   AX_VPP_FIND_JDK8
 242   AC_SUBST(JAVA_HOME)
 243   AC_SUBST(JAVAC)
 244   AC_SUBST(JAVAH)
 245   AC_SUBST(JAR)
 246 ])
 247
 248 ###############################################################################
 249 # PYTHON
 250 ###############################################################################
 251
 252 AM_COND_IF([ENABLE_PAPI],
 253 [
 254   AM_PATH_PYTHON
 255 ])
 256
 257 ###############################################################################
 258 # Output
 259 ###############################################################################
 260
 261 AC_OUTPUT
 262
 263 AC_MSG_RESULT([==============================================================================])
 264 PRINT_VAL([version], $PACKAGE $VERSION)
 265 PRINT_VAL([prefix], ${prefix})
 266 PRINT_VAL([libdir], ${libdir})
 267 PRINT_VAL([includedir], ${includedir})
 268 PRINT_VAL([CFLAGS], ${CFLAGS})
 269 PRINT_VAL([CPPFLAGS], ${CPPFLAGS})
 270 PRINT_VAL([LDFLAGS], ${LDFLAGS})
 271 AM_COND_IF([ENABLE_JAPI],
 272 [
 273   PRINT_VAL([JAVA_VERSION], ${JAVA_VERSION})
 274   PRINT_VAL([JAVA_HOME], ${JAVA_HOME})
 275 ])
 276
 277 AC_MSG_RESULT([])
 278 AC_MSG_RESULT([with:])
 279 m4_foreach([x], m4_dquote(list_of_with), [
 280   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${with_], x, [}])))
 281 ])
 282
 283 AC_MSG_RESULT([])
 284 AC_MSG_RESULT([enabled:])
 285 m4_foreach([x], m4_dquote(list_of_enabled), [
 286   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [}])))
 287 ])
 288
 289 AC_MSG_RESULT([])
 290 AC_MSG_RESULT([plugins:])
 291 m4_foreach([x], m4_dquote(list_of_plugins), [
 292   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [_plugin}])))
 293 ])
 294 AC_MSG_RESULT([==============================================================================])
 295
 296