src/plugins/dpdk/CMakeLists.txt

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 ##############################################################################
  15 # Find lib and include files
  16 ##############################################################################
  17 find_path(DPDK_INCLUDE_DIR PATH_SUFFIXES dpdk NAMES rte_config.h HINTS
  18           ${DPDK_INCLUDE_DIR_HINT})
  19 find_library(DPDK_LIB NAMES libdpdk.a HINTS ${DPDK_LIB_DIR_HINT})
  20
  21 ##############################################################################
  22 # Find DPDK Version
  23 ##############################################################################
  24 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.c
  25 "
  26 #include <stdio.h>
  27 #include <rte_version.h>
  28 int main()
  29 {
  30   printf(\"VERSION=%s\\n\", strchr(rte_version(), ' ') + 1);
  31   printf(\"RTE_PKTMBUF_HEADROOM=%u\\n\", RTE_PKTMBUF_HEADROOM);
  32 #ifdef RTE_LIBRTE_PMD_AESNI_MB
  33   printf(\"RTE_LIBRTE_PMD_AESNI_MB=%u\\n\", RTE_LIBRTE_PMD_AESNI_MB);
  34 #endif
  35 #ifdef RTE_LIBRTE_PMD_AESNI_GCM
  36   printf(\"RTE_LIBRTE_PMD_AESNI_GCM=%u\\n\", RTE_LIBRTE_PMD_AESNI_GCM);
  37 #endif
  38   return 0;
  39 }
  40 ")
  41
  42 try_compile(DPDK_VARS_COMPILED
  43   ${CMAKE_CURRENT_BINARY_DIR}
  44   ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.c
  45   CMAKE_FLAGS
  46   -DINCLUDE_DIRECTORIES=${DPDK_INCLUDE_DIR}
  47   COPY_FILE ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.bin
  48 )
  49
  50 if(DPDK_VARS_COMPILED)
  51   execute_process(
  52     WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
  53     COMMAND ./dpdk_vars.bin
  54     OUTPUT_VARIABLE DPDK_VARS
  55     OUTPUT_STRIP_TRAILING_WHITESPACE
  56   )
  57   string(REPLACE "\n" ";" DPDK_VARS ${DPDK_VARS})
  58   foreach(v ${DPDK_VARS})
  59     string(REPLACE "=" ";" v ${v})
  60     list(GET v 0 name)
  61     list(GET v 1 value)
  62     set(DPDK_${name} ${value})
  63   endforeach()
  64 endif()
  65
  66 file(REMOVE
  67   ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.c
  68   ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.bin
  69 )
  70
  71 if(NOT ${DPDK_RTE_PKTMBUF_HEADROOM} EQUAL ${PRE_DATA_SIZE})
  72   message(
  73     FATAL_ERROR
  74     "DPDK RTE_PKTMBUF_HEADROOM (${DPDK_RTE_PKTMBUF_HEADROOM}) "
  75      "must be equal to PRE_DATA_SIZE (${PRE_DATA_SIZE})"
  76   )
  77 endif()
  78
  79 ##############################################################################
  80 # DPDK plugin
  81 ##############################################################################
  82 if(DPDK_INCLUDE_DIR AND DPDK_LIB)
  83   include_directories (${DPDK_INCLUDE_DIR})
  84
  85   message(STATUS "Found DPDK ${DPDK_VERSION} in ${DPDK_INCLUDE_DIR}")
  86   get_filename_component(DPDK_LIB_DIR ${DPDK_LIB} DIRECTORY)
  87   set(DPDK_LINK_FLAGS "-L${DPDK_LIB_DIR} -Wl,--whole-archive,${DPDK_LIB},--no-whole-archive")
  88   if(DPDK_RTE_LIBRTE_PMD_AESNI_MB OR DPDK_RTE_LIBRTE_PMD_AESNI_GCM)
  89     set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,--exclude-libs,libIPSec_MB.a,-l:libIPSec_MB.a")
  90     message(STATUS "DPDK depends on IPSec MB library")
  91   endif()
  92   set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,-lnuma")
  93   add_vpp_plugin(dpdk
  94     SOURCES
  95     buffer.c
  96     main.c
  97     thread.c
  98     api/dpdk_api.c
  99     api/dpdk_test.c
 100     device/cli.c
 101     device/common.c
 102     device/device.c
 103     device/flow.c
 104     device/format.c
 105     device/init.c
 106     device/node.c
 107     hqos/hqos.c
 108     ipsec/cli.c
 109     ipsec/crypto_node.c
 110     ipsec/esp_decrypt.c
 111     ipsec/esp_encrypt.c
 112     ipsec/ipsec.c
 113
 114     MULTIARCH_SOURCES
 115     buffer.c
 116     device/device.c
 117     device/node.c
 118
 119     API_FILES
 120     api/dpdk.api
 121
 122     API_TEST_SOURCES
 123     api/dpdk_test.c
 124
 125     LINK_FLAGS
 126     ${DPDK_LINK_FLAGS}
 127   )
 128 else()
 129   message(WARNING "DPDK not found - dpdk disabled")
 130 endif()
 131