src/vlib/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 option(VPP_BUFFER_FAULT_INJECTOR "Include the buffer fault injector" OFF)
  15
  16 ##############################################################################
  17 # Generate vlib/config.h
  18 ##############################################################################
  19 if(VPP_BUFFER_FAULT_INJECTOR)
  20   set(BUFFER_ALLOC_FAULT_INJECTOR 1 CACHE STRING "fault injector on")
  21 else()
  22   set(BUFFER_ALLOC_FAULT_INJECTOR 0 CACHE STRING "fault injector off")
  23 endif()
  24
  25 set(PRE_DATA_SIZE 128 CACHE STRING "Buffer headroom size.")
  26
  27 if (CMAKE_BUILD_TYPE_UC STREQUAL "DEBUG")
  28   set(_ss 16)
  29 else()
  30   set(_ss 15)
  31 endif()
  32 set(VLIB_PROCESS_LOG2_STACK_SIZE
  33  ${_ss}
  34  CACHE
  35  STRING "Process node default stack size (log2)"
  36 )
  37
  38 configure_file(
  39   ${CMAKE_SOURCE_DIR}/vlib/config.h.in
  40   ${CMAKE_CURRENT_BINARY_DIR}/config.h
  41 )
  42 install(
  43   FILES ${CMAKE_CURRENT_BINARY_DIR}/config.h
  44   DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/vlib
  45   COMPONENT vpp-dev
  46 )
  47
  48 ##############################################################################
  49 # Find lib and include files
  50 ##############################################################################
  51 message(STATUS "Looking for libuuid")
  52 vpp_find_path(UUID_INCLUDE_DIR NAMES uuid/uuid.h)
  53 vpp_find_library(UUID_LIB NAMES uuid)
  54
  55 if(UUID_INCLUDE_DIR AND UUID_LIB)
  56   include_directories(${UUID_INCLUDE_DIR})
  57   set(VMBUS_SOURCE linux/vmbus.c)
  58   set(VMBUS_LIBS uuid)
  59   message(STATUS "Found uuid in ${UUID_INCLUDE_DIR}")
  60 else()
  61   message(WARNING "-- libuuid not found - vmbus support disabled")
  62 endif()
  63
  64 ##############################################################################
  65 # vlib shared library
  66 ##############################################################################
  67 add_vpp_library(vlib
  68   SOURCES
  69   buffer.c
  70   buffer_funcs.c
  71   cli.c
  72   counter.c
  73   drop.c
  74   error.c
  75   format.c
  76   handoff_trace.c
  77   init.c
  78   linux/pci.c
  79   linux/vfio.c
  80   log.c
  81   main.c
  82   node.c
  83   node_cli.c
  84   node_format.c
  85   node_init.c
  86   pci/pci.c
  87   pci/pci_types_api.c
  88   physmem.c
  89   punt.c
  90   punt_node.c
  91   threads.c
  92   threads_cli.c
  93   time.c
  94   trace.c
  95   unix/cli.c
  96   unix/input.c
  97   unix/main.c
  98   unix/plugin.c
  99   unix/util.c
 100   vmbus/vmbus.c
 101   ${VMBUS_SOURCE}
 102
 103   MULTIARCH_SOURCES
 104   buffer_funcs.c
 105   drop.c
 106   punt_node.c
 107   node_init.c
 108
 109   INSTALL_HEADERS
 110   buffer_funcs.h
 111   buffer.h
 112   buffer_node.h
 113   cli.h
 114   counter.h
 115   counter_types.h
 116   defs.h
 117   error_funcs.h
 118   error.h
 119   format_funcs.h
 120   global_funcs.h
 121   init.h
 122   linux/vfio.h
 123   log.h
 124   main.h
 125   node_funcs.h
 126   node.h
 127   pci/pci_config.h
 128   pci/pci.h
 129   pci/pci_types_api.h
 130   physmem_funcs.h
 131   physmem.h
 132   punt.h
 133   threads.h
 134   time.h
 135   trace_funcs.h
 136   trace.h
 137   unix/mc_socket.h
 138   unix/plugin.h
 139   unix/unix.h
 140   vlib.h
 141   vmbus/vmbus.h
 142
 143   API_FILES
 144   pci/pci_types.api
 145
 146   LINK_LIBRARIES vppinfra svm ${VMBUS_LIBS} ${CMAKE_DL_LIBS}
 147
 148   DEPENDS api_headers
 149 )