src/plugins/dpdk/CMakeLists.txt

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 ##############################################################################
  15 # Find lib and include files
  16 ##############################################################################
  17 find_path(DPDK_INCLUDE_DIR PATH_SUFFIXES dpdk NAMES rte_config.h)
  18 find_library(DPDK_LIB NAMES libdpdk.a)
  19
  20 ##############################################################################
  21 # Find DPDK Version
  22 ##############################################################################
  23 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.c
  24 "
  25 #include <stdio.h>
  26 #include <rte_version.h>
  27 int main()
  28 {
  29   printf(\"VERSION=%s\\n\", strchr(rte_version(), ' ') + 1);
  30   printf(\"RTE_PKTMBUF_HEADROOM=%u\\n\", RTE_PKTMBUF_HEADROOM);
  31 #ifdef RTE_LIBRTE_PMD_AESNI_MB
  32   printf(\"RTE_LIBRTE_PMD_AESNI_MB=%u\\n\", RTE_LIBRTE_PMD_AESNI_MB);
  33 #endif
  34 #ifdef RTE_LIBRTE_PMD_AESNI_GCM
  35   printf(\"RTE_LIBRTE_PMD_AESNI_GCM=%u\\n\", RTE_LIBRTE_PMD_AESNI_GCM);
  36 #endif
  37 #ifdef RTE_LIBRTE_MLX4_PMD
  38   printf(\"RTE_LIBRTE_MLX4_PMD=%u\\n\", RTE_LIBRTE_MLX4_PMD);
  39 #endif
  40 #ifdef RTE_LIBRTE_MLX5_PMD
  41   printf(\"RTE_LIBRTE_MLX5_PMD=%u\\n\", RTE_LIBRTE_MLX5_PMD);
  42 #ifdef RTE_LIBRTE_MLX5_DLOPEN_DEPS
  43   printf(\"RTE_LIBRTE_MLX5_DLOPEN_DEPS=%u\\n\", RTE_LIBRTE_MLX5_DLOPEN_DEPS);
  44 #endif
  45 #endif
  46   return 0;
  47 }
  48 ")
  49
  50 try_compile(DPDK_VARS_COMPILED
  51   ${CMAKE_CURRENT_BINARY_DIR}
  52   ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.c
  53   CMAKE_FLAGS
  54   -DINCLUDE_DIRECTORIES=${DPDK_INCLUDE_DIR}
  55   COPY_FILE ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.bin
  56 )
  57
  58 if(DPDK_VARS_COMPILED)
  59   execute_process(
  60     WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
  61     COMMAND ./dpdk_vars.bin
  62     OUTPUT_VARIABLE DPDK_VARS
  63     OUTPUT_STRIP_TRAILING_WHITESPACE
  64   )
  65   string(REPLACE "\n" ";" DPDK_VARS ${DPDK_VARS})
  66   foreach(v ${DPDK_VARS})
  67     string(REPLACE "=" ";" v ${v})
  68     list(GET v 0 name)
  69     list(GET v 1 value)
  70     set(DPDK_${name} ${value})
  71   endforeach()
  72 endif()
  73
  74 file(REMOVE
  75   ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.c
  76   ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.bin
  77 )
  78
  79 if(NOT ${DPDK_RTE_PKTMBUF_HEADROOM} EQUAL ${PRE_DATA_SIZE})
  80   message(
  81     FATAL_ERROR
  82     "DPDK RTE_PKTMBUF_HEADROOM (${DPDK_RTE_PKTMBUF_HEADROOM}) "
  83      "must be equal to PRE_DATA_SIZE (${PRE_DATA_SIZE})"
  84   )
  85 endif()
  86
  87 ##############################################################################
  88 # DPDK plugin
  89 ##############################################################################
  90 if(DPDK_INCLUDE_DIR AND DPDK_LIB)
  91   include_directories (${DPDK_INCLUDE_DIR})
  92
  93   message(STATUS "Found DPDK ${DPDK_VERSION} in ${DPDK_INCLUDE_DIR}")
  94   get_filename_component(DPDK_LIB_DIR ${DPDK_LIB} DIRECTORY)
  95   set(DPDK_LINK_FLAGS "-L${DPDK_LIB_DIR} -Wl,--whole-archive,${DPDK_LIB},--no-whole-archive")
  96   if(DPDK_RTE_LIBRTE_PMD_AESNI_MB OR DPDK_RTE_LIBRTE_PMD_AESNI_GCM)
  97     set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,--exclude-libs,libIPSec_MB.a,-l:libIPSec_MB.a")
  98     message(STATUS "DPDK depends on IPSec MB library")
  99   endif()
 100   if(DPDK_RTE_LIBRTE_MLX4_PMD OR DPDK_RTE_LIBRTE_MLX5_PMD)
 101     if (DPDK_RTE_LIBRTE_MLX5_DLOPEN_DEPS)
 102       set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,-lmnl")
 103       message(STATUS "DPDK depends on libmnl (Mellanox PMD requirement)")
 104     else()
 105       set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,-lmnl,-libverbs,-lmlx5")
 106       message(STATUS "DPDK depends on libmnl, libibverbs, libmlx5 (Mellanox PMD requirement)")
 107     endif()
 108   endif()
 109   set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,-lnuma")
 110   add_vpp_plugin(dpdk
 111     SOURCES
 112     buffer.c
 113     main.c
 114     thread.c
 115     api/dpdk_api.c
 116     api/dpdk_test.c
 117     device/cli.c
 118     device/common.c
 119     device/device.c
 120     device/flow.c
 121     device/format.c
 122     device/init.c
 123     device/node.c
 124     hqos/hqos.c
 125     ipsec/cli.c
 126     ipsec/crypto_node.c
 127     ipsec/esp_decrypt.c
 128     ipsec/esp_encrypt.c
 129     ipsec/ipsec.c
 130
 131     MULTIARCH_SOURCES
 132     buffer.c
 133     device/device.c
 134     device/node.c
 135
 136     API_FILES
 137     api/dpdk.api
 138
 139     API_TEST_SOURCES
 140     api/dpdk_test.c
 141
 142     INSTALL_HEADERS
 143     device/dpdk.h
 144     api/dpdk_all_api_h.h
 145     ipsec/ipsec.h
 146
 147     LINK_FLAGS
 148     ${DPDK_LINK_FLAGS}
 149
 150     COMPONENT
 151     vpp-plugin-dpdk
 152   )
 153 else()
 154   message(WARNING "DPDK not found - dpdk disabled")
 155 endif()
 156