src/configure.ac

   1 AC_INIT([vpp], [17.10], [vpp-dev@fd.io])
   2 LT_INIT
   3 AC_CONFIG_AUX_DIR([.])
   4 AM_INIT_AUTOMAKE([subdir-objects])
   5 AM_SILENT_RULES([yes])
   6 AC_CONFIG_FILES([Makefile plugins/Makefile vpp-api/python/Makefile vpp-api/java/Makefile vpp-api/vapi/Makefile])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_PROG_CC
  10 AC_PROG_CXX
  11 AM_PROG_AS
  12 AM_PROG_LIBTOOL
  13 AC_PROG_YACC
  14 AM_PATH_PYTHON
  15
  16 AM_CONDITIONAL([CROSSCOMPILE], [test "$cross_compiling" == "yes"])
  17
  18 ###############################################################################
  19 # Macros
  20 ###############################################################################
  21
  22 AC_DEFUN([ENABLE_ARG],
  23 [
  24   AC_ARG_ENABLE($1,
  25     AC_HELP_STRING(patsubst([--enable-$1],[_],[-]), $2),
  26     [enable_$1=yes n_enable_$1=1],
  27     [enable_$1=no n_enable_$1=0])
  28   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  29   m4_append([list_of_enabled], [$1], [, ])
  30 ])
  31
  32 AC_DEFUN([DISABLE_ARG],
  33 [
  34   AC_ARG_ENABLE($1,
  35     AC_HELP_STRING(patsubst([--disable-$1],[_],[-]), $2),
  36     [enable_$1=no n_enable_$1=0],
  37     [enable_$1=yes n_enable_$1=1])
  38   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  39   m4_append([list_of_enabled], [$1], [, ])
  40 ])
  41
  42 AC_DEFUN([WITH_ARG],
  43 [
  44   AC_ARG_WITH($1,
  45     AC_HELP_STRING(patsubst([--with-$1],[_],[-]), $2),
  46     [with_$1=yes n_with_$1=1],
  47     [with_$1=no n_with_$1=0])
  48   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  49   m4_append([list_of_with], [$1], [, ])
  50 ])
  51
  52 AC_DEFUN([WITHOUT_ARG],
  53 [
  54   AC_ARG_WITH($1,
  55     AC_HELP_STRING(patsubst([--without-$1],[_],[-]), $2),
  56     [with_$1=no n_with_$1=0],
  57     [with_$1=yes n_with_$1=1])
  58   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  59   m4_append([list_of_with], [$1], [, ])
  60 ])
  61
  62 AC_DEFUN([PLUGIN_ENABLED],
  63 [
  64    AC_ARG_ENABLE($1_plugin,
  65      AC_HELP_STRING([--disable-$1-plugin], [Do not build $1 plugin]),
  66        [enable_$1_plugin=no],
  67        [enable_$1_plugin=yes ])
  68   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  69   m4_append([list_of_plugins], [$1], [, ])
  70 ])
  71
  72 AC_DEFUN([PLUGIN_DISABLED],
  73 [
  74    AC_ARG_ENABLE($1_plugin,
  75      AC_HELP_STRING([--enable-$1-plugin], [Build $1 plugin]),
  76        [enable_$1_plugin=yes ],
  77        [enable_$1_plugin=no])
  78   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  79   m4_append([list_of_plugins], [$1], [, ])
  80 ])
  81
  82 AC_DEFUN([PRINT_VAL], [ AC_MSG_RESULT(AC_HELP_STRING($1,$2)) ])
  83
  84 AC_DEFUN([DPDK_IS_PMD_ENABLED],
  85 [
  86   AC_MSG_CHECKING([for $1 in rte_config.h])
  87   AC_COMPILE_IFELSE(
  88     [AC_LANG_PROGRAM(
  89       [[#include <rte_config.h>]],
  90       [[return RTE_$1;]],
  91     )],
  92     [with_$2=yes]
  93     [AC_MSG_RESULT([yes])],
  94     [with_$2=no]
  95     [AC_MSG_RESULT([no])]
  96   )
  97   AM_CONDITIONAL(m4_toupper(WITH_$2), test "$with_$2" = "yes")
  98   m4_append_uniq([list_of_with], [$2], [, ])
  99 ])
 100
 101 AC_DEFUN([DETECT_DPDK_IS_1702_OR_1705],
 102 [
 103   AC_MSG_CHECKING([for RTE_VERSION 17.02/17.05 in rte_version.h])
 104   AC_TRY_RUN(
 105     [
 106     #include <rte_version.h>
 107     int main()
 108     {
 109       return ((RTE_VER_YEAR != 17) ||
 110               (RTE_VER_MONTH != 2 && RTE_VER_MONTH != 5));
 111     }
 112     ],
 113     [dpdk_is_1702_or_1705=yes]
 114     [AC_MSG_RESULT([yes])],
 115     [dpdk_is_1702_or_1705=no]
 116     [AC_MSG_RESULT([no])]
 117   )
 118   AM_CONDITIONAL(DPDK_IS_1702_OR_1705, test "$dpdk_is_1702_or_1705" = "yes")
 119 ])
 120
 121 ###############################################################################
 122 # configure arguments
 123 ###############################################################################
 124
 125 # --enable-X
 126 ENABLE_ARG(tests,       [Enable unit tests])
 127 ENABLE_ARG(dpdk_shared, [Enable unit tests])
 128 ENABLE_ARG(perftool,    [Enable perftool])
 129 ENABLE_ARG(g2,          [Enable g2])
 130
 131 # --disable-X
 132 DISABLE_ARG(vlib,       [Disable vlib and dependant libs and binaries])
 133 DISABLE_ARG(svm,        [Disable svm and dependant libs and binaries])
 134 DISABLE_ARG(papi,       [Disable Python API bindings])
 135 DISABLE_ARG(japi,       [Disable Java API bindings])
 136
 137 # --with-X
 138
 139 # --without-X
 140 WITHOUT_ARG(libssl,     [Disable libssl])
 141 WITHOUT_ARG(apicli,     [Disable binary api CLI])
 142
 143 AC_ARG_WITH(unix,
 144             AC_HELP_STRING([--with-unix],[Compile unix version of clib]),
 145             [],
 146             [case $host_os in
 147               darwin* | linux*) with_unix=yes;;
 148               *) with_unix=no;;
 149               esac])
 150
 151 AM_CONDITIONAL(WITH_UNIX, test "$with_unix" = "yes")
 152
 153 AC_ARG_WITH(pre-data,
 154             AC_HELP_STRING([--with-pre-data],[Set buffer rewrite space]),
 155             [case $with_pre_data in
 156                128) ;;
 157                256) ;;
 158                *) with_pre_data="pre-data-not-set" ;;
 159              esac], [with_pre_data=128])
 160
 161 ###############################################################################
 162 # Substitutions and defines
 163 ###############################################################################
 164
 165 AC_SUBST(PRE_DATA_SIZE,         [$with_pre_data])
 166 AC_SUBST(APICLI,                [-DVPP_API_TEST_BUILTIN=${n_with_apicli}])
 167
 168 AC_DEFINE_UNQUOTED(DPDK_SHARED_LIB,     [${n_enable_dpdk_shared}])
 169 AC_DEFINE_UNQUOTED(WITH_LIBSSL,         [${n_with_libssl}])
 170
 171
 172 # Silence following noise:
 173 # ar: `u' modifier ignored since `D' is the default (see `U')
 174 AR_FLAGS=cr
 175 AC_SUBST(AR_FLAGS)
 176
 177 ###############################################################################
 178 # Plugins
 179 ###############################################################################
 180
 181 # Please keep alphabetical order
 182 PLUGIN_ENABLED(acl)
 183 PLUGIN_ENABLED(dpdk)
 184 PLUGIN_ENABLED(flowprobe)
 185 PLUGIN_ENABLED(gtpu)
 186 PLUGIN_ENABLED(ila)
 187 PLUGIN_ENABLED(ioam)
 188 PLUGIN_ENABLED(ixge)
 189 PLUGIN_ENABLED(lb)
 190 PLUGIN_ENABLED(memif)
 191 PLUGIN_ENABLED(pppoe)
 192 PLUGIN_ENABLED(sixrd)
 193 PLUGIN_ENABLED(nat)
 194
 195 ###############################################################################
 196 # Dependency checks
 197 ###############################################################################
 198
 199 AM_COND_IF([ENABLE_DPDK_SHARED],
 200 [
 201   AC_CHECK_HEADERS([rte_config.h],
 202     [],
 203     [AC_MSG_ERROR([DPDK header files not found])],)
 204   AC_CHECK_LIB( [dpdk], [rte_eal_init],
 205     [],
 206     [AC_MSG_ERROR([DPDK shared library not found])],)
 207 ])
 208
 209 with_aesni_mb_lib=no
 210 with_isa_l_crypto_lib=no
 211
 212 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_MB, dpdk_aesni_mb_pmd)
 213 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_GCM, dpdk_aesni_gcm_pmd)
 214
 215 DETECT_DPDK_IS_1702_OR_1705()
 216
 217 AM_COND_IF([WITH_DPDK_AESNI_MB_PMD],
 218 [
 219   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 220                [with_aesni_mb_lib=yes],
 221                [AC_MSG_ERROR([IPSec_MB library not found])])
 222 ])
 223
 224 AM_COND_IF([WITH_DPDK_AESNI_GCM_PMD],
 225 [
 226   AM_COND_IF([DPDK_IS_1702_OR_1705],
 227   [
 228     AC_CHECK_LIB([isal_crypto], [aesni_gcm128_init],
 229                  [with_isa_l_crypto_lib=yes],
 230                  [AC_MSG_ERROR([isal_crypto library not found])])
 231   ],
 232   [
 233     AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 234                  [with_aesni_mb_lib=yes],
 235                  [AC_MSG_ERROR([IPSec_MB library not found])])
 236   ])
 237 ])
 238
 239 m4_append([list_of_with], [aesni_mb_lib], [, ])
 240 AM_CONDITIONAL(WITH_AESNI_MB_LIB, test "$with_aesni_mb_lib" = "yes")
 241
 242 m4_append([list_of_with], [isa_l_crypto_lib], [, ])
 243 AM_CONDITIONAL(WITH_ISA_L_CRYPTO_LIB, test "$with_isa_l_crypto_lib" = "yes")
 244
 245
 246 with_ibverbs_lib=no
 247 DPDK_IS_PMD_ENABLED(LIBRTE_MLX4_PMD, dpdk_mlx4_pmd)
 248 AM_COND_IF([WITH_DPDK_MLX4_PMD],
 249 [
 250   AC_CHECK_LIB([ibverbs], [ibv_fork_init],
 251                [with_ibverbs_lib=yes],
 252                [AC_MSG_ERROR([ibverbs library not found])])
 253 ])
 254
 255 DPDK_IS_PMD_ENABLED(LIBRTE_MLX5_PMD, dpdk_mlx5_pmd)
 256 AM_COND_IF([WITH_DPDK_MLX5_PMD],
 257 [
 258   AC_CHECK_LIB([ibverbs], [ibv_fork_init],
 259                [with_ibverbs_lib=yes],
 260                [AC_MSG_ERROR([ibverbs library not found])])
 261 ])
 262
 263 m4_append([list_of_with], [ibverbs_lib], [, ])
 264 AM_CONDITIONAL(WITH_IBVERBS_LIB, test "$with_ibverbs_lib" = "yes")
 265
 266
 267 AM_COND_IF([ENABLE_G2],
 268 [
 269   PKG_CHECK_MODULES(g2, gtk+-2.0)
 270 ])
 271
 272 # If cross-compiling, we need external vppapigen and we cannot continue without it
 273 # For native builds, we just set dependency on vpppaigen binary in top_builddir
 274 AM_COND_IF([CROSSCOMPILE],
 275 [
 276   AC_PATH_PROG([VPPAPIGEN], [vppapigen], [no])
 277   if test "$VPPAPIGEN" = "no"; then
 278     AC_MSG_ERROR([Externaly built vppapigen is needed when cross-compiling...])
 279   fi
 280 ],[
 281   VPPAPIGEN=\$\(top_builddir\)/vppapigen
 282 ])
 283 AC_SUBST([VPPAPIGEN])
 284
 285
 286 ###############################################################################
 287 # JAVA
 288 ###############################################################################
 289
 290 AM_COND_IF([ENABLE_JAPI],
 291 [
 292   AX_VPP_FIND_JDK8
 293   AC_SUBST(JAVA_HOME)
 294   AC_SUBST(JAVAC)
 295   AC_SUBST(JAVAH)
 296   AC_SUBST(JAR)
 297 ])
 298
 299 ###############################################################################
 300 # PYTHON
 301 ###############################################################################
 302
 303 AM_COND_IF([ENABLE_PAPI],
 304 [
 305   AM_PATH_PYTHON
 306 ])
 307
 308 ###############################################################################
 309 # Output
 310 ###############################################################################
 311
 312 AC_OUTPUT
 313
 314 AC_MSG_RESULT([==============================================================================])
 315 PRINT_VAL([version], $PACKAGE $VERSION)
 316 PRINT_VAL([prefix], ${prefix})
 317 PRINT_VAL([libdir], ${libdir})
 318 PRINT_VAL([includedir], ${includedir})
 319 PRINT_VAL([CFLAGS], ${CFLAGS})
 320 PRINT_VAL([CPPFLAGS], ${CPPFLAGS})
 321 PRINT_VAL([LDFLAGS], ${LDFLAGS})
 322 AM_COND_IF([ENABLE_JAPI],
 323 [
 324   PRINT_VAL([JAVA_VERSION], ${JAVA_VERSION})
 325   PRINT_VAL([JAVA_HOME], ${JAVA_HOME})
 326 ])
 327
 328 AC_MSG_RESULT([])
 329 AC_MSG_RESULT([with:])
 330 m4_foreach([x], m4_dquote(list_of_with), [
 331   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${with_], x, [}])))
 332 ])
 333
 334 AC_MSG_RESULT([])
 335 AC_MSG_RESULT([enabled:])
 336 m4_foreach([x], m4_dquote(list_of_enabled), [
 337   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [}])))
 338 ])
 339
 340 AC_MSG_RESULT([])
 341 AC_MSG_RESULT([plugins:])
 342 m4_foreach([x], m4_dquote(list_of_plugins), [
 343   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [_plugin}])))
 344 ])
 345 AC_MSG_RESULT([==============================================================================])
 346
 347