src/vpp/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 ##############################################################################
  15 # Generate vpp/app/version.h
  16 ##############################################################################
  17 add_custom_command(
  18   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/app/version.h
  19   WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
  20   COMMAND mkdir
  21   ARGS -p ${CMAKE_CURRENT_BINARY_DIR}/app
  22   COMMAND scripts/generate_version_h
  23   ARGS ${CMAKE_CURRENT_BINARY_DIR}/app/version.h
  24   COMMENT "Generating VPP version.h"
  25 )
  26
  27 add_custom_target(vpp_version_h
  28   DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/app/version.h
  29 )
  30
  31 ##############################################################################
  32 # vpp binary
  33 ##############################################################################
  34 option(VPP_API_TEST_BUILTIN "Use builtin VPP API test." ON)
  35
  36 configure_file(
  37   ${CMAKE_SOURCE_DIR}/vpp/vnet/config.h.in
  38   ${CMAKE_CURRENT_BINARY_DIR}/vnet/config.h
  39 )
  40
  41 set(VPP_API_FILES
  42   api/vpe_types.api
  43   api/vpe.api
  44 )
  45
  46 vpp_add_api_files(vpp core vpp ${VPP_API_FILES})
  47
  48 foreach(file ${VPP_API_FILES})
  49   get_filename_component(dir ${file} DIRECTORY)
  50   install(
  51     FILES ${CMAKE_CURRENT_BINARY_DIR}/${file}.h
  52     ${CMAKE_CURRENT_BINARY_DIR}/${file}_enum.h
  53     ${CMAKE_CURRENT_BINARY_DIR}/${file}_types.h
  54     DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/vpp/${dir}
  55     COMPONENT vpp-dev
  56   )
  57 endforeach()
  58
  59 set(VPP_SOURCES
  60   vnet/main.c
  61   app/vpe_cli.c
  62   app/version.c
  63   stats/stat_segment.c
  64   stats/stat_segment_provider.c
  65   api/api.c
  66   api/json_format.c
  67   api/types.c
  68 )
  69
  70 if(VPP_API_TEST_BUILTIN)
  71   list(APPEND VPP_SOURCES
  72     api/api_format.c
  73     api/api_main.c
  74     api/plugin.c
  75     api/types.c
  76   )
  77   add_definitions(-DVPP_API_TEST_BUILTIN=1)
  78 endif()
  79
  80 add_vpp_executable(vpp
  81   ENABLE_EXPORTS
  82   SOURCES ${VPP_SOURCES}
  83   LINK_LIBRARIES svm vlib vppinfra vlibmemory vnet Threads::Threads ${CMAKE_DL_LIBS}
  84   DEPENDS vpp_version_h api_headers
  85 )
  86
  87 add_vpp_headers(vpp
  88   stats/stat_segment.h
  89   stats/stat_segment_shared.h
  90 )
  91
  92 ##############################################################################
  93 # vppctl binary
  94 ##############################################################################
  95 add_vpp_executable(vppctl
  96   SOURCES app/vppctl.c
  97   LINK_LIBRARIES vppinfra
  98 )
  99
 100 ##############################################################################
 101 # vpp_get_metrics binary
 102 ##############################################################################
 103 add_vpp_executable(vpp_get_metrics
 104   SOURCES api/vpp_get_metrics.c
 105   LINK_LIBRARIES vppinfra svm svmdb
 106   DEPENDS api_headers
 107 )
 108
 109 ##############################################################################
 110 # stats binaries
 111 ##############################################################################
 112 add_vpp_executable(vpp_get_stats
 113   SOURCES app/vpp_get_stats.c
 114   LINK_LIBRARIES vppapiclient vppinfra
 115   DEPENDS api_headers
 116 )
 117
 118 add_vpp_executable(vpp_prometheus_export
 119   SOURCES app/vpp_prometheus_export.c
 120   LINK_LIBRARIES vppapiclient vppinfra svm vlibmemoryclient
 121   DEPENDS api_headers
 122 )
 123
 124 ##############################################################################
 125 # vppmem_preload library
 126 ##############################################################################
 127 add_vpp_library(vppmem_preload
 128   SOURCES mem/mem.c
 129   LINK_LIBRARIES vppinfra
 130 )
 131
 132 install(FILES conf/startup.conf DESTINATION ${CMAKE_INSTALL_SYSCONFDIR}/vpp COMPONENT vpp)
 133 install(FILES conf/80-vpp.conf DESTINATION ${CMAKE_INSTALL_SYSCONFDIR}/sysctl.d COMPONENT vpp)
 134
 135 ##############################################################################
 136 # VAT2 plugins
 137 ##############################################################################
 138 add_vpp_test_library(vpp
 139   ${VPP_API_FILES}
 140 )
 141
 142 add_vat_test_library(vpp
 143   api/api_test.c
 144 )
 145
 146 ##############################################################################
 147 # minimal interactive startup.conf  - only if not present
 148 ##############################################################################
 149 if(NOT EXISTS ${CMAKE_BINARY_DIR}/startup.conf)
 150   configure_file(
 151     ${CMAKE_CURRENT_SOURCE_DIR}/conf/startup.conf.in
 152     ${CMAKE_BINARY_DIR}/startup.conf
 153   )
 154 endif()