src/configure.ac

   1 AC_INIT([vpp], [18.07], [vpp-dev@fd.io])
   2 LT_INIT
   3 AC_CONFIG_AUX_DIR([.])
   4 AM_INIT_AUTOMAKE([subdir-objects])
   5 AM_SILENT_RULES([yes])
   6 AC_CONFIG_FILES([Makefile plugins/Makefile vpp-api/python/Makefile vpp-api/java/Makefile vpp-api/vapi/Makefile vpp-api/vom/Makefile])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_PROG_CC
  10 AC_PROG_CXX
  11 AC_PROG_CPP
  12 AM_PROG_AS
  13 AM_PROG_LIBTOOL
  14 AC_PROG_YACC
  15 AM_PATH_PYTHON
  16
  17 AM_CONDITIONAL([CROSSCOMPILE], [test "$cross_compiling" == "yes"])
  18
  19 ###############################################################################
  20 # Macros
  21 ###############################################################################
  22
  23 AC_DEFUN([ENABLE_ARG],
  24 [
  25   AC_ARG_ENABLE($1,
  26     AC_HELP_STRING(patsubst([--enable-$1],[_],[-]), $2),
  27     [enable_$1=yes n_enable_$1=1],
  28     [enable_$1=no n_enable_$1=0])
  29   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  30   m4_append([list_of_enabled], [$1], [, ])
  31 ])
  32
  33 AC_DEFUN([DISABLE_ARG],
  34 [
  35   AC_ARG_ENABLE($1,
  36     AC_HELP_STRING(patsubst([--disable-$1],[_],[-]), $2),
  37     [enable_$1=no n_enable_$1=0],
  38     [enable_$1=yes n_enable_$1=1])
  39   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  40   m4_append([list_of_enabled], [$1], [, ])
  41 ])
  42
  43 AC_DEFUN([WITH_ARG],
  44 [
  45   AC_ARG_WITH($1,
  46     AC_HELP_STRING(patsubst([--with-$1],[_],[-]), $2),
  47     [with_$1=yes n_with_$1=1],
  48     [with_$1=no n_with_$1=0])
  49   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  50   m4_append([list_of_with], [$1], [, ])
  51 ])
  52
  53 AC_DEFUN([WITHOUT_ARG],
  54 [
  55   AC_ARG_WITH($1,
  56     AC_HELP_STRING(patsubst([--without-$1],[_],[-]), $2),
  57     [with_$1=no n_with_$1=0],
  58     [with_$1=yes n_with_$1=1])
  59   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  60   m4_append([list_of_with], [$1], [, ])
  61 ])
  62
  63 AC_DEFUN([PLUGIN_ENABLED],
  64 [
  65    AC_ARG_ENABLE($1_plugin,
  66      AC_HELP_STRING([--disable-$1-plugin], [Do not build $1 plugin]),
  67        [enable_$1_plugin=no],
  68        [enable_$1_plugin=yes ])
  69   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  70   m4_append([list_of_plugins], [$1], [, ])
  71 ])
  72
  73 AC_DEFUN([PLUGIN_DISABLED],
  74 [
  75    AC_ARG_ENABLE($1_plugin,
  76      AC_HELP_STRING([--enable-$1-plugin], [Build $1 plugin]),
  77        [enable_$1_plugin=yes ],
  78        [enable_$1_plugin=no])
  79   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  80   m4_append([list_of_plugins], [$1], [, ])
  81 ])
  82
  83 AC_DEFUN([PRINT_VAL], [ AC_MSG_RESULT(AC_HELP_STRING($1,$2)) ])
  84
  85 AC_DEFUN([DPDK_IS_PMD_ENABLED],
  86 [
  87   AC_MSG_CHECKING([for $1 in rte_config.h])
  88   AC_COMPILE_IFELSE(
  89     [AC_LANG_PROGRAM(
  90       [[#include <rte_config.h>]],
  91       [[return RTE_$1;]],
  92     )],
  93     [with_$2=yes]
  94     [AC_MSG_RESULT([yes])],
  95     [with_$2=no]
  96     [AC_MSG_RESULT([no])]
  97   )
  98   AM_CONDITIONAL(m4_toupper(WITH_$2), test "$with_$2" = "yes")
  99   m4_append_uniq([list_of_with], [$2], [, ])
 100 ])
 101
 102 # Check if compiler supports specific flag
 103 AC_DEFUN([CC_CHECK_FLAG],
 104 [
 105   AC_MSG_CHECKING([if $CC supports $1])
 106   AC_LANG_PUSH([C])
 107   ac_saved_cflags="$CFLAGS"
 108   CFLAGS="-Werror $1"
 109   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 110   [cc_flag_check=yes],
 111   [cc_flag_check=no]
 112 )
 113   AC_MSG_RESULT([$cc_flag_check])
 114   CFLAGS="$ac_saved_cflags"
 115   AC_LANG_POP([C])
 116 ])
 117
 118 ###############################################################################
 119 # configure arguments
 120 ###############################################################################
 121
 122 # --enable-X
 123 ENABLE_ARG(tests,       [Enable unit tests])
 124 ENABLE_ARG(dpdk_shared, [Enable unit tests])
 125 ENABLE_ARG(perftool,    [Enable perftool])
 126 ENABLE_ARG(g2,          [Enable g2])
 127
 128 # --disable-X
 129 DISABLE_ARG(vlib,       [Disable vlib and dependant libs and binaries])
 130 DISABLE_ARG(svm,        [Disable svm and dependant libs and binaries])
 131 DISABLE_ARG(papi,       [Disable Python API bindings])
 132 DISABLE_ARG(japi,       [Disable Java API bindings])
 133 DISABLE_ARG(vom,        [Disable VPP object model bindings])
 134
 135 # --with-X
 136
 137 # --without-X
 138 WITHOUT_ARG(libssl,     [Disable libssl])
 139 WITHOUT_ARG(apicli,     [Disable binary api CLI])
 140 WITHOUT_ARG(mbedtls,    [Disable mbedtls])
 141
 142 AC_ARG_WITH(unix,
 143             AC_HELP_STRING([--with-unix],[Compile unix version of clib]),
 144             [],
 145             [case $host_os in
 146               darwin* | linux*) with_unix=yes;;
 147               *) with_unix=no;;
 148               esac])
 149
 150 AM_CONDITIONAL(WITH_UNIX, test "$with_unix" = "yes")
 151
 152 AC_ARG_WITH(pre-data,
 153             AC_HELP_STRING([--with-pre-data],[Set buffer rewrite space]),
 154             [case $with_pre_data in
 155                128) ;;
 156                256) ;;
 157                *) with_pre_data="pre-data-not-set" ;;
 158              esac], [with_pre_data=128])
 159
 160 ###############################################################################
 161 # Target CPU flags
 162 ###############################################################################
 163
 164 # Check if compiler supports march=core-avx2
 165 CC_CHECK_FLAG("-march=core-avx2")
 166 AS_IF([test "$cc_flag_check" = yes],
 167       [march_core_avx2=yes],
 168       [march_core_avx2=no])
 169 AM_CONDITIONAL([CC_SUPPORTS_AVX2], [test "$march_core_avx2" = "yes"])
 170
 171 # Check if compiler supports march=skylake-avx512
 172 CC_CHECK_FLAG("-march=skylake-avx512")
 173 AS_IF([test "$cc_flag_check" = yes],
 174   [march_skylake_avx512=yes],
 175   [march_skylake_avx512=no])
 176 AM_CONDITIONAL([CC_SUPPORTS_AVX512], [test "$march_skylake_avx512" = "yes"])
 177
 178 AS_CASE([$build_cpu],
 179         [x86_64], [CPU_FLAGS="-march=corei7 -mtune=corei7-avx"],
 180         [aarch64], [CPU_FLAGS="-march=armv8-a+crc"],
 181         [CPU_FLAGS=""],
 182 )
 183 AC_SUBST([CPU_FLAGS])
 184
 185 AC_SUBST([CPU_AVX2_FLAGS],"-march=core-avx2 -mtune=core-avx2")
 186 AC_SUBST([CPU_AVX512_FLAGS],"-march=skylake-avx512 -mtune=skylake-avx512")
 187
 188 AM_CONDITIONAL([CPU_X86_64], [test "$build_cpu" = "x86_64"])
 189 AM_CONDITIONAL([CPU_AARCH64], [test "$build_cpu" = "aarch64"])
 190
 191 ###############################################################################
 192 # misc compiler flags
 193 ###############################################################################
 194
 195 CC_CHECK_FLAG("-Wno-address-of-packed-member")
 196 AS_IF([test "$cc_flag_check" = yes],
 197         [CFLAGS="${CFLAGS} -Wno-address-of-packed-member"], [])
 198
 199 ###############################################################################
 200 # Substitutions and defines
 201 ###############################################################################
 202
 203 AC_SUBST(PRE_DATA_SIZE,         [$with_pre_data])
 204 AC_SUBST(APICLI,                [-DVPP_API_TEST_BUILTIN=${n_with_apicli}])
 205
 206 AC_DEFINE_UNQUOTED(DPDK_SHARED_LIB,     [${n_enable_dpdk_shared}])
 207 AC_DEFINE_UNQUOTED(WITH_LIBSSL,         [${n_with_libssl}])
 208 AC_DEFINE_UNQUOTED(WITH_MBEDTLS,        [${n_with_mbedtls}])
 209
 210
 211 # Silence following noise:
 212 # ar: `u' modifier ignored since `D' is the default (see `U')
 213 AR_FLAGS=cr
 214 AC_SUBST(AR_FLAGS)
 215
 216 ###############################################################################
 217 # Plugins
 218 ###############################################################################
 219
 220 # Please keep alphabetical order
 221 PLUGIN_ENABLED(abf)
 222 PLUGIN_ENABLED(acl)
 223 PLUGIN_ENABLED(avf)
 224 PLUGIN_ENABLED(cdp)
 225 PLUGIN_ENABLED(dpdk)
 226 PLUGIN_ENABLED(flowprobe)
 227 PLUGIN_ENABLED(gbp)
 228 PLUGIN_ENABLED(gtpu)
 229 PLUGIN_ENABLED(igmp)
 230 PLUGIN_ENABLED(ila)
 231 PLUGIN_ENABLED(ioam)
 232 PLUGIN_ENABLED(ixge)
 233 PLUGIN_ENABLED(kubeproxy)
 234 PLUGIN_ENABLED(l2e)
 235 PLUGIN_ENABLED(lacp)
 236 PLUGIN_ENABLED(lb)
 237 PLUGIN_ENABLED(marvell)
 238 PLUGIN_ENABLED(memif)
 239 PLUGIN_ENABLED(pppoe)
 240 PLUGIN_ENABLED(nat)
 241 PLUGIN_ENABLED(srv6ad)
 242 PLUGIN_ENABLED(srv6am)
 243 PLUGIN_ENABLED(srv6as)
 244 PLUGIN_ENABLED(stn)
 245 PLUGIN_ENABLED(tlsmbedtls)
 246 PLUGIN_ENABLED(tlsopenssl)
 247
 248 ###############################################################################
 249 # Dependency checks
 250 ###############################################################################
 251 AC_CHECK_FUNC([memfd_create], [AC_DEFINE([HAVE_MEMFD_CREATE], [1], [Define if memfd exists])])
 252
 253 AM_COND_IF([ENABLE_DPDK_SHARED],
 254 [
 255   AC_CHECK_HEADERS([rte_config.h],
 256     [],
 257     [AC_MSG_ERROR([DPDK header files not found])],)
 258   AC_CHECK_LIB( [dpdk], [rte_eal_init],
 259     [],
 260     [AC_MSG_ERROR([DPDK shared library not found])],)
 261 ])
 262
 263 with_aesni_mb_lib=no
 264 with_isa_l_crypto_lib=no
 265
 266 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_MB, dpdk_aesni_mb_pmd)
 267 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_GCM, dpdk_aesni_gcm_pmd)
 268
 269 AM_COND_IF([WITH_DPDK_AESNI_MB_PMD],
 270 [
 271   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 272                [with_aesni_mb_lib=yes],
 273                [AC_MSG_ERROR([IPSec_MB library not found])])
 274 ])
 275
 276 AM_COND_IF([WITH_DPDK_AESNI_GCM_PMD],
 277 [
 278   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 279     [with_aesni_mb_lib=yes],
 280     [AC_MSG_ERROR([IPSec_MB library not found])])
 281 ])
 282
 283 m4_append([list_of_with], [aesni_mb_lib], [, ])
 284 AM_CONDITIONAL(WITH_AESNI_MB_LIB, test "$with_aesni_mb_lib" = "yes")
 285
 286 m4_append([list_of_with], [isa_l_crypto_lib], [, ])
 287 AM_CONDITIONAL(WITH_ISA_L_CRYPTO_LIB, test "$with_isa_l_crypto_lib" = "yes")
 288
 289 AM_COND_IF([ENABLE_G2],
 290 [
 291   PKG_CHECK_MODULES(g2, gtk+-2.0)
 292 ])
 293
 294 AM_COND_IF([ENABLE_MARVELL_PLUGIN],
 295 [
 296   AC_CHECK_LIB( [musdk], [pp2_init],
 297     [],
 298     [
 299       AC_MSG_WARN([Marvell MUSDK library with PP2 support not found. Plugin disabled.])
 300       enable_marvell_plugin=no
 301       AM_CONDITIONAL(ENABLE_MARVELL_PLUGIN, false)
 302     ])
 303 ])
 304
 305 AM_COND_IF([WITH_MBEDTLS], [],
 306 [
 307   AC_MSG_WARN([mbedtls not enabled. Disabling tlsmbedtls plugin])
 308   enable_tlsmbedtls_plugin=no
 309   AM_CONDITIONAL(ENABLE_TLSMBEDTLS_PLUGIN, false)
 310 ])
 311
 312 AM_COND_IF([ENABLE_TLSMBEDTLS_PLUGIN],
 313 [
 314   AC_CHECK_HEADERS([mbedtls/ssl.h], [],
 315     [
 316       AC_MSG_WARN([mbedtls headers not found. TLS engine implementation disabled])
 317       enable_tlsmbedtls_plugin=no
 318       AM_CONDITIONAL(ENABLE_TLSMBEDTLS_PLUGIN, false)
 319     ], [])
 320 ])
 321
 322 AM_COND_IF([WITH_LIBSSL], [],
 323 [
 324   AC_MSG_WARN([openssl not enabled. Disabling tlsopenssl plugin])
 325   enable_tlsopenssl_plugin=no
 326   AM_CONDITIONAL(ENABLE_TLSOPENSSL_PLUGIN, false)
 327 ])
 328
 329 ###############################################################################
 330 # JAVA
 331 ###############################################################################
 332
 333 AM_COND_IF([ENABLE_JAPI],
 334 [
 335   AX_VPP_FIND_JDK8
 336   AC_SUBST(JAVA_HOME)
 337   AC_SUBST(JAVAC)
 338   AC_SUBST(JAVAH)
 339   AC_SUBST(JAR)
 340 ])
 341
 342 ###############################################################################
 343 # PYTHON
 344 ###############################################################################
 345
 346 AM_COND_IF([ENABLE_PAPI],
 347 [
 348   AM_PATH_PYTHON
 349 ])
 350
 351 ###############################################################################
 352 # Output
 353 ###############################################################################
 354
 355 AC_OUTPUT
 356
 357 AC_MSG_RESULT([==============================================================================])
 358 PRINT_VAL([version], $PACKAGE $VERSION)
 359 PRINT_VAL([prefix], ${prefix})
 360 PRINT_VAL([libdir], ${libdir})
 361 PRINT_VAL([includedir], ${includedir})
 362 PRINT_VAL([CFLAGS], ${CFLAGS})
 363 PRINT_VAL([CPPFLAGS], ${CPPFLAGS})
 364 PRINT_VAL([LDFLAGS], ${LDFLAGS})
 365 AM_COND_IF([ENABLE_JAPI],
 366 [
 367   PRINT_VAL([JAVA_VERSION], ${JAVA_VERSION})
 368   PRINT_VAL([JAVA_HOME], ${JAVA_HOME})
 369 ])
 370
 371 AC_MSG_RESULT([])
 372 AC_MSG_RESULT([with:])
 373 m4_foreach([x], m4_dquote(list_of_with), [
 374   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${with_], x, [}])))
 375 ])
 376
 377 AC_MSG_RESULT([])
 378 AC_MSG_RESULT([enabled:])
 379 m4_foreach([x], m4_dquote(list_of_enabled), [
 380   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [}])))
 381 ])
 382
 383 AC_MSG_RESULT([])
 384 AC_MSG_RESULT([plugins:])
 385 m4_foreach([x], m4_dquote(list_of_plugins), [
 386   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [_plugin}])))
 387 ])
 388 AC_MSG_RESULT([==============================================================================])
 389
 390