src/vpp/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 ##############################################################################
  15 # Generate vpp/app/version.h
  16 ##############################################################################
  17 add_custom_command(
  18   OUTPUT ${CMAKE_BINARY_DIR}/include/vpp/app/version.h
  19   WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
  20   COMMAND mkdir
  21   ARGS -p ${CMAKE_BINARY_DIR}/include/vpp/app
  22   COMMAND scripts/generate_version_h
  23   ARGS ${CMAKE_BINARY_DIR}/include/vpp/app/version.h
  24   COMMENT "Generating VPP version.h"
  25 )
  26
  27 add_custom_target(vpp_version_h
  28   DEPENDS ${CMAKE_BINARY_DIR}/include/vpp/app/version.h
  29 )
  30
  31 ##############################################################################
  32 # vpp binary
  33 ##############################################################################
  34 option(VPP_API_TEST_BUILTIN "Use builtin VPP API test." ON)
  35
  36 configure_file(
  37   ${CMAKE_SOURCE_DIR}/vpp/vnet/config.h.in
  38   ${CMAKE_BINARY_DIR}/vpp/vnet/config.h
  39 )
  40
  41 set(VPP_API_FILES
  42   api/vpe_types.api
  43   api/vpe.api
  44 )
  45
  46 vpp_add_api_files(vpp core vpp ${VPP_API_FILES})
  47
  48 foreach(file ${VPP_API_FILES})
  49   get_filename_component(dir ${file} DIRECTORY)
  50   install(
  51     FILES ${CMAKE_CURRENT_BINARY_DIR}/${file}.h
  52     ${CMAKE_CURRENT_BINARY_DIR}/${file}_enum.h
  53     ${CMAKE_CURRENT_BINARY_DIR}/${file}_types.h
  54     DESTINATION include/vpp/${dir}
  55     COMPONENT vpp-dev
  56   )
  57 endforeach()
  58
  59 set(VPP_SOURCES
  60   vnet/main.c
  61   app/vpe_cli.c
  62   app/version.c
  63   stats/stat_segment.c
  64   api/api.c
  65   api/json_format.c
  66   api/custom_dump.c
  67   api/types.c
  68 )
  69
  70 if(VPP_API_TEST_BUILTIN)
  71   list(APPEND VPP_SOURCES
  72     api/api_format.c
  73     api/api_main.c
  74     api/plugin.c
  75     api/types.c
  76     ../vnet/arp/arp_test.c
  77   )
  78   add_definitions(-DVPP_API_TEST_BUILTIN=1)
  79 endif()
  80
  81 add_vpp_executable(vpp
  82   ENABLE_EXPORTS
  83   SOURCES ${VPP_SOURCES}
  84   LINK_LIBRARIES svm vlib vppinfra vlibmemory vnet Threads::Threads ${CMAKE_DL_LIBS}
  85   DEPENDS vpp_version_h api_headers
  86 )
  87
  88 add_vpp_headers(vpp
  89   api/vpe_msg_enum.h
  90   api/vpe_all_api_h.h
  91   stats/stat_segment.h
  92   stats/stat_segment_shared.h
  93 )
  94
  95 ##############################################################################
  96 # vppctl binary
  97 ##############################################################################
  98 add_vpp_executable(vppctl
  99   SOURCES app/vppctl.c
 100   LINK_LIBRARIES vppinfra
 101 )
 102
 103 ##############################################################################
 104 # vpp_get_metrics binary
 105 ##############################################################################
 106 add_vpp_executable(vpp_get_metrics
 107   SOURCES api/vpp_get_metrics.c
 108   LINK_LIBRARIES vppinfra svm svmdb
 109   DEPENDS api_headers
 110 )
 111
 112 ##############################################################################
 113 # stats binaries
 114 ##############################################################################
 115 add_vpp_executable(vpp_get_stats
 116   SOURCES app/vpp_get_stats.c
 117   LINK_LIBRARIES vppapiclient vppinfra
 118   DEPENDS api_headers
 119 )
 120
 121 add_vpp_executable(vpp_prometheus_export
 122   SOURCES app/vpp_prometheus_export.c
 123   LINK_LIBRARIES vppapiclient vppinfra svm vlibmemoryclient
 124   DEPENDS api_headers
 125 )
 126
 127 install(FILES conf/startup.conf DESTINATION etc/vpp COMPONENT vpp)
 128 install(FILES conf/80-vpp.conf DESTINATION etc/sysctl.d COMPONENT vpp)