HC Tests: fix packet trace library settings
[csit.git] / tests / vpp / func / honeycomb / mgmt-cfg-lispgpe-apihc-apivat-func.robot
1 # Copyright (c) 2017 Cisco and/or its affiliates.
2 # Licensed under the Apache License, Version 2.0 (the "License");
3 # you may not use this file except in compliance with the License.
4 # You may obtain a copy of the License at:
5 #
6 #     http://www.apache.org/licenses/LICENSE-2.0
7 #
8 # Unless required by applicable law or agreed to in writing, software
9 # distributed under the License is distributed on an "AS IS" BASIS,
10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11 # See the License for the specific language governing permissions and
12 # limitations under the License.
13
14 *** Variables***
15 | ${interface}= | ${node['interfaces']['port1']['name']}
16
17 *** Settings ***
18 | Library | resources.libraries.python.Trace
19 | Resource | resources/libraries/robot/shared/default.robot
20 | Resource | resources/libraries/robot/shared/testing_path.robot
21 | Resource | resources/libraries/robot/shared/traffic.robot
22 | Resource | resources/libraries/robot/honeycomb/honeycomb.robot
23 | Resource | resources/libraries/robot/honeycomb/interfaces.robot
24 | Resource | resources/libraries/robot/honeycomb/lisp_gpe.robot
25 | Variables | resources/test_data/honeycomb/lisp/lisp_gpe.py
26 | ...
27 | Documentation | *Honeycomb LISP GPE test suite.*
28 | ...
29 | Suite Setup | Set Up Honeycomb Functional Test Suite | ${node}
30 | ...
31 | Suite Teardown | Tear Down Honeycomb Functional Test Suite | ${node}
32 | ...
33 | Force Tags | HC_FUNC
34
35 *** Test Cases ***
36 | TC01: Honeycomb enables LISP GPE feature
37 | | [Documentation] | Check if Honeycomb can enable the LISP GPE feature.
38 | | ...
39 | | Given LISP GPE Should Not Be Configured | ${node}
40 | | When Honeycomb enables LISP GPE | ${node}
41 | | Then LISP GPE state from Honeycomb should be | ${node} | enabled
42 | | And LISP GPE state from VAT should be | ${node} | enabled
43
44 | TC02: Honeycomb disable LISP GPE feature
45 | | [Documentation] | Check if Honeycomb can enable the LISP GPE feature.
46 | | ...
47 | | [Teardown] | Honeycomb enables LISP GPE | ${node}
48 | | Given LISP GPE state from Honeycomb should be | ${node} | enabled
49 | | And LISP GPE state from VAT should be | ${node} | enabled
50 | | When Honeycomb disables LISP GPE | ${node}
51 | | Then LISP GPE state from Honeycomb should be | ${node} | disabled
52 | | And LISP GPE state from VAT should be | ${node} | disabled
53
54 | TC03: Honeycomb configures LISP GPE mapping - negative, IPv4
55 | | [Documentation] | Check if Honeycomb can configure a LISP mapping\
56 | | ... | with VRF.
57 | | ...
58 | | Given LISP GPE mappings from Honeycomb should not exist
59 | | ... | ${node}
60 | | When Honeycomb adds first LISP GPE mapping
61 | | ... | ${node} | ${negative_mapping_ip4}
62 | | Then LISP GPE mapping from Honeycomb should be
63 | | ... | ${node} | ${negative_mapping_ip4}
64
65 | TC04: Honeycomb can remove LISP GPE mapping
66 | | [Documentation] | Check if Honeycomb can remove a configured LISP GPE\
67 | | ... | mapping.
68 | | ...
69 | | Given LISP GPE mapping from Honeycomb should be
70 | | ... | ${node} | ${negative_mapping_ip4}
71 | | When Honeycomb removes LISP GPE mapping
72 | | ... | ${node} | ${negative_mapping_ip4['id']}
73 | | Then LISP GPE mappings from Honeycomb should not exist
74 | | ... | ${node}
75
76 | TC05: Honeycomb configures LISP GPE mapping - positive, IPv4
77 | | [Documentation] | Check if Honeycomb can configure a LISP mapping\
78 | | ... | with VRF.
79 | | ...
80 | | [Teardown] | Honeycomb removes LISP GPE mapping
81 | | ... | ${node} | ${positive_mapping_ip4['id']}
82 | | Given LISP GPE mappings from Honeycomb should not exist
83 | | ... | ${node}
84 | | When Honeycomb adds first LISP GPE mapping
85 | | ... | ${node} | ${positive_mapping_ip4}
86 | | Then LISP GPE mapping from Honeycomb should be
87 | | ... | ${node} | ${positive_mapping_ip4}
88
89 | TC06: Honeycomb configures LISP GPE mapping - negative, IPv6
90 | | [Documentation] | Check if Honeycomb can configure a LISP mapping\
91 | | ... | with VRF.
92 | | ...
93 | | [Teardown] | Honeycomb removes LISP GPE mapping
94 | | ... | ${node} | ${negative_mapping_ip6['id']}
95 | | Given LISP GPE mappings from Honeycomb should not exist
96 | | ... | ${node}
97 | | When Honeycomb adds first LISP GPE mapping
98 | | ... | ${node} | ${negative_mapping_ip6}
99 | | Then LISP GPE mapping from Honeycomb should be
100 | | ... | ${node} | ${negative_mapping_ip6}
101
102 | TC07: Honeycomb configures LISP GPE mapping - positive, IPv6
103 | | [Documentation] | Check if Honeycomb can configure a LISP mapping\
104 | | ... | with VRF.
105 | | ...
106 | | [Teardown] | Honeycomb removes LISP GPE mapping
107 | | ... | ${node} | ${positive_mapping_ip6['id']}
108 | | Given LISP GPE mappings from Honeycomb should not exist
109 | | ... | ${node}
110 | | When Honeycomb adds first LISP GPE mapping
111 | | ... | ${node} | ${positive_mapping_ip6}
112 | | Then LISP GPE mapping from Honeycomb should be
113 | | ... | ${node} | ${positive_mapping_ip6}
114
115 | TC08: Honeycomb can modify existing LISP GPE mappping
116 | | [Documentation] | Check if Honeycomb can modify and existing LISP GPE\
117 | | ... | mapping.
118 | | ...
119 | | [Teardown] | Honeycomb removes LISP GPE mapping
120 | | ... | ${node} | ${negative_mapping_ip4_edit['id']}
121 | | Given LISP GPE mappings from Honeycomb should not exist
122 | | ... | ${node}
123 | | When Honeycomb adds first LISP GPE mapping
124 | | ... | ${node} | ${negative_mapping_ip4}
125 | | Then LISP GPE mapping from Honeycomb should be
126 | | ... | ${node} | ${negative_mapping_ip4}
127 | | When Honeycomb adds first LISP GPE mapping | ${node}
128 | | ... | ${negative_mapping_ip4_edit}
129 | | Then LISP GPE mapping from Honeycomb should be
130 | | ... | ${node} | ${negative_mapping_ip4_edit}
131
132 | TC09: Honeycomb can configure multiple LISP GPE mapppings
133 | | [Documentation] | Check if Honeycomb can configure multiple LISP GPE\
134 | | ... | mappings at the same time.
135 | | ...
136 | | [Teardown] | Run Keywords
137 | | ... | Honeycomb removes LISP GPE mapping
138 | | ... | ${node} | ${negative_mapping_ip4['id']}
139 | | ... | AND | Honeycomb removes LISP GPE mapping
140 | | ... | ${node} | ${negative_mapping_ip4_2['id']}
141 | | Given LISP GPE mappings from Honeycomb should not exist
142 | | ... | ${node}
143 | | When Honeycomb adds first LISP GPE mapping
144 | | ... | ${node} | ${negative_mapping_ip4}
145 | | And Honeycomb adds LISP GPE mapping | ${node} | ${negative_mapping_ip4_2}
146 | | Then LISP GPE mapping from Honeycomb should be
147 | | ... | ${node} | ${negative_mapping_ip4}
148 | | And LISP GPE mapping from Honeycomb should be
149 | | ... | ${node} | ${negative_mapping_ip4_2}
150
151 | TC10: Honeycomb can disable all LISP GPE features
152 | | [Documentation] | Check if Honeycomb can disable all LISP GPE features.
153 | | ...
154 | | Given Honeycomb adds first LISP GPE mapping
155 | | ... | ${node} | ${negative_mapping_ip4}
156 | | When Honeycomb disables all LISP GPE features | ${node}
157 | | Then LISP GPE mappings from Honeycomb should not exist
158 | | ... | ${node}
159 | | And LISP GPE state from Honeycomb should be | ${node} | disabled
160 | | And LISP GPE state from VAT should be | ${node} | disabled
161
162 | TC11: Honeycomb can configure LISP GPE for traffic test - IPv4
163 | | [Documentation]
164 | | ... | [Top] TG-DUT1-TG.
165 | | ... | [Enc] Eth-IPv4-LISPGPE-IPv4-ICMPv4
166 | | ... | [Cfg] Configure IPv4 LISP static adjacencies on DUT1.
167 | | ... | [Ver] Case: ip4-lispgpe-ip4 - phy2lisp
168 | | ... | Make TG send ICMPv4 Echo Req between its interfaces through DUT1\
169 | | ... | LISP GPE tunnel verify LISP encapsulation of received packet.
170 | | ... | [Ref] RFC6830.
171 | | ...
172 | | [Teardown] | LISPGPE functional traffic test teardown
173 | | Given Configure path in 2-node circular topology
174 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
175 | | And Honeycomb configures interface state
176 | | ... | ${dut_node} | ${dut_to_tg_if1} | up
177 | | And Honeycomb configures interface state
178 | | ... | ${dut_node} | ${dut_to_tg_if2} | up
179 | | And Honeycomb sets interface IPv4 address with prefix | ${dut_node}
180 | | ... | ${dut_to_tg_if1} | ${dut_to_tg_if1_ip4} | ${prefix_len4}
181 | | And Honeycomb sets interface IPv4 address with prefix | ${dut_node}
182 | | ... | ${dut_to_tg_if2} | ${dut_to_tg_if2_ip4} | ${prefix_len4}
183 | | And Honeycomb adds interface IPv4 neighbor | ${dut_node} | ${dut_to_tg_if1}
184 | | ... | ${src_ip4} | ${tg_to_dut_if1_mac}
185 | | And Honeycomb adds interface IPv4 neighbor | ${dut_node} | ${dut_to_tg_if2}
186 | | ... | ${tg_to_dut_if2_ip4} | ${tg_to_dut_if2_mac}
187 | | When Honeycomb enables LISP GPE | ${node}
188 | | And Honeycomb adds LISP GPE mapping | ${node} | ${lisp_traffic_ip4}
189 | | Then send packet and verify LISP GPE encap
190 | | ... | ${tg_node} | ${src_ip4} | ${dst_ip4}
191 | | ... | ${tg_to_dut_if1} | ${tg_to_dut_if1_mac} | ${dut_to_tg_if1_mac}
192 | | ... | ${tg_to_dut_if2} | ${dut_to_tg_if2_mac} | ${tg_to_dut_if2_mac}
193 | | ... | ${src_rloc4} | ${dst_rloc4}
194
195 | TC12: Honeycomb can configure LISP GPE for traffic test - IPv6
196 | | [Documentation]
197 | | ... | [Top] TG-DUT1-TG.
198 | | ... | [Enc] Eth-IPv6-LISPGPE-IPv6-ICMPv6
199 | | ... | [Cfg] Configure IPv6 LISP static adjacencies on DUT1.
200 | | ... | [Ver] Case: ip6-lispgpe-ip6 - phy2lisp
201 | | ... | Make TG send ICMPv6 Echo Req between its interfaces through DUT1\
202 | | ... | LISP GPE tunnel verify LISP encapsulation of received packet.
203 | | ... | [Ref] RFC6830.
204 | | ...
205 | | [Teardown] | LISPGPE functional traffic test teardown
206 | | Given Configure path in 2-node circular topology
207 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
208 | | And Honeycomb configures interface state
209 | | ... | ${dut_node} | ${dut_to_tg_if1} | up
210 | | And Honeycomb configures interface state
211 | | ... | ${dut_node} | ${dut_to_tg_if2} | up
212 | | And Honeycomb sets interface IPv6 address | ${dut_node}
213 | | ... | ${dut_to_tg_if1} | ${dut_to_tg_if1_ip6} | ${prefix_len6}
214 | | And Honeycomb sets interface IPv6 address | ${dut_node}
215 | | ... | ${dut_to_tg_if2} | ${dut_to_tg_if2_ip6} | ${prefix_len6}
216 | | And Honeycomb adds interface IPv6 neighbor | ${dut_node} | ${dut_to_tg_if1}
217 | | ... | ${src_ip6} | ${tg_to_dut_if1_mac}
218 | | And Honeycomb adds interface IPv6 neighbor | ${dut_node} | ${dut_to_tg_if2}
219 | | ... | ${tg_to_dut_if2_ip6} | ${tg_to_dut_if2_mac}
220 | | When Honeycomb enables LISP GPE | ${node}
221 | | And Honeycomb adds LISP GPE mapping | ${node} | ${lisp_traffic_ip6}
222 | | Then send packet and verify LISP GPE encap
223 | | ... | ${tg_node} | ${src_ip6} | ${dst_ip6}
224 | | ... | ${tg_to_dut_if1} | ${tg_to_dut_if1_mac} | ${dut_to_tg_if1_mac}
225 | | ... | ${tg_to_dut_if2} | ${dut_to_tg_if2_mac} | ${tg_to_dut_if2_mac}
226 | | ... | ${src_rloc6} | ${dst_rloc6}

©2016 FD.io a Linux Foundation Collaborative Project. All Rights Reserved.
Linux Foundation is a registered trademark of The Linux Foundation. Linux is a registered trademark of Linus Torvalds.
Please see our privacy policy and terms of use.