src/plugins/dpdk/CMakeLists.txt

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 ##############################################################################
  15 # Find lib and include files
  16 ##############################################################################
  17 find_path(DPDK_INCLUDE_DIR PATH_SUFFIXES dpdk NAMES rte_config.h)
  18 find_library(DPDK_LIB NAMES libdpdk.a)
  19
  20 if (NOT DPDK_INCLUDE_DIR)
  21   message(WARNING "-- DPDK not found - dpdk_plugin disabled")
  22   return()
  23 endif()
  24
  25 ##############################################################################
  26 # Find DPDK Version
  27 ##############################################################################
  28 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.c
  29 "
  30 #include <stdio.h>
  31 #include <rte_version.h>
  32 int main()
  33 {
  34   printf(\"VERSION=%s\\n\", strchr(rte_version(), ' ') + 1);
  35   printf(\"RTE_PKTMBUF_HEADROOM=%u\\n\", RTE_PKTMBUF_HEADROOM);
  36 #ifdef RTE_LIBRTE_PMD_AESNI_MB
  37   printf(\"RTE_LIBRTE_PMD_AESNI_MB=%u\\n\", RTE_LIBRTE_PMD_AESNI_MB);
  38 #endif
  39 #ifdef RTE_LIBRTE_PMD_AESNI_GCM
  40   printf(\"RTE_LIBRTE_PMD_AESNI_GCM=%u\\n\", RTE_LIBRTE_PMD_AESNI_GCM);
  41 #endif
  42 #ifdef RTE_LIBRTE_MLX4_PMD
  43   printf(\"RTE_LIBRTE_MLX4_PMD=%u\\n\", RTE_LIBRTE_MLX4_PMD);
  44 #endif
  45 #ifdef RTE_LIBRTE_MLX5_PMD
  46   printf(\"RTE_LIBRTE_MLX5_PMD=%u\\n\", RTE_LIBRTE_MLX5_PMD);
  47 #ifdef RTE_LIBRTE_MLX5_DLOPEN_DEPS
  48   printf(\"RTE_LIBRTE_MLX5_DLOPEN_DEPS=%u\\n\", RTE_LIBRTE_MLX5_DLOPEN_DEPS);
  49 #endif
  50 #endif
  51   return 0;
  52 }
  53 ")
  54
  55 try_compile(DPDK_VARS_COMPILED
  56   ${CMAKE_CURRENT_BINARY_DIR}
  57   ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.c
  58   CMAKE_FLAGS
  59   -DINCLUDE_DIRECTORIES=${DPDK_INCLUDE_DIR}
  60   COPY_FILE ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.bin
  61 )
  62
  63 if(DPDK_VARS_COMPILED)
  64   execute_process(
  65     WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
  66     COMMAND ./dpdk_vars.bin
  67     OUTPUT_VARIABLE DPDK_VARS
  68     OUTPUT_STRIP_TRAILING_WHITESPACE
  69   )
  70   string(REPLACE "\n" ";" DPDK_VARS ${DPDK_VARS})
  71   foreach(v ${DPDK_VARS})
  72     string(REPLACE "=" ";" v ${v})
  73     list(GET v 0 name)
  74     list(GET v 1 value)
  75     set(DPDK_${name} ${value})
  76   endforeach()
  77 endif()
  78
  79 file(REMOVE
  80   ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.c
  81   ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.bin
  82 )
  83
  84 if(NOT ${DPDK_RTE_PKTMBUF_HEADROOM} EQUAL ${PRE_DATA_SIZE})
  85   message(
  86     FATAL_ERROR
  87     "DPDK RTE_PKTMBUF_HEADROOM (${DPDK_RTE_PKTMBUF_HEADROOM}) "
  88      "must be equal to PRE_DATA_SIZE (${PRE_DATA_SIZE})"
  89   )
  90 endif()
  91
  92 ##############################################################################
  93 # DPDK plugin
  94 ##############################################################################
  95 if(DPDK_INCLUDE_DIR AND DPDK_LIB)
  96   include_directories (${DPDK_INCLUDE_DIR})
  97
  98   message(STATUS "Found DPDK ${DPDK_VERSION} in ${DPDK_INCLUDE_DIR}")
  99   get_filename_component(DPDK_LIB_DIR ${DPDK_LIB} DIRECTORY)
 100   set(DPDK_LINK_FLAGS "-L${DPDK_LIB_DIR} -Wl,--whole-archive,${DPDK_LIB},--no-whole-archive")
 101   if(DPDK_RTE_LIBRTE_PMD_AESNI_MB OR DPDK_RTE_LIBRTE_PMD_AESNI_GCM)
 102     set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,--exclude-libs,libIPSec_MB.a,-l:libIPSec_MB.a")
 103     message(STATUS "DPDK depends on IPSec MB library")
 104   endif()
 105   if(DPDK_RTE_LIBRTE_MLX4_PMD OR DPDK_RTE_LIBRTE_MLX5_PMD)
 106     if (DPDK_RTE_LIBRTE_MLX5_DLOPEN_DEPS)
 107       set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,-lmnl")
 108       message(STATUS "DPDK depends on libmnl (Mellanox PMD requirement)")
 109     else()
 110       set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,-lmnl,-libverbs,-lmlx5")
 111       message(STATUS "DPDK depends on libmnl, libibverbs, libmlx5 (Mellanox PMD requirement)")
 112     endif()
 113   endif()
 114   set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,-lnuma")
 115   add_vpp_plugin(dpdk
 116     SOURCES
 117     buffer.c
 118     main.c
 119     thread.c
 120     api/dpdk_api.c
 121     api/dpdk_test.c
 122     device/cli.c
 123     device/common.c
 124     device/device.c
 125     device/flow.c
 126     device/format.c
 127     device/init.c
 128     device/node.c
 129     hqos/hqos.c
 130     ipsec/cli.c
 131     ipsec/crypto_node.c
 132     ipsec/esp_decrypt.c
 133     ipsec/esp_encrypt.c
 134     ipsec/ipsec.c
 135
 136     MULTIARCH_SOURCES
 137     buffer.c
 138     device/device.c
 139     device/node.c
 140
 141     API_FILES
 142     api/dpdk.api
 143
 144     API_TEST_SOURCES
 145     api/dpdk_test.c
 146
 147     INSTALL_HEADERS
 148     device/dpdk.h
 149     api/dpdk_all_api_h.h
 150     ipsec/ipsec.h
 151
 152     LINK_FLAGS
 153     ${DPDK_LINK_FLAGS}
 154
 155     COMPONENT
 156     vpp-plugin-dpdk
 157   )
 158 else()
 159   message(WARNING "DPDK not found - dpdk disabled")
 160 endif()
 161