src/vpp/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 ##############################################################################
  15 # Generate vpp/app/version.h
  16 ##############################################################################
  17 add_custom_command(
  18   OUTPUT ${CMAKE_BINARY_DIR}/include/vpp/app/version.h
  19   WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
  20   COMMAND mkdir
  21   ARGS -p ${CMAKE_BINARY_DIR}/include/vpp/app
  22   COMMAND scripts/generate_version_h
  23   ARGS ${CMAKE_BINARY_DIR}/include/vpp/app/version.h
  24   COMMENT "Generating VPP version.h"
  25 )
  26
  27 add_custom_target(vpp_version_h
  28   DEPENDS ${CMAKE_BINARY_DIR}/include/vpp/app/version.h
  29 )
  30
  31 ##############################################################################
  32 # vpp binary
  33 ##############################################################################
  34 option(VPP_API_TEST_BUILTIN "Use builtin VPP API test." ON)
  35
  36 set(VPP_API_FILES
  37   api/vpe.api
  38   stats/stats.api
  39   oam/oam.api
  40 )
  41
  42 vpp_add_api_files(vpp ${VPP_API_FILES})
  43
  44 foreach(file ${VPP_API_FILES})
  45   get_filename_component(dir ${file} DIRECTORY)
  46   install(
  47     FILES ${CMAKE_CURRENT_BINARY_DIR}/${file}.h
  48     DESTINATION include/vpp/${dir}
  49     COMPONENT vpp-dev
  50   )
  51 endforeach()
  52
  53 set(VPP_SOURCES
  54   vnet/main.c
  55   app/vpe_cli.c
  56   app/version.c
  57   oam/oam.c
  58   oam/oam_api.c
  59   stats/stats_to_be_deprecated.c
  60   stats/stat_segment.c
  61   api/api.c
  62   api/json_format.c
  63   api/custom_dump.c
  64   api/types.c
  65 )
  66
  67 if(VPP_API_TEST_BUILTIN)
  68   list(APPEND VPP_SOURCES
  69     api/api_format.c
  70     api/api_main.c
  71     api/plugin.c
  72     api/types.c
  73   )
  74   add_definitions(-DVPP_API_TEST_BUILTIN=1)
  75 endif()
  76
  77 add_vpp_executable(vpp
  78   ENABLE_EXPORTS
  79   SOURCES ${VPP_SOURCES}
  80   LINK_LIBRARIES svm vlib vppinfra vlibmemory vnet Threads::Threads ${CMAKE_DL_LIBS}
  81   DEPENDS vpp_version_h api_headers
  82 )
  83
  84 add_vpp_headers(vpp
  85   api/vpe_msg_enum.h
  86   api/vpe_all_api_h.h
  87   stats/stat_segment.h
  88 )
  89
  90 ##############################################################################
  91 # vppctl binary
  92 ##############################################################################
  93 add_vpp_executable(vppctl
  94   SOURCES app/vppctl.c
  95   LINK_LIBRARIES vppinfra
  96 )
  97
  98 ##############################################################################
  99 # vpp_get_metrics binary
 100 ##############################################################################
 101 add_vpp_executable(vpp_get_metrics
 102   SOURCES api/vpp_get_metrics.c
 103   LINK_LIBRARIES vppinfra svm svmdb
 104   DEPENDS api_headers
 105 )
 106
 107 ##############################################################################
 108 # stats binaries
 109 ##############################################################################
 110 add_vpp_executable(summary_stats_client
 111   SOURCES api/summary_stats_client.c
 112   LINK_LIBRARIES vppinfra svm vlibmemoryclient
 113   DEPENDS api_headers
 114   NO_INSTALL
 115 )
 116
 117 add_vpp_executable(vpp_get_stats
 118   SOURCES app/vpp_get_stats.c
 119   LINK_LIBRARIES vppapiclient vppinfra
 120   DEPENDS api_headers
 121 )
 122
 123 add_vpp_executable(vpp_prometheus_export
 124   SOURCES app/vpp_prometheus_export.c
 125   LINK_LIBRARIES vppapiclient vppinfra svm vlibmemoryclient
 126   DEPENDS api_headers
 127 )