src/plugins/crypto_native/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 if(CMAKE_SYSTEM_PROCESSOR MATCHES "amd64.*|x86_64.*|AMD64.*")
  15   list(APPEND VARIANTS "sse42\;-march=silvermont")
  16   list(APPEND VARIANTS "avx2\;-march=core-avx2")
  17   if(compiler_flag_march_skylake_avx512)
  18     list(APPEND VARIANTS "avx512\;-march=skylake-avx512")
  19   endif()
  20   if(compiler_flag_march_icelake_client)
  21     list(APPEND VARIANTS "vaesni\;-march=icelake-client")
  22   endif()
  23   set (COMPILE_FILES aes_cbc.c aes_gcm.c)
  24   set (COMPILE_OPTS -Wall -fno-common -maes)
  25 endif()
  26
  27 if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(aarch64.*|AARCH64.*)")
  28   list(APPEND VARIANTS "armv8\;-march=armv8.1-a+crc+crypto")
  29   set (COMPILE_FILES aes_cbc.c)
  30   set (COMPILE_OPTS -Wall -fno-common)
  31 endif()
  32
  33 if (NOT VARIANTS)
  34   return()
  35 endif()
  36
  37 add_vpp_plugin(crypto_native SOURCES main.c)
  38
  39 foreach(VARIANT ${VARIANTS})
  40   list(GET VARIANT 0 v)
  41   list(GET VARIANT 1 f)
  42   set(l crypto_native_${v})
  43   add_library(${l} OBJECT ${COMPILE_FILES})
  44   set_target_properties(${l} PROPERTIES POSITION_INDEPENDENT_CODE ON)
  45   target_compile_options(${l} PUBLIC ${f} ${COMPILE_OPTS})
  46   target_sources(crypto_native_plugin PRIVATE $<TARGET_OBJECTS:${l}>)
  47 endforeach()