src/plugins/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 include_directories (
  15   ${CMAKE_CURRENT_SOURCE_DIR}
  16   ${CMAKE_CURRENT_BINARY_DIR}
  17 )
  18
  19 macro(add_vpp_plugin name)
  20   cmake_parse_arguments(PLUGIN
  21     ""
  22     "LINK_FLAGS"
  23     "SOURCES;API_FILES;MULTIARCH_SOURCES;LINK_LIBRARIES"
  24     ${ARGN}
  25   )
  26   set(plugin_name ${name}_plugin)
  27   set(api_headers)
  28   foreach(f ${PLUGIN_API_FILES})
  29      vpp_generate_api_header(${f} plugins)
  30      list(APPEND api_headers ${f}.h ${f}.json)
  31   endforeach()
  32   add_library(${plugin_name} SHARED ${PLUGIN_SOURCES} ${api_headers})
  33   add_dependencies(${plugin_name} vpp_version_h api_headers)
  34   set_target_properties(${plugin_name} PROPERTIES
  35     PREFIX ""
  36     LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_plugins)
  37   if(PLUGIN_MULTIARCH_SOURCES)
  38     vpp_library_set_multiarch_sources(${plugin_name} ${PLUGIN_MULTIARCH_SOURCES})
  39   endif()
  40   if(PLUGIN_LINK_LIBRARIES)
  41     target_link_libraries(${plugin_name} ${PLUGIN_LINK_LIBRARIES})
  42   endif()
  43   if(PLUGIN_LINK_FLAGS)
  44     set_target_properties(${plugin_name} PROPERTIES LINK_FLAGS "${PLUGIN_LINK_FLAGS}")
  45   endif()
  46   install(TARGETS ${plugin_name} DESTINATION lib/vpp_plugins COMPONENT plugins)
  47 endmacro()
  48
  49 macro(add_vpp_api_test_plugin plugin_name)
  50   set(api_headers)
  51   foreach(f ${ARGN})
  52      if(${f} MATCHES ".*\.api$")
  53        vpp_generate_api_header(${f} plugins)
  54        list(APPEND api_headers ${f}.h)
  55      endif()
  56   endforeach()
  57   add_library(${plugin_name} SHARED ${ARGN} ${api_headers})
  58   add_dependencies(${plugin_name} api_headers)
  59   set_target_properties(${plugin_name} PROPERTIES PREFIX "")
  60   set_target_properties(${plugin_name} PROPERTIES
  61     PREFIX ""
  62     LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}//vpp_api_test_plugins)
  63   install(TARGETS ${plugin_name} DESTINATION lib/vpp_api_test_plugins COMPONENT
  64           plugins)
  65 endmacro()
  66
  67 ##############################################################################
  68 # find and add all plugin subdirs
  69 ############################################################################
  70 FILE(GLOB files RELATIVE
  71   ${CMAKE_CURRENT_SOURCE_DIR}
  72   ${CMAKE_CURRENT_SOURCE_DIR}/*/CMakeLists.txt
  73 )
  74 foreach (f ${files})
  75   get_filename_component(dir ${f} DIRECTORY)
  76   add_subdirectory(${dir})
  77 endforeach()