src/configure.ac

   1 AC_INIT([vpp], [18.10], [vpp-dev@fd.io])
   2 LT_INIT
   3 AC_CONFIG_AUX_DIR([.])
   4 AM_INIT_AUTOMAKE([subdir-objects])
   5 AM_SILENT_RULES([yes])
   6 AC_CONFIG_FILES([ \
   7   Makefile \
   8   plugins/Makefile \
   9   vpp-api/python/Makefile \
  10   vpp-api/java/Makefile \
  11   vpp-api/vapi/Makefile \
  12   vlib/config.h \
  13   vppinfra/config.h \
  14 ])
  15 AC_CONFIG_MACRO_DIR([m4])
  16
  17 AC_PROG_CC
  18 AC_PROG_CPP
  19 AM_PROG_AS
  20 AM_PROG_LIBTOOL
  21 AM_PATH_PYTHON
  22
  23 AM_CONDITIONAL([CROSSCOMPILE], [test "$cross_compiling" == "yes"])
  24
  25 ###############################################################################
  26 # Macros
  27 ###############################################################################
  28
  29 AC_DEFUN([ENABLE_ARG],
  30 [
  31   AC_ARG_ENABLE($1,
  32     AC_HELP_STRING(patsubst([--enable-$1],[_],[-]), $2),
  33     [enable_$1=yes n_enable_$1=1],
  34     [enable_$1=no n_enable_$1=0])
  35   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  36   m4_append([list_of_enabled], [$1], [, ])
  37 ])
  38
  39 AC_DEFUN([DISABLE_ARG],
  40 [
  41   AC_ARG_ENABLE($1,
  42     AC_HELP_STRING(patsubst([--disable-$1],[_],[-]), $2),
  43     [enable_$1=no n_enable_$1=0],
  44     [enable_$1=yes n_enable_$1=1])
  45   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  46   m4_append([list_of_enabled], [$1], [, ])
  47 ])
  48
  49 AC_DEFUN([WITH_ARG],
  50 [
  51   AC_ARG_WITH($1,
  52     AC_HELP_STRING(patsubst([--with-$1],[_],[-]), $2),
  53     [with_$1=yes n_with_$1=1],
  54     [with_$1=no n_with_$1=0])
  55   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  56   m4_append([list_of_with], [$1], [, ])
  57 ])
  58
  59 AC_DEFUN([WITHOUT_ARG],
  60 [
  61   AC_ARG_WITH($1,
  62     AC_HELP_STRING(patsubst([--without-$1],[_],[-]), $2),
  63     [with_$1=no n_with_$1=0],
  64     [with_$1=yes n_with_$1=1])
  65   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  66   m4_append([list_of_with], [$1], [, ])
  67 ])
  68
  69 AC_DEFUN([PLUGIN_ENABLED],
  70 [
  71    AC_ARG_ENABLE($1_plugin,
  72      AC_HELP_STRING([--disable-$1-plugin], [Do not build $1 plugin]),
  73        [enable_$1_plugin=no],
  74        [enable_$1_plugin=yes ])
  75   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  76   m4_append([list_of_plugins], [$1], [, ])
  77 ])
  78
  79 AC_DEFUN([PLUGIN_DISABLED],
  80 [
  81    AC_ARG_ENABLE($1_plugin,
  82      AC_HELP_STRING([--enable-$1-plugin], [Build $1 plugin]),
  83        [enable_$1_plugin=yes ],
  84        [enable_$1_plugin=no])
  85   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  86   m4_append([list_of_plugins], [$1], [, ])
  87 ])
  88
  89 AC_DEFUN([PRINT_VAL], [ AC_MSG_RESULT(AC_HELP_STRING($1,$2)) ])
  90
  91 AC_DEFUN([DPDK_IS_PMD_ENABLED],
  92 [
  93   AC_MSG_CHECKING([for $1 in rte_config.h])
  94   AC_COMPILE_IFELSE(
  95     [AC_LANG_PROGRAM(
  96       [[#include <rte_config.h>]],
  97       [[return RTE_$1;]],
  98     )],
  99     [with_$2=yes]
 100     [AC_MSG_RESULT([yes])],
 101     [with_$2=no]
 102     [AC_MSG_RESULT([no])]
 103   )
 104   AM_CONDITIONAL(m4_toupper(WITH_$2), test "$with_$2" = "yes")
 105   m4_append_uniq([list_of_with], [$2], [, ])
 106 ])
 107
 108 # Check if compiler supports specific flag
 109 AC_DEFUN([CC_CHECK_FLAG],
 110 [
 111   AC_MSG_CHECKING([if $CC supports $1])
 112   AC_LANG_PUSH([C])
 113   ac_saved_cflags="$CFLAGS"
 114   CFLAGS="-Werror $1"
 115   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 116   [cc_flag_check=yes],
 117   [cc_flag_check=no]
 118 )
 119   AC_MSG_RESULT([$cc_flag_check])
 120   CFLAGS="$ac_saved_cflags"
 121   AC_LANG_POP([C])
 122 ])
 123
 124 # This function deduces the BUILD HOST cache-line size by
 125 # inspecting /sys and/or /proc depending on the kernel / arch in use
 126 as_fn_log2_cache_line_size_p()
 127 {
 128   sysfs_cache_path="/sys/devices/system/cpu/cpu0/cache/index0/coherency_line_size"
 129   m4_define([read_cache_line_size_from_sysfs], [`head -n 1 $1`])
 130   m4_define([read_midr_implementer],
 131             [`awk '/implementer/ {print $[]4;exit}' /proc/cpuinfo`])
 132   m4_define([read_midr_cpuid],
 133             [`awk '/part/ {print $[]4;exit}' /proc/cpuinfo`])
 134
 135   #Check if sysfs path exists,to ignore warning, else do manual mapping
 136   AC_CHECK_FILE($sysfs_cache_path,
 137     [
 138       cache_line_size=read_cache_line_size_from_sysfs($sysfs_cache_path);
 139       if test $cache_line_size = "32"  ; then
 140           log2_cache_line_size="5";
 141       elif test $cache_line_size = "64"  ; then
 142           log2_cache_line_size="6";
 143       elif test $cache_line_size = "128"  ; then
 144           log2_cache_line_size="7";
 145       fi
 146       AC_MSG_NOTICE([cache_line_size/log2_cache_line_size deduced as $cache_line_size/$log2_cache_line_size])
 147     ],
 148     [
 149         #Define Implementer Ids here
 150         implementer_id_cavium=0x43
 151
 152         #Define CPU Ids here
 153         cpu_id_cavium_thunderx_cn88xx=0x0a1
 154         cpu_id_cavium_thunderx2_cn99xx=0x0af
 155
 156         implementer=read_midr_implementer()
 157         cpuid=read_midr_cpuid()
 158
 159         AC_MSG_CHECKING([for implementerid/cpuid to set log2_cache_line_size])
 160
 161         # Switch case to map log2_cache_line_size for implementer/cpuid combination.
 162         # Default case of Switch sets log2_cache_line_size to 6
 163         AS_CASE($implementer,
 164               #Switch Case for Cavium SoC's
 165               [$implementer_id_cavium],
 166                   [AS_CASE($cpuid,
 167                       #Only ThunderX2 is 64B. Remaining chips are 128B
 168                       [$cpu_id_cavium_thunderx2_cn99xx],
 169                             [AC_MSG_RESULT([Cavium/ThunderX2]);log2_cache_line_size=6],
 170                       [$cpu_id_cavium_thunderx_cn88xx],
 171                             [AC_MSG_RESULT([Cavium/ThunderX]);log2_cache_line_size=7],
 172                       [log2_cache_line_size=7;AC_MSG_RESULT([Cavium/OCTEONTx($cpuid)])]
 173                    )],
 174               #Add implementer specific case here:
 175
 176               #Default case: 64B for all SoC's
 177               [log2_cache_line_size=6;AC_MSG_RESULT([$implementer/$cpuid])]
 178         )
 179       AC_MSG_NOTICE([log2_cache_line_size deduced as $log2_cache_line_size])
 180     ]
 181   )
 182   echo $log2_cache_line_size
 183 }
 184
 185 ###############################################################################
 186 # configure arguments
 187 ###############################################################################
 188
 189 # --enable-X
 190 ENABLE_ARG(tests,       [Enable unit tests])
 191 ENABLE_ARG(dpdk_shared, [Enable unit tests])
 192 ENABLE_ARG(perftool,    [Enable perftool])
 193 ENABLE_ARG(g2,          [Enable g2])
 194 ENABLE_ARG(dlmalloc,    [Enable dlmalloc])
 195
 196 # --disable-X
 197 DISABLE_ARG(vlib,       [Disable vlib and dependant libs and binaries])
 198 DISABLE_ARG(svm,        [Disable svm and dependant libs and binaries])
 199 DISABLE_ARG(papi,       [Disable Python API bindings])
 200 DISABLE_ARG(japi,       [Disable Java API bindings])
 201
 202 # --with-X
 203
 204 # --without-X
 205 WITHOUT_ARG(libssl,     [Disable libssl])
 206 WITHOUT_ARG(apicli,     [Disable binary api CLI])
 207 WITHOUT_ARG(mbedtls,    [Disable mbedtls])
 208 WITHOUT_ARG(libnuma,    [for non numa architectures])
 209
 210 AC_ARG_WITH(log2-cache-line-bytes,
 211             AC_HELP_STRING([--with-log2-cache-line-bytes],[Set the cache line size, --with-log2-cache-line-bytes=5|6|7|auto]),
 212             [case $with_log2_cache_line_bytes in
 213               5 | 6 | 7);;
 214               auto) with_log2_cache_line_bytes=`as_fn_log2_cache_line_size_p`;;
 215               *) with_log2_cache_line_bytes="CONFIG_ERROR";;
 216               esac],
 217               [with_log2_cache_line_bytes=`as_fn_log2_cache_line_size_p`])
 218
 219 AC_ARG_WITH(unix,
 220             AC_HELP_STRING([--with-unix],[Compile unix version of clib]),
 221             [],
 222             [case $host_os in
 223               darwin* | linux*) with_unix=yes;;
 224               *) with_unix=no;;
 225               esac])
 226
 227 AM_CONDITIONAL(WITH_UNIX, test "$with_unix" = "yes")
 228
 229 AC_ARG_WITH(pre-data,
 230             AC_HELP_STRING([--with-pre-data],[Set buffer rewrite space]),
 231             [case $with_pre_data in
 232                128) ;;
 233                256) ;;
 234                *) with_pre_data="pre-data-not-set" ;;
 235              esac], [with_pre_data=128])
 236
 237 AM_CONDITIONAL(ENABLE_DLMALLOC, test "$enable_dlmalloc" = "yes")
 238
 239 ###############################################################################
 240 # Target CPU flags
 241 ###############################################################################
 242
 243 # Check if compiler supports march=core-avx2
 244 CC_CHECK_FLAG("-march=core-avx2")
 245 AS_IF([test "$cc_flag_check" = yes],
 246       [march_core_avx2=yes],
 247       [march_core_avx2=no])
 248 AM_CONDITIONAL([CC_SUPPORTS_AVX2], [test "$march_core_avx2" = "yes"])
 249
 250 # Check if compiler supports march=skylake-avx512
 251 CC_CHECK_FLAG("-march=skylake-avx512")
 252 AS_IF([test "$cc_flag_check" = yes],
 253   [march_skylake_avx512=yes],
 254   [march_skylake_avx512=no])
 255 AM_CONDITIONAL([CC_SUPPORTS_AVX512], [test "$march_skylake_avx512" = "yes"])
 256
 257 AS_CASE([$host_cpu],
 258         [x86_64], [CPU_FLAGS="-march=corei7 -mtune=corei7-avx"],
 259         [aarch64], [CPU_FLAGS="-march=armv8-a+crc"],
 260         [CPU_FLAGS=""],
 261 )
 262 AC_SUBST([CPU_FLAGS])
 263
 264 AC_SUBST([CPU_AVX2_FLAGS],"-march=core-avx2 -mtune=core-avx2")
 265 AC_SUBST([CPU_AVX512_FLAGS],"-march=skylake-avx512 -mtune=skylake-avx512")
 266
 267 AM_CONDITIONAL([CPU_X86_64], [test "$host_cpu" = "x86_64"])
 268 AM_CONDITIONAL([CPU_AARCH64], [test "$host_cpu" = "aarch64"])
 269
 270 ###############################################################################
 271 # misc compiler flags
 272 ###############################################################################
 273
 274 CC_CHECK_FLAG("-Wno-address-of-packed-member")
 275 AS_IF([test "$cc_flag_check" = yes],
 276         [CFLAGS="${CFLAGS} -Wno-address-of-packed-member"], [])
 277
 278 ###############################################################################
 279 # Substitutions and defines
 280 ###############################################################################
 281
 282 AC_SUBST(PRE_DATA_SIZE,         [$with_pre_data])
 283 AC_SUBST(LOG2_CACHE_LINE_BYTES, [$with_log2_cache_line_bytes])
 284 AC_SUBST(APICLI,                [-DVPP_API_TEST_BUILTIN=${n_with_apicli}])
 285 AC_SUBST(DLMALLOC,              [${n_enable_dlmalloc}])
 286
 287 AC_DEFINE_UNQUOTED(DPDK_SHARED_LIB,     [${n_enable_dpdk_shared}])
 288 AC_DEFINE_UNQUOTED(WITH_LIBSSL,         [${n_with_libssl}])
 289 AC_DEFINE_UNQUOTED(WITH_MBEDTLS,        [${n_with_mbedtls}])
 290 AC_DEFINE_UNQUOTED(WITH_LIBNUMA,        [${n_with_libnuma}])
 291
 292
 293 # Silence following noise:
 294 # ar: `u' modifier ignored since `D' is the default (see `U')
 295 AR_FLAGS=cr
 296 AC_SUBST(AR_FLAGS)
 297
 298 ###############################################################################
 299 # Plugins
 300 ###############################################################################
 301
 302 # Please keep alphabetical order
 303 PLUGIN_ENABLED(abf)
 304 PLUGIN_ENABLED(acl)
 305 PLUGIN_ENABLED(avf)
 306 PLUGIN_ENABLED(cdp)
 307 PLUGIN_ENABLED(dpdk)
 308 PLUGIN_ENABLED(flowprobe)
 309 PLUGIN_ENABLED(gbp)
 310 PLUGIN_ENABLED(gtpu)
 311 PLUGIN_ENABLED(igmp)
 312 PLUGIN_ENABLED(ila)
 313 PLUGIN_ENABLED(ioam)
 314 PLUGIN_ENABLED(ixge)
 315 PLUGIN_ENABLED(l2e)
 316 PLUGIN_ENABLED(lacp)
 317 PLUGIN_ENABLED(lb)
 318 PLUGIN_ENABLED(mactime)
 319 PLUGIN_ENABLED(marvell)
 320 PLUGIN_ENABLED(memif)
 321 PLUGIN_ENABLED(pppoe)
 322 PLUGIN_ENABLED(nat)
 323 PLUGIN_ENABLED(map)
 324 PLUGIN_ENABLED(srv6ad)
 325 PLUGIN_ENABLED(srv6am)
 326 PLUGIN_ENABLED(srv6as)
 327 PLUGIN_ENABLED(stn)
 328 PLUGIN_ENABLED(tlsmbedtls)
 329 PLUGIN_ENABLED(tlsopenssl)
 330 PLUGIN_ENABLED(unittest)
 331
 332 ###############################################################################
 333 # Dependency checks
 334 ###############################################################################
 335 AC_CHECK_FUNC([memfd_create], [AC_DEFINE([HAVE_MEMFD_CREATE], [1], [Define if memfd exists])])
 336
 337 AM_COND_IF([ENABLE_DPDK_SHARED],
 338 [
 339   AC_CHECK_HEADERS([rte_config.h],
 340     [],
 341     [AC_MSG_ERROR([DPDK header files not found])],)
 342   AC_CHECK_LIB( [dpdk], [rte_eal_init],
 343     [],
 344     [AC_MSG_ERROR([DPDK shared library not found])],)
 345 ])
 346
 347 with_aesni_mb_lib=no
 348 with_isa_l_crypto_lib=no
 349
 350 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_MB, dpdk_aesni_mb_pmd)
 351 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_GCM, dpdk_aesni_gcm_pmd)
 352
 353 AM_COND_IF([WITH_DPDK_AESNI_MB_PMD],
 354 [
 355   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 356                [with_aesni_mb_lib=yes],
 357                [AC_MSG_ERROR([IPSec_MB library not found])])
 358 ])
 359
 360 AM_COND_IF([WITH_DPDK_AESNI_GCM_PMD],
 361 [
 362   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 363     [with_aesni_mb_lib=yes],
 364     [AC_MSG_ERROR([IPSec_MB library not found])])
 365 ])
 366
 367 m4_append([list_of_with], [aesni_mb_lib], [, ])
 368 AM_CONDITIONAL(WITH_AESNI_MB_LIB, test "$with_aesni_mb_lib" = "yes")
 369
 370 m4_append([list_of_with], [isa_l_crypto_lib], [, ])
 371 AM_CONDITIONAL(WITH_ISA_L_CRYPTO_LIB, test "$with_isa_l_crypto_lib" = "yes")
 372
 373 AM_COND_IF([ENABLE_G2],
 374 [
 375   PKG_CHECK_MODULES(g2, gtk+-2.0)
 376 ])
 377
 378 AM_COND_IF([ENABLE_MARVELL_PLUGIN],
 379 [
 380   AC_CHECK_LIB( [musdk], [pp2_init],
 381     [],
 382     [
 383       AC_MSG_WARN([Marvell MUSDK library with PP2 support not found. Plugin disabled.])
 384       enable_marvell_plugin=no
 385       AM_CONDITIONAL(ENABLE_MARVELL_PLUGIN, false)
 386     ])
 387 ])
 388
 389 AM_COND_IF([WITH_MBEDTLS], [],
 390 [
 391   AC_MSG_WARN([mbedtls not enabled. Disabling tlsmbedtls plugin])
 392   enable_tlsmbedtls_plugin=no
 393   AM_CONDITIONAL(ENABLE_TLSMBEDTLS_PLUGIN, false)
 394 ])
 395
 396 AM_COND_IF([ENABLE_TLSMBEDTLS_PLUGIN],
 397 [
 398   AC_CHECK_HEADERS([mbedtls/ssl.h], [],
 399     [
 400       AC_MSG_WARN([mbedtls headers not found. TLS engine implementation disabled])
 401       enable_tlsmbedtls_plugin=no
 402       AM_CONDITIONAL(ENABLE_TLSMBEDTLS_PLUGIN, false)
 403     ], [])
 404 ])
 405
 406 AM_COND_IF([WITH_LIBSSL],
 407 [
 408   AC_CHECK_LIB([ssl -lcrypto], [SSL_set_async_callback],
 409     [
 410       AC_DEFINE([HAVE_OPENSSL_ASYNC], [1], [Define if new openssl interface exists])
 411     ])
 412 ],
 413 [
 414   AC_MSG_WARN([openssl not enabled. Disabling tlsopenssl plugin])
 415   enable_tlsopenssl_plugin=no
 416   AM_CONDITIONAL(ENABLE_TLSOPENSSL_PLUGIN, false)
 417 ])
 418
 419 ###############################################################################
 420 # JAVA
 421 ###############################################################################
 422
 423 AM_COND_IF([ENABLE_JAPI],
 424 [
 425   AX_VPP_FIND_JDK8
 426   AC_SUBST(JAVA_HOME)
 427   AC_SUBST(JAVAC)
 428   AC_SUBST(JAVAH)
 429   AC_SUBST(JAR)
 430 ])
 431
 432 ###############################################################################
 433 # PYTHON
 434 ###############################################################################
 435
 436 AM_COND_IF([ENABLE_PAPI],
 437 [
 438   AM_PATH_PYTHON
 439 ])
 440
 441 ###############################################################################
 442 # Output
 443 ###############################################################################
 444
 445 AC_OUTPUT
 446
 447 AC_MSG_RESULT([==============================================================================])
 448 PRINT_VAL([version], $PACKAGE $VERSION)
 449 PRINT_VAL([prefix], ${prefix})
 450 PRINT_VAL([libdir], ${libdir})
 451 PRINT_VAL([includedir], ${includedir})
 452 PRINT_VAL([CFLAGS], ${CFLAGS})
 453 PRINT_VAL([CPPFLAGS], ${CPPFLAGS})
 454 PRINT_VAL([LDFLAGS], ${LDFLAGS})
 455 PRINT_VAL([LOG2_CACHE_LINE_BYTES], ${with_log2_cache_line_bytes})
 456 PRINT_VAL([DLMALLOC], ${enable_dlmalloc})
 457 AM_COND_IF([ENABLE_JAPI],
 458 [
 459   PRINT_VAL([JAVA_VERSION], ${JAVA_VERSION})
 460   PRINT_VAL([JAVA_HOME], ${JAVA_HOME})
 461 ])
 462
 463 AC_MSG_RESULT([])
 464 AC_MSG_RESULT([with:])
 465 m4_foreach([x], m4_dquote(list_of_with), [
 466   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${with_], x, [}])))
 467 ])
 468
 469 AC_MSG_RESULT([])
 470 AC_MSG_RESULT([enabled:])
 471 m4_foreach([x], m4_dquote(list_of_enabled), [
 472   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [}])))
 473 ])
 474
 475 AC_MSG_RESULT([])
 476 AC_MSG_RESULT([plugins:])
 477 m4_foreach([x], m4_dquote(list_of_plugins), [
 478   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [_plugin}])))
 479 ])
 480 AC_MSG_RESULT([==============================================================================])
 481
 482