src/configure.ac

   1 AC_INIT([vpp], [18.07], [vpp-dev@fd.io])
   2 LT_INIT
   3 AC_CONFIG_AUX_DIR([.])
   4 AM_INIT_AUTOMAKE([subdir-objects])
   5 AM_SILENT_RULES([yes])
   6 AC_CONFIG_FILES([ \
   7   Makefile \
   8   plugins/Makefile \
   9   vpp-api/python/Makefile \
  10   vpp-api/java/Makefile \
  11   vpp-api/vapi/Makefile \
  12   vlib/config.h \
  13 ])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AC_PROG_CC
  17 AC_PROG_CPP
  18 AM_PROG_AS
  19 AM_PROG_LIBTOOL
  20 AM_PATH_PYTHON
  21
  22 AM_CONDITIONAL([CROSSCOMPILE], [test "$cross_compiling" == "yes"])
  23
  24 ###############################################################################
  25 # Macros
  26 ###############################################################################
  27
  28 AC_DEFUN([ENABLE_ARG],
  29 [
  30   AC_ARG_ENABLE($1,
  31     AC_HELP_STRING(patsubst([--enable-$1],[_],[-]), $2),
  32     [enable_$1=yes n_enable_$1=1],
  33     [enable_$1=no n_enable_$1=0])
  34   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  35   m4_append([list_of_enabled], [$1], [, ])
  36 ])
  37
  38 AC_DEFUN([DISABLE_ARG],
  39 [
  40   AC_ARG_ENABLE($1,
  41     AC_HELP_STRING(patsubst([--disable-$1],[_],[-]), $2),
  42     [enable_$1=no n_enable_$1=0],
  43     [enable_$1=yes n_enable_$1=1])
  44   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  45   m4_append([list_of_enabled], [$1], [, ])
  46 ])
  47
  48 AC_DEFUN([WITH_ARG],
  49 [
  50   AC_ARG_WITH($1,
  51     AC_HELP_STRING(patsubst([--with-$1],[_],[-]), $2),
  52     [with_$1=yes n_with_$1=1],
  53     [with_$1=no n_with_$1=0])
  54   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  55   m4_append([list_of_with], [$1], [, ])
  56 ])
  57
  58 AC_DEFUN([WITHOUT_ARG],
  59 [
  60   AC_ARG_WITH($1,
  61     AC_HELP_STRING(patsubst([--without-$1],[_],[-]), $2),
  62     [with_$1=no n_with_$1=0],
  63     [with_$1=yes n_with_$1=1])
  64   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  65   m4_append([list_of_with], [$1], [, ])
  66 ])
  67
  68 AC_DEFUN([PLUGIN_ENABLED],
  69 [
  70    AC_ARG_ENABLE($1_plugin,
  71      AC_HELP_STRING([--disable-$1-plugin], [Do not build $1 plugin]),
  72        [enable_$1_plugin=no],
  73        [enable_$1_plugin=yes ])
  74   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  75   m4_append([list_of_plugins], [$1], [, ])
  76 ])
  77
  78 AC_DEFUN([PLUGIN_DISABLED],
  79 [
  80    AC_ARG_ENABLE($1_plugin,
  81      AC_HELP_STRING([--enable-$1-plugin], [Build $1 plugin]),
  82        [enable_$1_plugin=yes ],
  83        [enable_$1_plugin=no])
  84   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  85   m4_append([list_of_plugins], [$1], [, ])
  86 ])
  87
  88 AC_DEFUN([PRINT_VAL], [ AC_MSG_RESULT(AC_HELP_STRING($1,$2)) ])
  89
  90 AC_DEFUN([DPDK_IS_PMD_ENABLED],
  91 [
  92   AC_MSG_CHECKING([for $1 in rte_config.h])
  93   AC_COMPILE_IFELSE(
  94     [AC_LANG_PROGRAM(
  95       [[#include <rte_config.h>]],
  96       [[return RTE_$1;]],
  97     )],
  98     [with_$2=yes]
  99     [AC_MSG_RESULT([yes])],
 100     [with_$2=no]
 101     [AC_MSG_RESULT([no])]
 102   )
 103   AM_CONDITIONAL(m4_toupper(WITH_$2), test "$with_$2" = "yes")
 104   m4_append_uniq([list_of_with], [$2], [, ])
 105 ])
 106
 107 # Check if compiler supports specific flag
 108 AC_DEFUN([CC_CHECK_FLAG],
 109 [
 110   AC_MSG_CHECKING([if $CC supports $1])
 111   AC_LANG_PUSH([C])
 112   ac_saved_cflags="$CFLAGS"
 113   CFLAGS="-Werror $1"
 114   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 115   [cc_flag_check=yes],
 116   [cc_flag_check=no]
 117 )
 118   AC_MSG_RESULT([$cc_flag_check])
 119   CFLAGS="$ac_saved_cflags"
 120   AC_LANG_POP([C])
 121 ])
 122
 123 ###############################################################################
 124 # configure arguments
 125 ###############################################################################
 126
 127 # --enable-X
 128 ENABLE_ARG(tests,       [Enable unit tests])
 129 ENABLE_ARG(dpdk_shared, [Enable unit tests])
 130 ENABLE_ARG(perftool,    [Enable perftool])
 131 ENABLE_ARG(g2,          [Enable g2])
 132
 133 # --disable-X
 134 DISABLE_ARG(vlib,       [Disable vlib and dependant libs and binaries])
 135 DISABLE_ARG(svm,        [Disable svm and dependant libs and binaries])
 136 DISABLE_ARG(papi,       [Disable Python API bindings])
 137 DISABLE_ARG(japi,       [Disable Java API bindings])
 138
 139 # --with-X
 140
 141 # --without-X
 142 WITHOUT_ARG(libssl,     [Disable libssl])
 143 WITHOUT_ARG(apicli,     [Disable binary api CLI])
 144 WITHOUT_ARG(mbedtls,    [Disable mbedtls])
 145 WITHOUT_ARG(libnuma,    [for non numa architectures])
 146
 147 AC_ARG_WITH(unix,
 148             AC_HELP_STRING([--with-unix],[Compile unix version of clib]),
 149             [],
 150             [case $host_os in
 151               darwin* | linux*) with_unix=yes;;
 152               *) with_unix=no;;
 153               esac])
 154
 155 AM_CONDITIONAL(WITH_UNIX, test "$with_unix" = "yes")
 156
 157 AC_ARG_WITH(pre-data,
 158             AC_HELP_STRING([--with-pre-data],[Set buffer rewrite space]),
 159             [case $with_pre_data in
 160                128) ;;
 161                256) ;;
 162                *) with_pre_data="pre-data-not-set" ;;
 163              esac], [with_pre_data=128])
 164
 165 ###############################################################################
 166 # Target CPU flags
 167 ###############################################################################
 168
 169 # Check if compiler supports march=core-avx2
 170 CC_CHECK_FLAG("-march=core-avx2")
 171 AS_IF([test "$cc_flag_check" = yes],
 172       [march_core_avx2=yes],
 173       [march_core_avx2=no])
 174 AM_CONDITIONAL([CC_SUPPORTS_AVX2], [test "$march_core_avx2" = "yes"])
 175
 176 # Check if compiler supports march=skylake-avx512
 177 CC_CHECK_FLAG("-march=skylake-avx512")
 178 AS_IF([test "$cc_flag_check" = yes],
 179   [march_skylake_avx512=yes],
 180   [march_skylake_avx512=no])
 181 AM_CONDITIONAL([CC_SUPPORTS_AVX512], [test "$march_skylake_avx512" = "yes"])
 182
 183 AS_CASE([$host_cpu],
 184         [x86_64], [CPU_FLAGS="-march=corei7 -mtune=corei7-avx"],
 185         [aarch64], [CPU_FLAGS="-march=armv8-a+crc"],
 186         [CPU_FLAGS=""],
 187 )
 188 AC_SUBST([CPU_FLAGS])
 189
 190 AC_SUBST([CPU_AVX2_FLAGS],"-march=core-avx2 -mtune=core-avx2")
 191 AC_SUBST([CPU_AVX512_FLAGS],"-march=skylake-avx512 -mtune=skylake-avx512")
 192
 193 AM_CONDITIONAL([CPU_X86_64], [test "$host_cpu" = "x86_64"])
 194 AM_CONDITIONAL([CPU_AARCH64], [test "$host_cpu" = "aarch64"])
 195
 196 ###############################################################################
 197 # misc compiler flags
 198 ###############################################################################
 199
 200 CC_CHECK_FLAG("-Wno-address-of-packed-member")
 201 AS_IF([test "$cc_flag_check" = yes],
 202         [CFLAGS="${CFLAGS} -Wno-address-of-packed-member"], [])
 203
 204 ###############################################################################
 205 # Substitutions and defines
 206 ###############################################################################
 207
 208 AC_SUBST(PRE_DATA_SIZE,         [$with_pre_data])
 209 AC_SUBST(APICLI,                [-DVPP_API_TEST_BUILTIN=${n_with_apicli}])
 210
 211 AC_DEFINE_UNQUOTED(DPDK_SHARED_LIB,     [${n_enable_dpdk_shared}])
 212 AC_DEFINE_UNQUOTED(WITH_LIBSSL,         [${n_with_libssl}])
 213 AC_DEFINE_UNQUOTED(WITH_MBEDTLS,        [${n_with_mbedtls}])
 214 AC_DEFINE_UNQUOTED(WITH_LIBNUMA,        [${n_with_libnuma}])
 215
 216
 217 # Silence following noise:
 218 # ar: `u' modifier ignored since `D' is the default (see `U')
 219 AR_FLAGS=cr
 220 AC_SUBST(AR_FLAGS)
 221
 222 ###############################################################################
 223 # Plugins
 224 ###############################################################################
 225
 226 # Please keep alphabetical order
 227 PLUGIN_ENABLED(abf)
 228 PLUGIN_ENABLED(acl)
 229 PLUGIN_ENABLED(avf)
 230 PLUGIN_ENABLED(cdp)
 231 PLUGIN_ENABLED(dpdk)
 232 PLUGIN_ENABLED(flowprobe)
 233 PLUGIN_ENABLED(gbp)
 234 PLUGIN_ENABLED(gtpu)
 235 PLUGIN_ENABLED(igmp)
 236 PLUGIN_ENABLED(ila)
 237 PLUGIN_ENABLED(ioam)
 238 PLUGIN_ENABLED(ixge)
 239 PLUGIN_ENABLED(l2e)
 240 PLUGIN_ENABLED(lacp)
 241 PLUGIN_ENABLED(lb)
 242 PLUGIN_ENABLED(marvell)
 243 PLUGIN_ENABLED(memif)
 244 PLUGIN_ENABLED(pppoe)
 245 PLUGIN_ENABLED(nat)
 246 PLUGIN_ENABLED(srv6ad)
 247 PLUGIN_ENABLED(srv6am)
 248 PLUGIN_ENABLED(srv6as)
 249 PLUGIN_ENABLED(stn)
 250 PLUGIN_ENABLED(tlsmbedtls)
 251 PLUGIN_ENABLED(tlsopenssl)
 252
 253 ###############################################################################
 254 # Dependency checks
 255 ###############################################################################
 256 AC_CHECK_FUNC([memfd_create], [AC_DEFINE([HAVE_MEMFD_CREATE], [1], [Define if memfd exists])])
 257
 258 AM_COND_IF([ENABLE_DPDK_SHARED],
 259 [
 260   AC_CHECK_HEADERS([rte_config.h],
 261     [],
 262     [AC_MSG_ERROR([DPDK header files not found])],)
 263   AC_CHECK_LIB( [dpdk], [rte_eal_init],
 264     [],
 265     [AC_MSG_ERROR([DPDK shared library not found])],)
 266 ])
 267
 268 with_aesni_mb_lib=no
 269 with_isa_l_crypto_lib=no
 270
 271 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_MB, dpdk_aesni_mb_pmd)
 272 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_GCM, dpdk_aesni_gcm_pmd)
 273
 274 AM_COND_IF([WITH_DPDK_AESNI_MB_PMD],
 275 [
 276   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 277                [with_aesni_mb_lib=yes],
 278                [AC_MSG_ERROR([IPSec_MB library not found])])
 279 ])
 280
 281 AM_COND_IF([WITH_DPDK_AESNI_GCM_PMD],
 282 [
 283   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 284     [with_aesni_mb_lib=yes],
 285     [AC_MSG_ERROR([IPSec_MB library not found])])
 286 ])
 287
 288 m4_append([list_of_with], [aesni_mb_lib], [, ])
 289 AM_CONDITIONAL(WITH_AESNI_MB_LIB, test "$with_aesni_mb_lib" = "yes")
 290
 291 m4_append([list_of_with], [isa_l_crypto_lib], [, ])
 292 AM_CONDITIONAL(WITH_ISA_L_CRYPTO_LIB, test "$with_isa_l_crypto_lib" = "yes")
 293
 294 AM_COND_IF([ENABLE_G2],
 295 [
 296   PKG_CHECK_MODULES(g2, gtk+-2.0)
 297 ])
 298
 299 AM_COND_IF([ENABLE_MARVELL_PLUGIN],
 300 [
 301   AC_CHECK_LIB( [musdk], [pp2_init],
 302     [],
 303     [
 304       AC_MSG_WARN([Marvell MUSDK library with PP2 support not found. Plugin disabled.])
 305       enable_marvell_plugin=no
 306       AM_CONDITIONAL(ENABLE_MARVELL_PLUGIN, false)
 307     ])
 308 ])
 309
 310 AM_COND_IF([WITH_MBEDTLS], [],
 311 [
 312   AC_MSG_WARN([mbedtls not enabled. Disabling tlsmbedtls plugin])
 313   enable_tlsmbedtls_plugin=no
 314   AM_CONDITIONAL(ENABLE_TLSMBEDTLS_PLUGIN, false)
 315 ])
 316
 317 AM_COND_IF([ENABLE_TLSMBEDTLS_PLUGIN],
 318 [
 319   AC_CHECK_HEADERS([mbedtls/ssl.h], [],
 320     [
 321       AC_MSG_WARN([mbedtls headers not found. TLS engine implementation disabled])
 322       enable_tlsmbedtls_plugin=no
 323       AM_CONDITIONAL(ENABLE_TLSMBEDTLS_PLUGIN, false)
 324     ], [])
 325 ])
 326
 327 AM_COND_IF([WITH_LIBSSL], [],
 328 [
 329   AC_MSG_WARN([openssl not enabled. Disabling tlsopenssl plugin])
 330   enable_tlsopenssl_plugin=no
 331   AM_CONDITIONAL(ENABLE_TLSOPENSSL_PLUGIN, false)
 332 ])
 333
 334 ###############################################################################
 335 # JAVA
 336 ###############################################################################
 337
 338 AM_COND_IF([ENABLE_JAPI],
 339 [
 340   AX_VPP_FIND_JDK8
 341   AC_SUBST(JAVA_HOME)
 342   AC_SUBST(JAVAC)
 343   AC_SUBST(JAVAH)
 344   AC_SUBST(JAR)
 345 ])
 346
 347 ###############################################################################
 348 # PYTHON
 349 ###############################################################################
 350
 351 AM_COND_IF([ENABLE_PAPI],
 352 [
 353   AM_PATH_PYTHON
 354 ])
 355
 356 ###############################################################################
 357 # Output
 358 ###############################################################################
 359
 360 AC_OUTPUT
 361
 362 AC_MSG_RESULT([==============================================================================])
 363 PRINT_VAL([version], $PACKAGE $VERSION)
 364 PRINT_VAL([prefix], ${prefix})
 365 PRINT_VAL([libdir], ${libdir})
 366 PRINT_VAL([includedir], ${includedir})
 367 PRINT_VAL([CFLAGS], ${CFLAGS})
 368 PRINT_VAL([CPPFLAGS], ${CPPFLAGS})
 369 PRINT_VAL([LDFLAGS], ${LDFLAGS})
 370 AM_COND_IF([ENABLE_JAPI],
 371 [
 372   PRINT_VAL([JAVA_VERSION], ${JAVA_VERSION})
 373   PRINT_VAL([JAVA_HOME], ${JAVA_HOME})
 374 ])
 375
 376 AC_MSG_RESULT([])
 377 AC_MSG_RESULT([with:])
 378 m4_foreach([x], m4_dquote(list_of_with), [
 379   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${with_], x, [}])))
 380 ])
 381
 382 AC_MSG_RESULT([])
 383 AC_MSG_RESULT([enabled:])
 384 m4_foreach([x], m4_dquote(list_of_enabled), [
 385   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [}])))
 386 ])
 387
 388 AC_MSG_RESULT([])
 389 AC_MSG_RESULT([plugins:])
 390 m4_foreach([x], m4_dquote(list_of_plugins), [
 391   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [_plugin}])))
 392 ])
 393 AC_MSG_RESULT([==============================================================================])
 394
 395