src/vat2/CMakeLists.txt

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 ##############################################################################
  15 # vat2
  16 ##############################################################################
  17 add_vpp_executable(vat2 ENABLE_EXPORTS
  18   SOURCES
  19   main.c
  20   plugin.c
  21   jsonconvert.c
  22
  23   DEPENDS api_headers
  24
  25   LINK_LIBRARIES
  26   vlibmemoryclient
  27   svm
  28   vppinfra
  29   vppapiclient
  30   Threads::Threads
  31   rt m dl crypto
  32 )
  33
  34 #
  35 # Unit test code. Call generator directly to avoid it being installed
  36 #set_source_files_properties(vat2_test.c PROPERTIES
  37 #  COMPILE_FLAGS " -fsanitize=address"
  38 #)
  39
  40 vpp_generate_api_c_header (test/vat2_test.api)
  41 add_vpp_executable(test_vat2 ENABLE_EXPORTS NO_INSTALL
  42   SOURCES
  43   test/vat2_test.c
  44   jsonconvert.c
  45
  46   DEPENDS api_headers
  47
  48   LINK_LIBRARIES
  49   vlibmemoryclient
  50   svm
  51   vppinfra
  52   vppapiclient
  53   Threads::Threads
  54   rt m dl crypto
  55 )
  56 #target_link_options(test_vat2 PUBLIC "LINKER:-fsanitize=address")
  57
  58 if("${CMAKE_VERSION}" VERSION_GREATER_EQUAL "3.13" AND "${CMAKE_C_COMPILER_ID}" MATCHES "(Apple)?[Cc]lang")
  59   set(TARGET_NAME test_vat2)
  60   set(COV_SOURCES ${CMAKE_SOURCE_DIR}/vat2/jsonconvert.c)
  61
  62   message("Building with llvm Code Coverage Tools ${TARGET_NAME}")
  63   target_compile_options(${TARGET_NAME} PRIVATE -fprofile-instr-generate -fcoverage-mapping)
  64   target_link_options(${TARGET_NAME} PRIVATE -fprofile-instr-generate -fcoverage-mapping)
  65   target_compile_options(${TARGET_NAME} PRIVATE -fsanitize=address)
  66   target_link_options(${TARGET_NAME} PRIVATE -fsanitize=address)
  67
  68   # llvm-cov
  69   add_custom_target(${TARGET_NAME}-ccov-preprocessing
  70     COMMAND LLVM_PROFILE_FILE=${TARGET_NAME}.profraw $<TARGET_FILE:${TARGET_NAME}>
  71     COMMAND llvm-profdata merge -sparse ${TARGET_NAME}.profraw -o ${TARGET_NAME}.profdata
  72     DEPENDS ${TARGET_NAME})
  73
  74   add_custom_target(${TARGET_NAME}-ccov-show
  75     COMMAND llvm-cov show $<TARGET_FILE:${TARGET_NAME}> -instr-profile=${TARGET_NAME}.profdata -show-line-counts-or-regions ${COV_SOURCES}
  76     DEPENDS ${TARGET_NAME}-ccov-preprocessing)
  77
  78   add_custom_target(${TARGET_NAME}-ccov-report
  79     COMMAND llvm-cov report -show-functions $<TARGET_FILE:${TARGET_NAME}> -instr-profile=${TARGET_NAME}.profdata ${COV_SOURCES}
  80     DEPENDS ${TARGET_NAME}-ccov-preprocessing)
  81
  82   add_custom_target(${TARGET_NAME}-ccov
  83     COMMAND llvm-cov show $<TARGET_FILE:${TARGET_NAME}> -instr-profile=${TARGET_NAME}.profdata -show-line-counts-or-regions -output-dir=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/${TARGET_NAME}-llvm-cov -format="html" ${COV_SOURCES}
  84     DEPENDS ${TARGET_NAME}-ccov-preprocessing)
  85
  86   add_custom_command(TARGET ${TARGET_NAME}-ccov POST_BUILD
  87     COMMAND ;
  88     COMMENT "Open ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/${TARGET_NAME}-llvm-cov/index.html in your browser to view the coverage report."
  89 )
  90 endif()
  91
  92
  93
  94 ##############################################################################
  95 # vat2 headers
  96 ##############################################################################
  97 install(
  98   FILES
  99   jsonconvert.h
 100   vat2_helpers.h
 101   DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/vat2
 102   COMPONENT vpp-dev
 103 )